matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbs_lfpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/ffdeq_fqus.ma".
  16 include "basic_2/static/ffdeq_ffdeq.ma".
  17 include "basic_2/rt_computation/cpxs_fqus.ma".
  18 include "basic_2/rt_computation/cpxs_ffdeq.ma".
  19 include "basic_2/rt_computation/cpxs_lfpx.ma".
  20 include "basic_2/rt_computation/lfpxs_ffdeq.ma".
  21 include "basic_2/rt_computation/fpbs_cpxs.ma".
  22
  23 (* PARALLEL RST-COMPUTATION FOR CLOSURES ************************************)
  24
  25 (* Properties with uncounted parallel rt-computation on referred entries ****)
  26
  27 (* Basic_2A1: uses: lpxs_fpbs *)
  28 lemma lfpxs_fpbs: ∀h,o,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈*[h, T] L2 → ⦃G, L1, T⦄ ≥[h, o] ⦃G, L2, T⦄.
  29 #h #o #G #L1 #L2 #T #H @(lfpxs_ind_sn … H) -L2
  30 /3 width=5 by fpbq_lfpx, fpbs_strap1/
  31 qed.
  32
  33 (* Basic_2A1: uses: fpbs_lpxs_trans *)
  34 lemma fpbs_lfpxs_trans: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L, T2⦄ →
  35                         ∀L2. ⦃G2, L⦄ ⊢ ⬈*[h, T2] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  36 #h #o #G1 #G2 #L1 #L #T1 #T2 #H1 #L2 #H @(lfpxs_ind_sn … H) -L2
  37 /3 width=5 by fpbs_strap1, fpbq_lfpx/
  38 qed-.
  39
  40 (* Basic_2A1: uses: lpxs_fpbs_trans *)
  41 lemma lfpxs_fpbs_trans: ∀h,o,G1,G2,L,L2,T1,T2. ⦃G1, L, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ →
  42                         ∀L1. ⦃G1, L1⦄ ⊢ ⬈*[h, T1] L → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  43 #h #o #G1 #G2 #L #L2 #T1 #T2 #H1 #L1 #H @(lfpxs_ind_dx … H) -L1
  44 /3 width=5 by fpbs_strap2, fpbq_lfpx/
  45 qed-.
  46
  47 (* Basic_2A1: uses: lpxs_lleq_fpbs *)
  48 lemma lfpxs_ffdeq_fpbs: ∀h,o,G1,L1,L,T1. ⦃G1, L1⦄ ⊢ ⬈*[h, T1] L →
  49                         ∀G2,L2,T2. ⦃G1, L, T1⦄ ≛[h, o] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  50 /3 width=3 by lfpxs_fpbs_trans, ffdeq_fpbs/ qed.
  51
  52 (* Properties with star-iterated structural successor for closures **********)
  53
  54 (* Basic_2A1: uses: fqus_lpxs_fpbs *)
  55 lemma fqus_lfpxs_fpbs: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L, T2⦄ →
  56                        ∀L2. ⦃G2, L⦄ ⊢ ⬈*[h, T2] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  57 /3 width=3 by fpbs_lfpxs_trans, fqus_fpbs/ qed.
  58
  59 (* Properties with uncounted context-sensitive parallel rt-computation ******)
  60
  61 (* Basic_2A1: uses: cpxs_fqus_lpxs_fpbs *)
  62 lemma cpxs_fqus_lfpxs_fpbs: ∀h,o,G1,L1,T1,T. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T →
  63                             ∀G2,L,T2. ⦃G1, L1, T⦄ ⊐* ⦃G2, L, T2⦄ →
  64                             ∀L2.⦃G2, L⦄ ⊢ ⬈*[h, T2] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  65 /3 width=5 by cpxs_fqus_fpbs, fpbs_lfpxs_trans/ qed.
  66
  67 (* Advanced properties ******************************************************)
  68
  69 lemma fpbs_intro_fstar: ∀h,o,G1,L1,T1,T. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T →
  70                         ∀G,L,T0. ⦃G1, L1, T⦄ ⊐* ⦃G, L, T0⦄ →
  71                         ∀L0. ⦃G, L⦄ ⊢ ⬈*[h, T0] L0 →
  72                         ∀G2,L2,T2. ⦃G, L0, T0⦄ ≛[h, o] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ .
  73 /3 width=5 by cpxs_fqus_lfpxs_fpbs, fpbs_strap1, fpbq_ffdeq/ qed.
  74
  75 (* Advanced inversion lemmas *************************************************)
  76
  77 lemma fpbs_inv_fstar: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ →
  78                       ∃∃G,L,L0,T,T0. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T & ⦃G1, L1, T⦄ ⊐* ⦃G, L, T0⦄
  79                                    & ⦃G, L⦄ ⊢ ⬈*[h, T0] L0 & ⦃G, L0, T0⦄ ≛[h, o] ⦃G2, L2, T2⦄.
  80 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind_dx … H) -G1 -L1 -T1
  81 [ /2 width=9 by ex4_5_intro/
  82 | #G1 #G0 #L1 #L0 #T1 #T0 * -G0 -L0 -T0
  83   [ #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  84     elim (fquq_cpxs_trans … HT03 … H10) -T0
  85     /3 width=9 by fqus_strap2, ex4_5_intro/
  86   | #T0 #HT10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  87     /3 width=9 by cpxs_strap2, ex4_5_intro/
  88   | #L0 #HL10 #_ * #G3 #L3 #L4 #T3 #T4 #HT13 #H34 #HL34 #H42
  89     lapply (lfpx_cpxs_trans … HT13 … HL10) -HT13 #HT13
  90     lapply (lfpx_cpxs_conf … HT13 … HL10) -HL10 #HL10
  91     elim (lfpx_fqus_trans … H34 … HL10) -L0
  92     /3 width=9 by lfpxs_step_sn, cpxs_trans, ex4_5_intro/
  93   | #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  94     elim (ffdeq_cpxs_trans … H10 … HT03) -T0 #T0 #HT10 #H03
  95     elim (ffdeq_fqus_trans … H03 … H34) -G0 -L0 -T3 #G0 #L0 #T3 #H03 #H34
  96     elim (ffdeq_lfpxs_trans … H34 … HL34) -L3 #L3 #HL03 #H34
  97     /3 width=13 by ffdeq_trans, ex4_5_intro/
  98   ]
  99 ]
 100 qed-.