matita/matita/contribs/lambdadelta/basic_2/rt_computation/fpbs_lpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/ffdeq_fqus.ma".
  16 include "basic_2/static/ffdeq_ffdeq.ma".
  17 include "basic_2/rt_computation/cpxs_fqus.ma".
  18 include "basic_2/rt_computation/cpxs_ffdeq.ma".
  19 include "basic_2/rt_computation/lpxs_ffdeq.ma".
  20 include "basic_2/rt_computation/lpxs_lpx.ma".
  21 include "basic_2/rt_computation/fpbs_fqus.ma".
  22 include "basic_2/rt_computation/fpbs_cpxs.ma".
  23
  24 (* PARALLEL RST-COMPUTATION FOR CLOSURES ************************************)
  25
  26 (* Properties with unbound rt-computation on full local environments  *******)
  27
  28 lemma lpxs_fpbs: ∀h,o,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈*[h] L2 → ⦃G, L1, T⦄ ≥[h, o] ⦃G, L2, T⦄.
  29 #h #o #G #L1 #L2 #T #H @(lpxs_ind_dx … H) -L2
  30 /3 width=5 by fpbq_lpx, fpbs_strap1/
  31 qed.
  32
  33 lemma fpbs_lpxs_trans: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L, T2⦄ →
  34                        ∀L2. ⦃G2, L⦄ ⊢ ⬈*[h] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  35 #h #o #G1 #G2 #L1 #L #T1 #T2 #H1 #L2 #H @(lpxs_ind_dx … H) -L2
  36 /3 width=5 by fpbs_strap1, fpbq_lpx/
  37 qed-.
  38
  39 lemma lpxs_fpbs_trans: ∀h,o,G1,G2,L,L2,T1,T2. ⦃G1, L, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ →
  40                        ∀L1. ⦃G1, L1⦄ ⊢ ⬈*[h] L → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  41 #h #o #G1 #G2 #L #L2 #T1 #T2 #H1 #L1 #H @(lpxs_ind_sn … H) -L1
  42 /3 width=5 by fpbs_strap2, fpbq_lpx/
  43 qed-.
  44
  45 (* Basic_2A1: uses: lpxs_lleq_fpbs *)
  46 lemma lpxs_ffdeq_fpbs: ∀h,o,G1,L1,L,T1. ⦃G1, L1⦄ ⊢ ⬈*[h] L →
  47                        ∀G2,L2,T2. ⦃G1, L, T1⦄ ≛[h, o] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  48 /3 width=3 by lpxs_fpbs_trans, ffdeq_fpbs/ qed.
  49
  50 lemma fpbs_lpx_trans: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L, T2⦄ →
  51                       ∀L2. ⦃G2, L⦄ ⊢ ⬈[h] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  52 /3 width=3 by fpbs_lpxs_trans, lpx_lpxs/ qed-.
  53
  54 (* Properties with star-iterated structural successor for closures **********)
  55
  56 lemma fqus_lpxs_fpbs: ∀h,o,G1,G2,L1,L,T1,T2. ⦃G1, L1, T1⦄ ⊐* ⦃G2, L, T2⦄ →
  57                       ∀L2. ⦃G2, L⦄ ⊢ ⬈*[h] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  58 /3 width=3 by fpbs_lpxs_trans, fqus_fpbs/ qed.
  59
  60 (* Properties with unbound context-sensitive parallel rt-computation ********)
  61
  62 lemma cpxs_fqus_lpxs_fpbs: ∀h,o,G1,L1,T1,T. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T →
  63                            ∀G2,L,T2. ⦃G1, L1, T⦄ ⊐* ⦃G2, L, T2⦄ →
  64                            ∀L2.⦃G2, L⦄ ⊢ ⬈*[h] L2 → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄.
  65 /3 width=5 by cpxs_fqus_fpbs, fpbs_lpxs_trans/ qed.
  66
  67 lemma fpbs_cpxs_tdeq_fqup_lpx_trans: ∀h,o,G1,G3,L1,L3,T1,T3. ⦃G1, L1, T1⦄ ≥ [h, o] ⦃G3, L3, T3⦄ →
  68                                      ∀T4. ⦃G3, L3⦄ ⊢ T3 ⬈*[h] T4 → ∀T5. T4 ≛[h, o] T5 →
  69                                      ∀G2,L4,T2. ⦃G3, L3, T5⦄ ⊐+ ⦃G2, L4, T2⦄ →
  70                                      ∀L2. ⦃G2, L4⦄ ⊢ ⬈[h] L2 → ⦃G1, L1, T1⦄ ≥ [h, o] ⦃G2, L2, T2⦄.
  71 #h #o #G1 #G3 #L1 #L3 #T1 #T3 #H13 #T4 #HT34 #T5 #HT45 #G2 #L4 #T2 #H34 #L2 #HL42
  72 @(fpbs_lpx_trans … HL42) -L2 (**) (* full auto too slow *)
  73 @(fpbs_fqup_trans … H34) -G2 -L4 -T2
  74 /3 width=3 by fpbs_cpxs_trans, fpbs_tdeq_trans/
  75 qed-.
  76
  77 (* Advanced properties ******************************************************)
  78
  79 (* Basic_2A1: uses: fpbs_intro_alt *)
  80 lemma fpbs_intro_star: ∀h,o,G1,L1,T1,T. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T →
  81                        ∀G,L,T0. ⦃G1, L1, T⦄ ⊐* ⦃G, L, T0⦄ →
  82                        ∀L0. ⦃G, L⦄ ⊢ ⬈*[h] L0 →
  83                        ∀G2,L2,T2. ⦃G, L0, T0⦄ ≛[h, o] ⦃G2, L2, T2⦄ → ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ .
  84 /3 width=5 by cpxs_fqus_lpxs_fpbs, fpbs_strap1, fpbq_ffdeq/ qed.
  85
  86 (* Advanced inversion lemmas *************************************************)
  87
  88 (* Basic_2A1: uses: fpbs_inv_alt *)
  89 lemma fpbs_inv_star: ∀h,o,G1,G2,L1,L2,T1,T2. ⦃G1, L1, T1⦄ ≥[h, o] ⦃G2, L2, T2⦄ →
  90                      ∃∃G,L,L0,T,T0. ⦃G1, L1⦄ ⊢ T1 ⬈*[h] T & ⦃G1, L1, T⦄ ⊐* ⦃G, L, T0⦄
  91                                   & ⦃G, L⦄ ⊢ ⬈*[h] L0 & ⦃G, L0, T0⦄ ≛[h, o] ⦃G2, L2, T2⦄.
  92 #h #o #G1 #G2 #L1 #L2 #T1 #T2 #H @(fpbs_ind_dx … H) -G1 -L1 -T1
  93 [ /2 width=9 by ex4_5_intro/
  94 | #G1 #G0 #L1 #L0 #T1 #T0 * -G0 -L0 -T0
  95   [ #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  96     elim (fquq_cpxs_trans … HT03 … H10) -T0
  97     /3 width=9 by fqus_strap2, ex4_5_intro/
  98   | #T0 #HT10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
  99     /3 width=9 by cpxs_strap2, ex4_5_intro/
 100   | #L0 #HL10 #_ * #G3 #L3 #L4 #T3 #T4 #HT13 #H34 #HL34 #H42
 101     lapply (lpx_cpxs_trans … HT13 … HL10) -HT13 #HT13
 102     elim (lpx_fqus_trans … H34 … HL10) -L0
 103     /3 width=9 by lpxs_step_sn, cpxs_trans, ex4_5_intro/
 104   | #G0 #L0 #T0 #H10 #_ * #G3 #L3 #L4 #T3 #T4 #HT03 #H34 #HL34 #H42
 105     elim (ffdeq_cpxs_trans … H10 … HT03) -T0 #T0 #HT10 #H03
 106     elim (ffdeq_fqus_trans … H03 … H34) -G0 -L0 -T3 #G0 #L0 #T3 #H03 #H34
 107     elim (ffdeq_lpxs_trans … H34 … HL34) -L3 #L3 #HL03 #H34
 108     /3 width=13 by ffdeq_trans, ex4_5_intro/
 109   ]
 110 ]
 111 qed-.