matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/lib/star.ma".
  16 include "basic_2/notation/relations/predsubtystar_6.ma".
  17 include "basic_2/rt_transition/fpbq.ma".
  18
  19 (* PARALLEL RST-COMPUTATION FOR CLOSURES ************************************)
  20
  21 definition fpbs: tri_relation genv lenv term ≝
  22            tri_TC … fpbq.
  23
  24 interpretation
  25   "parallel rst-computation (closure)"
  26   'PRedSubTyStar  G1 L1 T1 G2 L2 T2 = (fpbs G1 L1 T1 G2 L2 T2).
  27
  28 (* Basic eliminators ********************************************************)
  29
  30 lemma fpbs_ind:
  31       ∀G1,L1,T1. ∀Q:relation3 genv lenv term. Q G1 L1 T1 →
  32       (∀G,G2,L,L2,T,T2. ❪G1,L1,T1❫ ≥ ❪G,L,T❫ → ❪G,L,T❫ ≽ ❪G2,L2,T2❫ → Q G L T → Q G2 L2 T2) →
  33       ∀G2,L2,T2. ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫ → Q G2 L2 T2.
  34 /3 width=8 by tri_TC_star_ind/ qed-.
  35
  36 lemma fpbs_ind_dx:
  37       ∀G2,L2,T2. ∀Q:relation3 genv lenv term. Q G2 L2 T2 →
  38       (∀G1,G,L1,L,T1,T. ❪G1,L1,T1❫ ≽ ❪G,L,T❫ → ❪G,L,T❫ ≥ ❪G2,L2,T2❫ → Q G L T → Q G1 L1 T1) →
  39       ∀G1,L1,T1. ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫ → Q G1 L1 T1.
  40 /3 width=8 by tri_TC_star_ind_dx/ qed-.
  41
  42 (* Basic properties *********************************************************)
  43
  44 lemma fpbs_refl:
  45       tri_reflexive … fpbs.
  46 /2 width=1 by tri_inj/ qed.
  47
  48 lemma fpbq_fpbs:
  49       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫ →
  50       ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  51 /2 width=1 by tri_inj/ qed.
  52
  53 lemma fpbs_strap1:
  54       ∀G1,G,G2,L1,L,L2,T1,T,T2. ❪G1,L1,T1❫ ≥ ❪G,L,T❫ →
  55       ❪G,L,T❫ ≽ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  56 /2 width=5 by tri_step/ qed-.
  57
  58 lemma fpbs_strap2:
  59       ∀G1,G,G2,L1,L,L2,T1,T,T2. ❪G1,L1,T1❫ ≽ ❪G,L,T❫ →
  60       ❪G,L,T❫ ≥ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  61 /2 width=5 by tri_TC_strap/ qed-.
  62
  63 (* Basic_2A1: uses: lleq_fpbs fleq_fpbs *)
  64 lemma feqx_fpbs:
  65       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≛ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  66 /3 width=1 by fpbq_fpbs, fpbq_feqx/ qed.
  67
  68 (* Basic_2A1: uses: fpbs_lleq_trans *)
  69 lemma fpbs_feqx_trans:
  70       ∀G1,G,L1,L,T1,T. ❪G1,L1,T1❫ ≥ ❪G,L,T❫ →
  71       ∀G2,L2,T2. ❪G,L,T❫ ≛ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  72 /3 width=9 by fpbs_strap1, fpbq_feqx/ qed-.
  73
  74 (* Basic_2A1: uses: lleq_fpbs_trans *)
  75 lemma feqx_fpbs_trans:
  76       ∀G,G2,L,L2,T,T2. ❪G,L,T❫ ≥ ❪G2,L2,T2❫ →
  77       ∀G1,L1,T1. ❪G1,L1,T1❫ ≛ ❪G,L,T❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  78 /3 width=5 by fpbs_strap2, fpbq_feqx/ qed-.
  79
  80 lemma teqx_reqx_lpx_fpbs:
  81       ∀T1,T2. T1 ≛ T2 → ∀L1,L0. L1 ≛[T2] L0 →
  82       ∀G,L2. ❪G,L0❫ ⊢ ⬈ L2 → ❪G,L1,T1❫ ≥ ❪G,L2,T2❫.
  83 /4 width=5 by feqx_fpbs, fpbs_strap1, fpbq_lpx, feqx_intro_dx/ qed.
  84
  85 (* Basic_2A1: removed theorems 3:
  86               fpb_fpbsa_trans fpbs_fpbsa fpbsa_inv_fpbs
  87 *)