matita/matita/contribs/lambdadelta/basic_2/rt_computation/fsb.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predsubtystrong_3.ma".
  16 include "basic_2/rt_transition/fpb.ma".
  17
  18 (* STRONGLY NORMALIZING CLOSURES FOR PARALLEL RST-TRANSITION ****************)
  19
  20 inductive fsb: relation3 genv lenv term ≝
  21 | fsb_intro: ∀G1,L1,T1.
  22              (∀G2,L2,T2. ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫ → fsb G2 L2 T2) →
  23              fsb G1 L1 T1
  24 .
  25
  26 interpretation
  27   "strong normalization for parallel rst-transition (closure)"
  28   'PRedSubTyStrong G L T = (fsb G L T).
  29
  30 (* Basic eliminators ********************************************************)
  31
  32 (* Note: eliminator with shorter ground hypothesis *)
  33 (* Note: to be named fsb_ind when fsb becomes a definition like csx, rsx ****)
  34 lemma fsb_ind_alt (Q:relation3 …):
  35       (∀G1,L1,T1. ≥𝐒 ❪G1,L1,T1❫ →
  36         (∀G2,L2,T2. ❪G1,L1,T1❫ ≻ ❪G2,L2,T2❫ → Q G2 L2 T2) →
  37         Q G1 L1 T1
  38       ) →
  39       ∀G,L,T. ≥𝐒 ❪G,L,T❫ → Q G L T.
  40 #Q #IH #G #L #T #H elim H -G -L -T
  41 /4 width=1 by fsb_intro/
  42 qed-.
  43
  44 (* Basic_2A1: removed theorems 6:
  45               fsba_intro fsba_ind_alt fsba_fpbs_trans fsb_fsba fsba_inv_fsb
  46               aaa_fsba
  47 *)