matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbs_lpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/feqx_fqus.ma".
  16 include "static_2/static/feqx_feqx.ma".
  17 include "basic_2/rt_computation/cpxs_fqus.ma".
  18 include "basic_2/rt_computation/cpxs_feqx.ma".
  19 include "basic_2/rt_computation/lpxs_feqx.ma".
  20 include "basic_2/rt_computation/fpbs_cpxs.ma".
  21
  22 (* PARALLEL RST-COMPUTATION FOR CLOSURES ************************************)
  23
  24 (* Properties with extended rt-computation on full local environments  ******)
  25
  26 lemma lpxs_fpbs:
  27       ∀G,L1,L2,T. ❪G,L1❫ ⊢ ⬈* L2 → ❪G,L1,T❫ ≥ ❪G,L2,T❫.
  28 #G #L1 #L2 #T #H @(lpxs_ind_dx … H) -L2
  29 /3 width=5 by fpbq_lpx, fpbs_strap1/
  30 qed.
  31
  32 lemma fpbs_lpxs_trans:
  33       ∀G1,G2,L1,L,T1,T2. ❪G1,L1,T1❫ ≥ ❪G2,L,T2❫ →
  34       ∀L2. ❪G2,L❫ ⊢ ⬈* L2 → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  35 #G1 #G2 #L1 #L #T1 #T2 #H1 #L2 #H @(lpxs_ind_dx … H) -L2
  36 /3 width=5 by fpbs_strap1, fpbq_lpx/
  37 qed-.
  38
  39 lemma lpxs_fpbs_trans:
  40       ∀G1,G2,L,L2,T1,T2. ❪G1,L,T1❫ ≥ ❪G2,L2,T2❫ →
  41       ∀L1. ❪G1,L1❫ ⊢ ⬈* L → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  42 #G1 #G2 #L #L2 #T1 #T2 #H1 #L1 #H @(lpxs_ind_sn … H) -L1
  43 /3 width=5 by fpbs_strap2, fpbq_lpx/
  44 qed-.
  45
  46 (* Basic_2A1: uses: lpxs_lleq_fpbs *)
  47 lemma lpxs_feqx_fpbs:
  48       ∀G1,L1,L,T1. ❪G1,L1❫ ⊢ ⬈* L →
  49       ∀G2,L2,T2. ❪G1,L,T1❫ ≛ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  50 /3 width=3 by lpxs_fpbs_trans, feqx_fpbs/ qed.
  51
  52 lemma fpbs_lpx_trans:
  53       ∀G1,G2,L1,L,T1,T2. ❪G1,L1,T1❫ ≥ ❪G2,L,T2❫ →
  54       ∀L2. ❪G2,L❫ ⊢ ⬈ L2 → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  55 /3 width=3 by fpbs_lpxs_trans, lpx_lpxs/ qed-.
  56
  57 (* Properties with star-iterated structural successor for closures **********)
  58
  59 lemma fqus_lpxs_fpbs:
  60       ∀G1,G2,L1,L,T1,T2. ❪G1,L1,T1❫ ⬂* ❪G2,L,T2❫ →
  61       ∀L2. ❪G2,L❫ ⊢ ⬈* L2 → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  62 /3 width=3 by fpbs_lpxs_trans, fqus_fpbs/ qed.
  63
  64 (* Properties with extended context-sensitive parallel rt-computation *******)
  65
  66 lemma cpxs_fqus_lpxs_fpbs:
  67       ∀G1,L1,T1,T. ❪G1,L1❫ ⊢ T1 ⬈* T →
  68       ∀G2,L,T2. ❪G1,L1,T❫ ⬂* ❪G2,L,T2❫ →
  69       ∀L2.❪G2,L❫ ⊢ ⬈* L2 → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫.
  70 /3 width=5 by cpxs_fqus_fpbs, fpbs_lpxs_trans/ qed.
  71
  72 lemma fpbs_cpxs_teqx_fqup_lpx_trans:
  73       ∀G1,G3,L1,L3,T1,T3. ❪G1,L1,T1❫ ≥  ❪G3,L3,T3❫ →
  74       ∀T4. ❪G3,L3❫ ⊢ T3 ⬈* T4 → ∀T5. T4 ≛ T5 →
  75       ∀G2,L4,T2. ❪G3,L3,T5❫ ⬂+ ❪G2,L4,T2❫ →
  76       ∀L2. ❪G2,L4❫ ⊢ ⬈ L2 → ❪G1,L1,T1❫ ≥  ❪G2,L2,T2❫.
  77 #G1 #G3 #L1 #L3 #T1 #T3 #H13 #T4 #HT34 #T5 #HT45 #G2 #L4 #T2 #H34 #L2 #HL42
  78 @(fpbs_lpx_trans … HL42) -L2 (**) (* full auto too slow *)
  79 @(fpbs_fqup_trans … H34) -G2 -L4 -T2
  80 /3 width=3 by fpbs_cpxs_trans, fpbs_teqx_trans/
  81 qed-.
  82
  83 (* Advanced properties ******************************************************)
  84
  85 (* Basic_2A1: uses: fpbs_intro_alt *)
  86 lemma fpbs_intro_star:
  87       ∀G1,L1,T1,T. ❪G1,L1❫ ⊢ T1 ⬈* T →
  88       ∀G,L,T0. ❪G1,L1,T❫ ⬂* ❪G,L,T0❫ →
  89       ∀L0. ❪G,L❫ ⊢ ⬈* L0 →
  90       ∀G2,L2,T2. ❪G,L0,T0❫ ≛ ❪G2,L2,T2❫ → ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫ .
  91 /3 width=5 by cpxs_fqus_lpxs_fpbs, fpbs_strap1, fpbq_feqx/ qed.
  92
  93 (* Advanced inversion lemmas *************************************************)
  94
  95 (* Basic_2A1: uses: fpbs_inv_alt *)
  96 lemma fpbs_inv_star:
  97       ∀G1,G2,L1,L2,T1,T2. ❪G1,L1,T1❫ ≥ ❪G2,L2,T2❫ →
  98       ∃∃G,L,L0,T,T0. ❪G1,L1❫ ⊢ T1 ⬈* T & ❪G1,L1,T❫ ⬂* ❪G,L,T0❫ & ❪G,L❫ ⊢ ⬈* L0 & ❪G,L0,T0❫ ≛ ❪G2,L2,T2❫.
  99 #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind_dx … H) -G1 -L1 -T1
 100 [ /2 width=9 by ex4_5_intro/
 101 | #G1 #G0 #L1 #L0 #T1 #T0 * -G0 -L0 -T0
 102   [ #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
 103     elim (fquq_cpxs_trans … HT03 … H10) -T0
 104     /3 width=9 by fqus_strap2, ex4_5_intro/
 105   | #T0 #HT10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
 106     /3 width=9 by cpxs_strap2, ex4_5_intro/
 107   | #L0 #HL10 #_ * #G3 #L3 #L4 #T3 #T4 #HT13 #H34 #HL34 #H42
 108     lapply (lpx_cpxs_trans … HT13 … HL10) -HT13 #HT13
 109     elim (lpx_fqus_trans … H34 … HL10) -L0
 110     /3 width=9 by lpxs_step_sn, cpxs_trans, ex4_5_intro/
 111   | #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
 112     elim (feqx_cpxs_trans … H10 … HT03) -T0 #T0 #HT10 #H03
 113     elim (feqx_fqus_trans … H03 … H34) -G0 -L0 -T3 #G0 #L0 #T3 #H03 #H34
 114     elim (feqx_lpxs_trans … H34 … HL34) -L3 #L3 #HL03 #H34
 115     /3 width=13 by feqx_trans, ex4_5_intro/
 116   ]
 117 ]
 118 qed-.