matita/matita/contribs/lambdadelta/basic_2/rt_computation/csx_vector.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/syntax/term_vector.ma".
  16 include "basic_2/rt_computation/csx.ma".
  17
  18 (* STRONGLY NORMALIZING TERMS VECTORS FOR EXTENDED PARALLEL RT-TRANSITION ***)
  19
  20 definition csxv (G) (L): predicate (list term) ≝
  21            all … (csx G L).
  22
  23 interpretation
  24   "strong normalization for extended context-sensitive parallel rt-transition (term vector)"
  25   'PRedTyStrong G L Ts = (csxv G L Ts).
  26
  27 (* Basic inversion lemmas ***************************************************)
  28
  29 lemma csxv_inv_cons (G) (L):
  30       ∀T,Ts. ❪G,L❫ ⊢ ⬈*𝐒 T⨮Ts →
  31       ∧∧ ❪G,L❫ ⊢ ⬈*𝐒 T & ❪G,L❫ ⊢ ⬈*𝐒 Ts.
  32 normalize // qed-.
  33
  34 (* Basic forward lemmas *****************************************************)
  35
  36 lemma csx_fwd_applv (G) (L):
  37       ∀T,Vs. ❪G,L❫ ⊢ ⬈*𝐒 ⒶVs.T →
  38       ∧∧ ❪G,L❫ ⊢ ⬈*𝐒 Vs & ❪G,L❫ ⊢ ⬈*𝐒 T.
  39 #G #L #T #Vs elim Vs -Vs /2 width=1 by conj/
  40 #V #Vs #IHVs #HVs
  41 lapply (csx_fwd_pair_sn … HVs) #HV
  42 lapply (csx_fwd_flat_dx … HVs) -HVs #HVs
  43 elim (IHVs HVs) -IHVs -HVs /3 width=1 by conj/
  44 qed-.