matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbs_lfpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/ffdeq_fqup.ma".
  16 include "basic_2/static/ffdeq_fqus.ma".
  17 include "basic_2/static/ffdeq_ffdeq.ma".
  18 include "basic_2/rt_computation/cpxs_fqus.ma".
  19 include "basic_2/rt_computation/cpxs_ffdeq.ma".
  20 include "basic_2/rt_computation/cpxs_lfpx.ma".
  21 include "basic_2/rt_computation/lfpxs_ffdeq.ma".
  22 include "basic_2/rt_computation/fpbs_cpxs.ma".
  23
  24 (* PARALLEL RST-COMPUTATION FOR CLOSURES ************************************)
  25
  26 (* Properties with uncounted parallel rt-computation on referred entries ****)
  27
  28 (* Basic_2A1: uses: lpxs_fpbs *)
  29 lemma lfpxs_fpbs: ∀h,o,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈*[h, T] L2 → ⦃G, L1, T⦄ ≥[h, o] ⦃G, L2, T⦄.
  30 #h #o #G #L1 #L2 #T #H @(lfpxs_ind_sn … H) -L2
  31 /3 width=5 by fpbq_lfpx, fpbs_strap1/
  32 qed.
  33
  34 (* Basic_2A1: uses: fpbs_lpxs_trans *)
  35 lemma fpbs_lfpxs_trans: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L, T2⦄ →
  36                         ∀L2. ⦃G2, L⦄ ⊢ ⬈*[h, T2] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  37 #h #o #G1 #G2 #L1 #L #T1 #T2 #H1 #L2 #H @(lfpxs_ind_sn … H) -L2
  38 /3 width=5 by fpbs_strap1, fpbq_lfpx/
  39 qed-.
  40
  41 (* Basic_2A1: uses: lpxs_fpbs_trans *)
  42 lemma lfpxs_fpbs_trans: ∀h,o,G1,G2,L,L2,T1,T2. ⦃G1, L, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ →
  43                         ∀L1. ⦃G1, L1⦄ ⊢ ⬈*[h, T1] L → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  44 #h #o #G1 #G2 #L #L2 #T1 #T2 #H1 #L1 #H @(lfpxs_ind_dx … H) -L1
  45 /3 width=5 by fpbs_strap2, fpbq_lfpx/
  46 qed-.
  47
  48 (* Basic_2A1: uses: lpxs_lleq_fpbs *)
  49 lemma lpxs_ffdeq_fpbs: ∀h,o,G1,L1,L,T1. ⦃G1, L1⦄ ⊢ ⬈*[h, T1] L →
  50                        ∀G2,L2,T2. ⦃G1, L, T1⦄ ≛[h, o] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  51 /3 width=3 by lfpxs_fpbs_trans, ffdeq_fpbs/ qed.
  52
  53 (* Properties with star-iterated structural successor for closures **********)
  54
  55 (* Basic_2A1: uses: fqus_lpxs_fpbs *)
  56 lemma fqus_lfpxs_fpbs: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L, T2⦄ →
  57                        ∀L2. ⦃G2, L⦄ ⊢ ⬈*[h, T2] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  58 /3 width=3 by fpbs_lfpxs_trans, fqus_fpbs/ qed.
  59
  60 (* Properties with uncounted context-sensitive parallel rt-computation ******)
  61
  62 (* Basic_2A1: uses: cpxs_fqus_lpxs_fpbs *)
  63 lemma cpxs_fqus_lfpxs_fpbs: ∀h,o,G1,L1,T1,T. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T →
  64                             ∀G2,L,T2. ⦃G1, L1, T⦄ ⊐* ⦃G2, L, T2⦄ →
  65                             ∀L2.⦃G2, L⦄ ⊢ ⬈*[h, T2] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  66 /3 width=5 by cpxs_fqus_fpbs, fpbs_lfpxs_trans/ qed.
  67
  68 (* Advanced properties ******************************************************)
  69
  70 (* Basic_2A1: uses: fpbs_intro_alt *)
  71 lemma fpbs_intro_star: ∀h,o,G1,L1,T1,T. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T →
  72                        ∀G,L,T0. ⦃G1, L1, T⦄ ⊐* ⦃G, L, T0⦄ →
  73                        ∀L0. ⦃G, L⦄ ⊢ ⬈*[h, T0] L0 →
  74                        ∀G2,L2,T2. ⦃G, L0, T0⦄ ≛[h, o] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ .
  75 /3 width=5 by cpxs_fqus_lfpxs_fpbs, fpbs_strap1, fpbq_ffdeq/ qed.
  76
  77 (* Advanced inversion lemmas *************************************************)
  78
  79 (* Basic_2A1: uses: fpbs_inv_alt *)
  80 lemma fpbs_inv_star: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ →
  81                      ∃∃G,L,L0,T,T0. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T & ⦃G1, L1, T⦄ ⊐* ⦃G, L, T0⦄
  82                                   & ⦃G, L⦄ ⊢ ⬈*[h, T0] L0 & ⦃G, L0, T0⦄ ≛[h, o] ⦃G2, L2, T2⦄.
  83 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind_dx … H) -G1 -L1 -T1
  84 [ /2 width=9 by ex4_5_intro/
  85 | #G1 #G0 #L1 #L0 #T1 #T0 * -G0 -L0 -T0
  86   [ #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  87     elim (fquq_cpxs_trans … HT03 … H10) -T0
  88     /3 width=9 by fqus_strap2, ex4_5_intro/
  89   | #T0 #HT10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  90     /3 width=9 by cpxs_strap2, ex4_5_intro/
  91   | #L0 #HL10 #_ * #G3 #L3 #L4 #T3 #T4 #HT13 #H34 #HL34 #H42
  92     lapply (lfpx_cpxs_trans … HT13 … HL10) -HT13 #HT13
  93     lapply (lfpx_cpxs_conf … HT13 … HL10) -HL10 #HL10
  94     elim (lfpx_fqus_trans … H34 … HL10) -L0
  95     /3 width=9 by lfpxs_step_sn, cpxs_trans, ex4_5_intro/
  96   | #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  97     elim (ffdeq_cpxs_trans … H10 … HT03) -T0 #T0 #HT10 #H03
  98     elim (ffdeq_fqus_trans … H03 … H34) -G0 -L0 -T3 #G0 #L0 #T3 #H03 #H34
  99     elim (ffdeq_lfpxs_trans … H34 … HL34) -L3 #L3 #HL03 #H34
 100     /3 width=13 by ffdeq_trans, ex4_5_intro/
 101   ]
 102 ]
 103 qed-.