matita/matita/contribs/lambdadelta/basic_2/rt_computation/fsb_aaa.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/csx_aaa.ma".
  16 include "basic_2/rt_computation/fpbs_aaa.ma".
  17 include "basic_2/rt_computation/fpbs_fpb.ma".
  18 include "basic_2/rt_computation/fsb_csx.ma".
  19
  20 (* STRONGLY NORMALIZING CLOSURES FOR PARALLEL RST-TRANSITION ****************)
  21
  22 (* Main properties with atomic arity assignment for terms *******************)
  23
  24 (* Note: this is the "big tree" theorem *)
  25 theorem aaa_fsb: ∀h,G,L,T,A. ⦃G, L⦄ ⊢ T ⁝ A → ≥[h] 𝐒⦃G, L, T⦄.
  26 /3 width=2 by aaa_csx, csx_fsb/ qed.
  27
  28 (* Advanced eliminators with atomic arity assignment for terms **************)
  29
  30 fact aaa_ind_fpb_aux: ∀h. ∀Q:relation3 ….
  31                       (∀G1,L1,T1,A. ⦃G1, L1⦄ ⊢ T1 ⁝ A →
  32                                     (∀G2,L2,T2. ⦃G1, L1, T1⦄ ≻[h] ⦃G2, L2, T2⦄ → Q G2 L2 T2) →
  33                                     Q G1 L1 T1
  34                       ) →
  35                       ∀G,L,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄ → ∀A. ⦃G, L⦄ ⊢ T ⁝ A →  Q G L T.
  36 #h #R #IH #G #L #T #H @(csx_ind_fpb … H) -G -L -T
  37 #G1 #L1 #T1 #H1 #IH1 #A1 #HTA1 @IH -IH //
  38 #G2 #L2 #T2 #H12 elim (fpbs_aaa_conf … G2 … L2 … T2 … HTA1) -A1
  39 /2 width=2 by fpb_fpbs/
  40 qed-.
  41
  42 lemma aaa_ind_fpb: ∀h. ∀Q:relation3 ….
  43                    (∀G1,L1,T1,A. ⦃G1, L1⦄ ⊢ T1 ⁝ A →
  44                                  (∀G2,L2,T2. ⦃G1, L1, T1⦄ ≻[h] ⦃G2, L2, T2⦄ → Q G2 L2 T2) →
  45                                  Q G1 L1 T1
  46                    ) →
  47                    ∀G,L,T,A. ⦃G, L⦄ ⊢ T ⁝ A → Q G L T.
  48 /4 width=4 by aaa_ind_fpb_aux, aaa_csx/ qed-.
  49
  50 fact aaa_ind_fpbg_aux: ∀h. ∀Q:relation3 ….
  51                        (∀G1,L1,T1,A. ⦃G1, L1⦄ ⊢ T1 ⁝ A →
  52                                      (∀G2,L2,T2. ⦃G1, L1, T1⦄ >[h] ⦃G2, L2, T2⦄ → Q G2 L2 T2) →
  53                                      Q G1 L1 T1
  54                        ) →
  55                        ∀G,L,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄ → ∀A. ⦃G, L⦄ ⊢ T ⁝ A →  Q G L T.
  56 #h #Q #IH #G #L #T #H @(csx_ind_fpbg … H) -G -L -T
  57 #G1 #L1 #T1 #H1 #IH1 #A1 #HTA1 @IH -IH //
  58 #G2 #L2 #T2 #H12 elim (fpbs_aaa_conf … G2 … L2 … T2 … HTA1) -A1
  59 /2 width=2 by fpbg_fwd_fpbs/
  60 qed-.
  61
  62 lemma aaa_ind_fpbg: ∀h. ∀Q:relation3 ….
  63                     (∀G1,L1,T1,A. ⦃G1, L1⦄ ⊢ T1 ⁝ A →
  64                                   (∀G2,L2,T2. ⦃G1, L1, T1⦄ >[h] ⦃G2, L2, T2⦄ → Q G2 L2 T2) →
  65                                   Q G1 L1 T1
  66                     ) →
  67                     ∀G,L,T,A. ⦃G, L⦄ ⊢ T ⁝ A → Q G L T.
  68 /4 width=4 by aaa_ind_fpbg_aux, aaa_csx/ qed-.