matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/lib/star.ma".
  16 include "basic_2/notation/relations/predsubtystar_6.ma".
  17 include "static_2/static/reqx.ma".
  18 include "basic_2/rt_transition/fpbq.ma".
  19
  20 (* PARALLEL RST-COMPUTATION FOR CLOSURES ************************************)
  21
  22 definition fpbs: tri_relation genv lenv term ≝
  23            tri_TC … fpbq.
  24
  25 interpretation
  26   "parallel rst-computation (closure)"
  27   'PRedSubTyStar  G1 L1 T1 G2 L2 T2 = (fpbs G1 L1 T1 G2 L2 T2).
  28
  29 (* Basic eliminators ********************************************************)
  30
  31 lemma fpbs_ind:
  32       ∀G1,L1,T1. ∀Q:relation3 genv lenv term. Q G1 L1 T1 →
  33       (∀G,G2,L,L2,T,T2. ❪G1,L1,T1❫ ≥ ❪G,L,T❫ → ❪G,L,T❫ ≽ ❪G2,L2,T2❫ → Q G L T → Q G2 L2 T2) →
  34       ∀G2,L2,T2. ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫ → Q G2 L2 T2.
  35 /3 width=8 by tri_TC_star_ind/ qed-.
  36
  37 lemma fpbs_ind_dx:
  38       ∀G2,L2,T2. ∀Q:relation3 genv lenv term. Q G2 L2 T2 →
  39       (∀G1,G,L1,L,T1,T. ❪G1,L1,T1❫ ≽ ❪G,L,T❫ → ❪G,L,T❫ ≥ ❪G2,L2,T2❫ → Q G L T → Q G1 L1 T1) →
  40       ∀G1,L1,T1. ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫ → Q G1 L1 T1.
  41 /3 width=8 by tri_TC_star_ind_dx/ qed-.
  42
  43 (* Basic properties *********************************************************)
  44
  45 lemma fpbs_refl:
  46       tri_reflexive … fpbs.
  47 /2 width=1 by tri_inj/ qed.
  48
  49 lemma fpbq_fpbs:
  50       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≽ ❪G2,L2,T2❫ →
  51       ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  52 /2 width=1 by tri_inj/ qed.
  53
  54 lemma fpbs_strap1:
  55       ∀G1,G,G2,L1,L,L2,T1,T,T2. ❪G1,L1,T1❫ ≥ ❪G,L,T❫ →
  56       ❪G,L,T❫ ≽ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  57 /2 width=5 by tri_step/ qed-.
  58
  59 lemma fpbs_strap2:
  60       ∀G1,G,G2,L1,L,L2,T1,T,T2. ❪G1,L1,T1❫ ≽ ❪G,L,T❫ →
  61       ❪G,L,T❫ ≥ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  62 /2 width=5 by tri_TC_strap/ qed-.
  63
  64 (* Basic_2A1: uses: lleq_fpbs fleq_fpbs *)
  65 lemma feqx_fpbs:
  66       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≅ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  67 /3 width=1 by fpbq_fpbs, fpbq_feqx/ qed.
  68
  69 (* Basic_2A1: uses: fpbs_lleq_trans *)
  70 lemma fpbs_feqx_trans:
  71       ∀G1,G,L1,L,T1,T. ❪G1,L1,T1❫ ≥ ❪G,L,T❫ →
  72       ∀G2,L2,T2. ❪G,L,T❫ ≅ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  73 /3 width=9 by fpbs_strap1, fpbq_feqx/ qed-.
  74
  75 (* Basic_2A1: uses: lleq_fpbs_trans *)
  76 lemma feqx_fpbs_trans:
  77       ∀G,G2,L,L2,T,T2. ❪G,L,T❫ ≥ ❪G2,L2,T2❫ →
  78       ∀G1,L1,T1. ❪G1,L1,T1❫ ≅ ❪G,L,T❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  79 /3 width=5 by fpbs_strap2, fpbq_feqx/ qed-.
  80
  81 lemma teqx_reqx_lpx_fpbs:
  82       ∀T1,T2. T1 ≅ T2 → ∀L1,L0. L1 ≅[T2] L0 →
  83       ∀G,L2. ❪G,L0❫ ⊢ ⬈ L2 → ❪G,L1,T1❫ ≥ ❪G,L2,T2❫.
  84 /4 width=5 by feqx_fpbs, fpbs_strap1, fpbq_lpx, feqg_intro_dx/ qed.
  85
  86 (* Basic_2A1: removed theorems 3:
  87               fpb_fpbsa_trans fpbs_fpbsa fpbsa_inv_fpbs
  88 *)