matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_3_6.ma".
  16 include "basic_2/notation/relations/predsubtystarproper_6.ma".
  17 include "basic_2/rt_transition/fpbc.ma".
  18 include "basic_2/rt_computation/fpbs.ma".
  19
  20 (* PROPER PARALLEL RST-COMPUTATION FOR CLOSURES *****************************)
  21
  22 definition fpbg: tri_relation genv lenv term ≝
  23            λG1,L1,T1,G2,L2,T2.
  24            ∃∃G3,L3,T3,G4,L4,T4. ❨G1,L1,T1❩ ≥ ❨G3,L3,T3❩ & ❨G3,L3,T3❩ ≻ ❨G4,L4,T4❩ & ❨G4,L4,T4❩ ≥ ❨G2,L2,T2❩.
  25
  26 interpretation
  27   "proper parallel rst-computation (closure)"
  28   'PRedSubTyStarProper G1 L1 T1 G2 L2 T2 = (fpbg G1 L1 T1 G2 L2 T2).
  29
  30 (* Basic inversion lemmas ***************************************************)
  31
  32 lemma fpbg_inv_gen (G1) (G2) (L1) (L2) (T1) (T2):
  33       ❨G1,L1,T1❩ > ❨G2,L2,T2❩ →
  34       ∃∃G3,L3,T3,G4,L4,T4. ❨G1,L1,T1❩ ≥ ❨G3,L3,T3❩ & ❨G3,L3,T3❩ ≻ ❨G4,L4,T4❩ & ❨G4,L4,T4❩ ≥ ❨G2,L2,T2❩.
  35 // qed-.
  36
  37 (* Basic properties *********************************************************)
  38
  39 lemma fpbg_intro (G3) (G4) (L3) (L4) (T3) (T4):
  40       ∀G1,L1,T1,G2,L2,T2.
  41       ❨G1,L1,T1❩ ≥ ❨G3,L3,T3❩ → ❨G3,L3,T3❩ ≻ ❨G4,L4,T4❩ →
  42       ❨G4,L4,T4❩ ≥ ❨G2,L2,T2❩ → ❨G1,L1,T1❩ > ❨G2,L2,T2❩.
  43 /2 width=9 by ex3_6_intro/ qed.
  44
  45 (* Basic_2A1: was: fpbg_fpbq_trans *)
  46 lemma fpbg_fpb_trans:
  47       ∀G1,G,G2,L1,L,L2,T1,T,T2.
  48       ❨G1,L1,T1❩ > ❨G,L,T❩ → ❨G,L,T❩ ≽ ❨G2,L2,T2❩ →
  49       ❨G1,L1,T1❩ > ❨G2,L2,T2❩.
  50 #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2
  51 elim (fpbg_inv_gen … H1) -H1
  52 /3 width=13 by fpbs_strap1, fpbg_intro/
  53 qed-.
  54
  55 (* Basic_2A1: was: fpbq_fpbg_trans *)
  56 lemma fpb_fpbg_trans:
  57       ∀G1,G,G2,L1,L,L2,T1,T,T2.
  58       ❨G1,L1,T1❩ ≽ ❨G,L,T❩ → ❨G,L,T❩ > ❨G2,L2,T2❩ →
  59       ❨G1,L1,T1❩ > ❨G2,L2,T2❩.
  60 #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2
  61 elim (fpbg_inv_gen … H2) -H2
  62 /3 width=13 by fpbs_strap2, fpbg_intro/
  63 qed-.