matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbs_lpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/fdeq_fqus.ma".
  16 include "static_2/static/fdeq_fdeq.ma".
  17 include "basic_2/rt_computation/cpxs_fqus.ma".
  18 include "basic_2/rt_computation/cpxs_fdeq.ma".
  19 include "basic_2/rt_computation/lpxs_fdeq.ma".
  20 include "basic_2/rt_computation/fpbs_cpxs.ma".
  21
  22 (* PARALLEL RST-COMPUTATION FOR CLOSURES ************************************)
  23
  24 (* Properties with unbound rt-computation on full local environments  *******)
  25
  26 lemma lpxs_fpbs: ∀h,o,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈*[h] L2 → ⦃G, L1, T⦄ ≥[h, o] ⦃G, L2, T⦄.
  27 #h #o #G #L1 #L2 #T #H @(lpxs_ind_dx … H) -L2
  28 /3 width=5 by fpbq_lpx, fpbs_strap1/
  29 qed.
  30
  31 lemma fpbs_lpxs_trans: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L, T2⦄ →
  32                        ∀L2. ⦃G2, L⦄ ⊢ ⬈*[h] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  33 #h #o #G1 #G2 #L1 #L #T1 #T2 #H1 #L2 #H @(lpxs_ind_dx … H) -L2
  34 /3 width=5 by fpbs_strap1, fpbq_lpx/
  35 qed-.
  36
  37 lemma lpxs_fpbs_trans: ∀h,o,G1,G2,L,L2,T1,T2. ⦃G1, L, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ →
  38                        ∀L1. ⦃G1, L1⦄ ⊢ ⬈*[h] L → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  39 #h #o #G1 #G2 #L #L2 #T1 #T2 #H1 #L1 #H @(lpxs_ind_sn … H) -L1
  40 /3 width=5 by fpbs_strap2, fpbq_lpx/
  41 qed-.
  42
  43 (* Basic_2A1: uses: lpxs_lleq_fpbs *)
  44 lemma lpxs_fdeq_fpbs: ∀h,o,G1,L1,L,T1. ⦃G1, L1⦄ ⊢ ⬈*[h] L →
  45                       ∀G2,L2,T2. ⦃G1, L, T1⦄ ≛[h, o] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  46 /3 width=3 by lpxs_fpbs_trans, fdeq_fpbs/ qed.
  47
  48 lemma fpbs_lpx_trans: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L, T2⦄ →
  49                       ∀L2. ⦃G2, L⦄ ⊢ ⬈[h] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  50 /3 width=3 by fpbs_lpxs_trans, lpx_lpxs/ qed-.
  51
  52 (* Properties with star-iterated structural successor for closures **********)
  53
  54 lemma fqus_lpxs_fpbs: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L, T2⦄ →
  55                       ∀L2. ⦃G2, L⦄ ⊢ ⬈*[h] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  56 /3 width=3 by fpbs_lpxs_trans, fqus_fpbs/ qed.
  57
  58 (* Properties with unbound context-sensitive parallel rt-computation ********)
  59
  60 lemma cpxs_fqus_lpxs_fpbs: ∀h,o,G1,L1,T1,T. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T →
  61                            ∀G2,L,T2. ⦃G1, L1, T⦄ ⊐* ⦃G2, L, T2⦄ →
  62                            ∀L2.⦃G2, L⦄ ⊢ ⬈*[h] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  63 /3 width=5 by cpxs_fqus_fpbs, fpbs_lpxs_trans/ qed.
  64
  65 lemma fpbs_cpxs_tdeq_fqup_lpx_trans: ∀h,o,G1,G3,L1,L3,T1,T3. ⦃G1, L1, T1⦄ ≥ [h, o] ⦃G3, L3, T3⦄ →
  66                                      ∀T4. ⦃G3, L3⦄ ⊢ T3 ⬈*[h] T4 → ∀T5. T4 ≛[h, o] T5 →
  67                                      ∀G2,L4,T2. ⦃G3, L3, T5⦄ ⊐+ ⦃G2, L4, T2⦄ →
  68                                      ∀L2. ⦃G2, L4⦄ ⊢ ⬈[h] L2 → ⦃G1, L1, T1⦄ ≥ [h, o] ⦃G2, L2, T2⦄.
  69 #h #o #G1 #G3 #L1 #L3 #T1 #T3 #H13 #T4 #HT34 #T5 #HT45 #G2 #L4 #T2 #H34 #L2 #HL42
  70 @(fpbs_lpx_trans … HL42) -L2 (**) (* full auto too slow *)
  71 @(fpbs_fqup_trans … H34) -G2 -L4 -T2
  72 /3 width=3 by fpbs_cpxs_trans, fpbs_tdeq_trans/
  73 qed-.
  74
  75 (* Advanced properties ******************************************************)
  76
  77 (* Basic_2A1: uses: fpbs_intro_alt *)
  78 lemma fpbs_intro_star: ∀h,o,G1,L1,T1,T. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T →
  79                        ∀G,L,T0. ⦃G1, L1, T⦄ ⊐* ⦃G, L, T0⦄ →
  80                        ∀L0. ⦃G, L⦄ ⊢ ⬈*[h] L0 →
  81                        ∀G2,L2,T2. ⦃G, L0, T0⦄ ≛[h, o] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ .
  82 /3 width=5 by cpxs_fqus_lpxs_fpbs, fpbs_strap1, fpbq_fdeq/ qed.
  83
  84 (* Advanced inversion lemmas *************************************************)
  85
  86 (* Basic_2A1: uses: fpbs_inv_alt *)
  87 lemma fpbs_inv_star: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ →
  88                      ∃∃G,L,L0,T,T0. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T & ⦃G1, L1, T⦄ ⊐* ⦃G, L, T0⦄
  89                                   & ⦃G, L⦄ ⊢ ⬈*[h] L0 & ⦃G, L0, T0⦄ ≛[h, o] ⦃G2, L2, T2⦄.
  90 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind_dx … H) -G1 -L1 -T1
  91 [ /2 width=9 by ex4_5_intro/
  92 | #G1 #G0 #L1 #L0 #T1 #T0 * -G0 -L0 -T0
  93   [ #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  94     elim (fquq_cpxs_trans … HT03 … H10) -T0
  95     /3 width=9 by fqus_strap2, ex4_5_intro/
  96   | #T0 #HT10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  97     /3 width=9 by cpxs_strap2, ex4_5_intro/
  98   | #L0 #HL10 #_ * #G3 #L3 #L4 #T3 #T4 #HT13 #H34 #HL34 #H42
  99     lapply (lpx_cpxs_trans … HT13 … HL10) -HT13 #HT13
 100     elim (lpx_fqus_trans … H34 … HL10) -L0
 101     /3 width=9 by lpxs_step_sn, cpxs_trans, ex4_5_intro/
 102   | #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
 103     elim (fdeq_cpxs_trans … H10 … HT03) -T0 #T0 #HT10 #H03
 104     elim (fdeq_fqus_trans … H03 … H34) -G0 -L0 -T3 #G0 #L0 #T3 #H03 #H34
 105     elim (fdeq_lpxs_trans … H34 … HL34) -L3 #L3 #HL03 #H34
 106     /3 width=13 by fdeq_trans, ex4_5_intro/
 107   ]
 108 ]
 109 qed-.