matita/matita/contribs/lambdadelta/basic_2/rt_computation/fsb.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predsubtystrong_3.ma".
  16 include "basic_2/rt_transition/fpbc.ma".
  17
  18 (* STRONGLY NORMALIZING CLOSURES FOR PARALLEL RST-TRANSITION ****************)
  19
  20 definition fsb: relation3 genv lenv term ≝
  21            SN3 … fpb (feqg sfull).
  22
  23 interpretation
  24   "strong normalization for parallel rst-transition (closure)"
  25   'PRedSubTyStrong G L T = (fsb G L T).
  26
  27 (* Basic properties *********************************************************)
  28
  29 lemma fsb_intro (G1) (L1) (T1):
  30       (∀G2,L2,T2. ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫ → ≥𝐒 ❪G2,L2,T2❫) → ≥𝐒 ❪G1,L1,T1❫.
  31 /5 width=1 by fpbc_intro, SN3_intro/ qed.
  32
  33 (* Basic eliminators ********************************************************)
  34
  35 (* Note: eliminator with shorter ground hypothesis *)
  36 lemma fsb_ind (Q:relation3 …):
  37       (∀G1,L1,T1. ≥𝐒 ❪G1,L1,T1❫ →
  38         (∀G2,L2,T2. ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫ → Q G2 L2 T2) →
  39         Q G1 L1 T1
  40       ) →
  41       ∀G,L,T. ≥𝐒 ❪G,L,T❫ → Q G L T.
  42 #Q #IH #G #L #T #H elim H -G -L -T
  43 #G1 #L1 #T1 #H1 #IH1
  44 @IH -IH [ /4 width=1 by SN3_intro/ ] -H1 #G2 #L2 #T2 #H
  45 elim (fpbc_inv_gen sfull … H) -H #H12 #Hn12 /3 width=1 by/
  46 qed-.
  47
  48 (* Basic_2A1: removed theorems 6:
  49               fsba_intro fsba_ind_alt fsba_fpbs_trans fsb_fsba fsba_inv_fsb
  50               aaa_fsba
  51 *)