]> matita.cs.unibo.it Git - helm.git/blob - matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbg_fpbs.ma
update in ground_2, static_2, basic_2, apps_2, alpha_1
[helm.git] / matita / matita / contribs / lambdadelta / basic_2 / rt_computation / fpbg_fpbs.ma
1 (**************************************************************************)
2 (*       ___                                                              *)
3 (*      ||M||                                                             *)
4 (*      ||A||       A project by Andrea Asperti                           *)
5 (*      ||T||                                                             *)
6 (*      ||I||       Developers:                                           *)
7 (*      ||T||         The HELM team.                                      *)
8 (*      ||A||         http://helm.cs.unibo.it                             *)
9 (*      \   /                                                             *)
10 (*       \ /        This file is distributed under the terms of the       *)
11 (*        v         GNU General Public License Version 2                  *)
12 (*                                                                        *)
13 (**************************************************************************)
14
15 include "static_2/static/feqx_feqx.ma".
16 include "basic_2/rt_transition/fpbq_fpb.ma".
17 include "basic_2/rt_computation/fpbs_fqup.ma".
18 include "basic_2/rt_computation/fpbg.ma".
19
20 (* PROPER PARALLEL RST-COMPUTATION FOR CLOSURES *****************************)
21
22 (* Advanced forward lemmas **************************************************)
23
24 lemma fpbg_fwd_fpbs: ∀h,G1,G2,L1,L2,T1,T2.
25                      ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥[h] ❪G2,L2,T2❫.
26 #h #G1 #G2 #L1 #L2 #T1 #T2 *
27 /3 width=5 by fpbs_strap2, fpb_fpbq/
28 qed-.
29
30 (* Advanced properties with sort-irrelevant equivalence on closures *********)
31
32 (* Basic_2A1: uses: fleq_fpbg_trans *)
33 lemma feqx_fpbg_trans: ∀h,G,G2,L,L2,T,T2. ❪G,L,T❫ >[h] ❪G2,L2,T2❫ →
34                        ∀G1,L1,T1. ❪G1,L1,T1❫ ≛ ❪G,L,T❫ → ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
35 #h #G #G2 #L #L2 #T #T2 * #G0 #L0 #T0 #H0 #H02 #G1 #L1 #T1 #H1
36 elim (feqx_fpb_trans …  H1 … H0) -G -L -T
37 /4 width=9 by fpbs_strap2, fpbq_feqx, ex2_3_intro/
38 qed-.
39
40 (* Properties with parallel proper rst-reduction on closures ****************)
41
42 lemma fpb_fpbg_trans: ∀h,G1,G,G2,L1,L,L2,T1,T,T2.
43                       ❪G1,L1,T1❫ ≻[h] ❪G,L,T❫ → ❪G,L,T❫ >[h] ❪G2,L2,T2❫ →
44                       ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
45 /3 width=5 by fpbg_fwd_fpbs, ex2_3_intro/ qed-.
46
47 (* Properties with parallel rst-reduction on closures ***********************)
48
49 lemma fpbq_fpbg_trans: ∀h,G1,G,G2,L1,L,L2,T1,T,T2.
50                        ❪G1,L1,T1❫ ≽[h] ❪G,L,T❫ → ❪G,L,T❫ >[h] ❪G2,L2,T2❫ →
51                        ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
52 #h #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2
53 elim (fpbq_inv_fpb … H1) -H1
54 /2 width=5 by feqx_fpbg_trans, fpb_fpbg_trans/
55 qed-.
56
57 (* Properties with parallel rst-compuutation on closures ********************)
58
59 lemma fpbs_fpbg_trans: ∀h,G1,G,L1,L,T1,T. ❪G1,L1,T1❫ ≥[h] ❪G,L,T❫ →
60                        ∀G2,L2,T2. ❪G,L,T❫ >[h] ❪G2,L2,T2❫ → ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
61 #h #G1 #G #L1 #L #T1 #T #H @(fpbs_ind … H) -G -L -T /3 width=5 by fpbq_fpbg_trans/
62 qed-.
63
64 (* Advanced properties with plus-iterated structural successor for closures *)
65
66 lemma fqup_fpbg_trans (h):
67       ∀G1,G,L1,L,T1,T. ❪G1,L1,T1❫ ⬂+ ❪G,L,T❫ →
68       ∀G2,L2,T2. ❪G,L,T❫ >[h] ❪G2,L2,T2❫ → ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
69 /3 width=5 by fpbs_fpbg_trans, fqup_fpbs/ qed-.
70
71 (* Advanced inversion lemmas of parallel rst-computation on closures ********)
72
73 (* Basic_2A1: was: fpbs_fpbg *)
74 lemma fpbs_inv_fpbg: ∀h,G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≥[h] ❪G2,L2,T2❫ →
75                      ∨∨ ❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫
76                       | ❪G1,L1,T1❫ >[h] ❪G2,L2,T2❫.
77 #h #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind … H) -G2 -L2 -T2
78 [ /2 width=1 by or_introl/
79 | #G #G2 #L #L2 #T #T2 #_ #H2 * #H1
80   elim (fpbq_inv_fpb … H2) -H2 #H2
81   [ /3 width=5 by feqx_trans, or_introl/
82   | elim (feqx_fpb_trans … H1 … H2) -G -L -T
83     /4 width=5 by ex2_3_intro, or_intror, feqx_fpbs/
84   | /3 width=5 by fpbg_feqx_trans, or_intror/
85   | /4 width=5 by fpbg_fpbq_trans, fpb_fpbq, or_intror/
86   ]
87 ]
88 qed-.
89
90 (* Advanced properties of parallel rst-computation on closures **************)
91
92 lemma fpbs_fpb_trans: ∀h,F1,F2,K1,K2,T1,T2. ❪F1,K1,T1❫ ≥[h] ❪F2,K2,T2❫ →
93                       ∀G2,L2,U2. ❪F2,K2,T2❫ ≻[h] ❪G2,L2,U2❫ →
94                       ∃∃G1,L1,U1. ❪F1,K1,T1❫ ≻[h] ❪G1,L1,U1❫ & ❪G1,L1,U1❫ ≥[h] ❪G2,L2,U2❫.
95 #h #F1 #F2 #K1 #K2 #T1 #T2 #H elim (fpbs_inv_fpbg … H) -H
96 [ #H12 #G2 #L2 #U2 #H2 elim (feqx_fpb_trans … H12 … H2) -F2 -K2 -T2
97   /3 width=5 by feqx_fpbs, ex2_3_intro/
98 | * #H1 #H2 #H3 #H4 #H5 #H6 #H7 #H8 #H9
99   @(ex2_3_intro … H4) -H4 /3 width=5 by fpbs_strap1, fpb_fpbq/
100 ]
101 qed-.