matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbs_fqup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/fpb_fqup.ma".
  16 include "basic_2/rt_computation/fpbs.ma".
  17
  18 (* PARALLEL RST-COMPUTATION FOR CLOSURES ************************************)
  19
  20 (* Advanced eliminators *****************************************************)
  21
  22 lemma fpbs_ind:
  23       ∀G1,L1,T1. ∀Q:relation3 genv lenv term. Q G1 L1 T1 →
  24       (∀G,G2,L,L2,T,T2. ❨G1,L1,T1❩ ≥ ❨G,L,T❩ → ❨G,L,T❩ ≽ ❨G2,L2,T2❩ → Q G L T → Q G2 L2 T2) →
  25       ∀G2,L2,T2. ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩ → Q G2 L2 T2.
  26 /3 width=8 by tri_TC_star_ind/ qed-.
  27
  28 lemma fpbs_ind_dx:
  29       ∀G2,L2,T2. ∀Q:relation3 genv lenv term. Q G2 L2 T2 →
  30       (∀G1,G,L1,L,T1,T. ❨G1,L1,T1❩ ≽ ❨G,L,T❩ → ❨G,L,T❩ ≥ ❨G2,L2,T2❩ → Q G L T → Q G1 L1 T1) →
  31       ∀G1,L1,T1. ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩ → Q G1 L1 T1.
  32 /3 width=8 by tri_TC_star_ind_dx/ qed-.
  33
  34 (* Advanced properties ******************************************************)
  35
  36 lemma fpbs_refl:
  37       tri_reflexive … fpbs.
  38 /2 width=1 by tri_inj/ qed.
  39
  40 (* Properties with plus-iterated structural successor for closures **********)
  41
  42 lemma fqup_fpbs:
  43       ∀G1,G2,L1,L2,T1,T2. ❨G1,L1,T1❩ ⬂+ ❨G2,L2,T2❩ → ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩.
  44 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  45 /4 width=5 by fqu_fquq, fquq_fpb, tri_step/
  46 qed.
  47
  48 lemma fpbs_fqup_trans:
  49       ∀G1,G,L1,L,T1,T. ❨G1,L1,T1❩ ≥ ❨G,L,T❩ →
  50       ∀G2,L2,T2. ❨G,L,T❩ ⬂+ ❨G2,L2,T2❩ → ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩.
  51 #G1 #G #L1 #L #T1 #T #H1 #G2 #L2 #T2 #H @(fqup_ind … H) -G2 -L2 -T2
  52 /3 width=5 by fpbs_strap1, fqu_fpb/
  53 qed-.
  54
  55 lemma fqup_fpbs_trans:
  56       ∀G,G2,L,L2,T,T2. ❨G,L,T❩ ≥ ❨G2,L2,T2❩ →
  57       ∀G1,L1,T1. ❨G1,L1,T1❩ ⬂+ ❨G,L,T❩ → ❨G1,L1,T1❩ ≥ ❨G2,L2,T2❩.
  58 #G #G2 #L #L2 #T #T2 #H1 #G1 #L1 #T1 #H @(fqup_ind_dx … H) -G1 -L1 -T1
  59 /3 width=9 by fpbs_strap2, fqu_fpb/
  60 qed-.