matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbg_fpbs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/feqx_feqx.ma".
  16 include "basic_2/rt_transition/fpbq_fpb.ma".
  17 include "basic_2/rt_computation/fpbs_fqup.ma".
  18 include "basic_2/rt_computation/fpbg.ma".
  19
  20 (* PROPER PARALLEL RST-COMPUTATION FOR CLOSURES *****************************)
  21
  22 (* Advanced forward lemmas **************************************************)
  23
  24 lemma fpbg_fwd_fpbs:
  25       ∀G1,G2,L1,L2,T1,T2.
  26       ❪G1,L1,T1❫ > ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  27 #G1 #G2 #L1 #L2 #T1 #T2 *
  28 /3 width=5 by fpbs_strap2, fpb_fpbq/
  29 qed-.
  30
  31 (* Advanced properties with sort-irrelevant equivalence on closures *********)
  32
  33 (* Basic_2A1: uses: fleq_fpbg_trans *)
  34 lemma feqx_fpbg_trans:
  35       ∀G,G2,L,L2,T,T2. ❪G,L,T❫ > ❪G2,L2,T2❫ →
  36       ∀G1,L1,T1. ❪G1,L1,T1❫ ≛ ❪G,L,T❫ → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  37 #G #G2 #L #L2 #T #T2 * #G0 #L0 #T0 #H0 #H02 #G1 #L1 #T1 #H1
  38 elim (feqx_fpb_trans …  H1 … H0) -G -L -T
  39 /4 width=9 by fpbs_strap2, fpbq_feqx, ex2_3_intro/
  40 qed-.
  41
  42 (* Properties with parallel proper rst-reduction on closures ****************)
  43
  44 lemma fpb_fpbg_trans:
  45       ∀G1,G,G2,L1,L,L2,T1,T,T2.
  46       ❪G1,L1,T1❫ ≻ ❪G,L,T❫ → ❪G,L,T❫ > ❪G2,L2,T2❫ →
  47       ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  48 /3 width=5 by fpbg_fwd_fpbs, ex2_3_intro/ qed-.
  49
  50 (* Properties with parallel rst-reduction on closures ***********************)
  51
  52 lemma fpbq_fpbg_trans:
  53       ∀G1,G,G2,L1,L,L2,T1,T,T2.
  54       ❪G1,L1,T1❫ ≽ ❪G,L,T❫ → ❪G,L,T❫ > ❪G2,L2,T2❫ →
  55       ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  56 #G1 #G #G2 #L1 #L #L2 #T1 #T #T2 #H1 #H2
  57 elim (fpbq_inv_fpb … H1) -H1
  58 /2 width=5 by feqx_fpbg_trans, fpb_fpbg_trans/
  59 qed-.
  60
  61 (* Properties with parallel rst-compuutation on closures ********************)
  62
  63 lemma fpbs_fpbg_trans:
  64       ∀G1,G,L1,L,T1,T. ❪G1,L1,T1❫ ≥ ❪G,L,T❫ →
  65       ∀G2,L2,T2. ❪G,L,T❫ > ❪G2,L2,T2❫ → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  66 #G1 #G #L1 #L #T1 #T #H @(fpbs_ind … H) -G -L -T /3 width=5 by fpbq_fpbg_trans/
  67 qed-.
  68
  69 (* Advanced properties with plus-iterated structural successor for closures *)
  70
  71 lemma fqup_fpbg_trans:
  72       ∀G1,G,L1,L,T1,T. ❪G1,L1,T1❫ ⬂+ ❪G,L,T❫ →
  73       ∀G2,L2,T2. ❪G,L,T❫ > ❪G2,L2,T2❫ → ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  74 /3 width=5 by fpbs_fpbg_trans, fqup_fpbs/ qed-.
  75
  76 (* Advanced inversion lemmas of parallel rst-computation on closures ********)
  77
  78 (* Basic_2A1: was: fpbs_fpbg *)
  79 lemma fpbs_inv_fpbg:
  80       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫ →
  81       ∨∨ ❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫
  82        | ❪G1,L1,T1❫ > ❪G2,L2,T2❫.
  83 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind … H) -G2 -L2 -T2
  84 [ /2 width=1 by or_introl/
  85 | #G #G2 #L #L2 #T #T2 #_ #H2 * #H1
  86   elim (fpbq_inv_fpb … H2) -H2 #H2
  87   [ /3 width=5 by feqx_trans, or_introl/
  88   | elim (feqx_fpb_trans … H1 … H2) -G -L -T
  89     /4 width=5 by ex2_3_intro, or_intror, feqx_fpbs/
  90   | /3 width=5 by fpbg_feqx_trans, or_intror/
  91   | /4 width=5 by fpbg_fpbq_trans, fpb_fpbq, or_intror/
  92   ]
  93 ]
  94 qed-.
  95
  96 (* Advanced properties of parallel rst-computation on closures **************)
  97
  98 lemma fpbs_fpb_trans:
  99       ∀F1,F2,K1,K2,T1,T2. ❪F1,K1,T1❫ ≥ ❪F2,K2,T2❫ →
 100       ∀G2,L2,U2. ❪F2,K2,T2❫ ≻ ❪G2,L2,U2❫ →
 101       ∃∃G1,L1,U1. ❪F1,K1,T1❫ ≻ ❪G1,L1,U1❫ & ❪G1,L1,U1❫ ≥ ❪G2,L2,U2❫.
 102 #F1 #F2 #K1 #K2 #T1 #T2 #H elim (fpbs_inv_fpbg … H) -H
 103 [ #H12 #G2 #L2 #U2 #H2 elim (feqx_fpb_trans … H12 … H2) -F2 -K2 -T2
 104   /3 width=5 by feqx_fpbs, ex2_3_intro/
 105 | * #H1 #H2 #H3 #H4 #H5 #H6 #H7 #H8 #H9
 106   @(ex2_3_intro … H4) -H4 /3 width=5 by fpbs_strap1, fpb_fpbq/
 107 ]
 108 qed-.