matita/matita/contribs/lambdadelta/basic_2/rt_computation/fsb_csx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/rdsx_csx.ma".
  16 include "basic_2/rt_computation/fpbs_cpx.ma".
  17 include "basic_2/rt_computation/fpbs_csx.ma".
  18 include "basic_2/rt_computation/fsb_fpbg.ma".
  19
  20 (* STRONGLY NORMALIZING CLOSURES FOR PARALLEL RST-TRANSITION ****************)
  21
  22 (* Inversion lemmas with context-sensitive stringly rt-normalizing terms ****)
  23
  24 lemma fsb_inv_csx: ∀h,G,L,T. ≥[h] 𝐒⦃G, L, T⦄ → ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄.
  25 #h #G #L #T #H @(fsb_ind_alt … H) -G -L -T /5 width=1 by csx_intro, fpb_cpx/
  26 qed-.
  27
  28 (* Propreties with context-sensitive stringly rt-normalizing terms **********)
  29
  30 lemma csx_fsb_fpbs: ∀h,G1,L1,T1. ⦃G1, L1⦄ ⊢ ⬈*[h] 𝐒⦃T1⦄ →
  31                     ∀G2,L2,T2. ⦃G1, L1, T1⦄ ≥[h] ⦃G2, L2, T2⦄ → ≥[h] 𝐒⦃G2, L2, T2⦄.
  32 #h #G1 #L1 #T1 #H @(csx_ind … H) -T1
  33 #T1 #HT1 #IHc #G2 #L2 #T2 @(fqup_wf_ind (Ⓣ) … G2 L2 T2) -G2 -L2 -T2
  34 #G0 #L0 #T0 #IHu #H10
  35 lapply (fpbs_csx_conf … H10) // -HT1 #HT0
  36 generalize in match IHu; -IHu generalize in match H10; -H10
  37 @(rdsx_ind … (csx_rdsx … HT0)) -L0
  38 #L0 #_ #IHd #H10 #IHu @fsb_intro
  39 #G2 #L2 #T2 * -G2 -L2 -T2 [ -IHd -IHc | -IHu -IHd |  ]
  40 [ /4 width=5 by fpbs_fqup_trans, fqu_fqup/
  41 | #T2 #HT02 #HnT02
  42   elim (fpbs_cpx_tdneq_trans … H10 … HT02 HnT02) -T0
  43   /3 width=4 by/
  44 | #L2 #HL02 #HnL02 @(IHd … HL02 HnL02) -IHd -HnL02 [ -IHu -IHc | ]
  45   [ /3 width=3 by fpbs_lpxs_trans, lpx_lpxs/
  46   | #G3 #L3 #T3 #H03 #_
  47     elim (lpx_fqup_trans … H03 … HL02) -L2 #L4 #T4 #HT04 #H43 #HL43
  48     elim (tdeq_dec T0 T4) [ -IHc -HT04 #HT04 | -IHu #HnT04 ]
  49     [ elim (tdeq_fqup_trans … H43 … HT04) -T4 #L2 #T4 #H04 #HT43 #HL24
  50       /4 width=7 by fsb_fpbs_trans, tdeq_rdeq_lpx_fpbs, fpbs_fqup_trans/
  51     | elim (cpxs_tdneq_fwd_step_sn … HT04 HnT04) -HT04 -HnT04 #T2 #T5 #HT02 #HnT02 #HT25 #HT54
  52       elim (fpbs_cpx_tdneq_trans … H10 … HT02 HnT02) -T0 #T0 #HT10 #HnT10 #H02
  53       /3 width=14 by fpbs_cpxs_tdeq_fqup_lpx_trans/
  54     ]
  55   ]
  56 ]
  57 qed.
  58
  59 lemma csx_fsb: ∀h,G,L,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄ → ≥[h] 𝐒⦃G, L, T⦄.
  60 /2 width=5 by csx_fsb_fpbs/ qed.
  61
  62 (* Advanced eliminators *****************************************************)
  63
  64 lemma csx_ind_fpb: ∀h. ∀Q:relation3 genv lenv term.
  65                    (∀G1,L1,T1. ⦃G1, L1⦄ ⊢ ⬈*[h] 𝐒⦃T1⦄ →
  66                                (∀G2,L2,T2. ⦃G1, L1, T1⦄ ≻[h] ⦃G2, L2, T2⦄ → Q G2 L2 T2) →
  67                                Q G1 L1 T1
  68                    ) →
  69                    ∀G,L,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄ →  Q G L T.
  70 /4 width=4 by fsb_inv_csx, csx_fsb, fsb_ind_alt/ qed-.
  71
  72 lemma csx_ind_fpbg: ∀h. ∀Q:relation3 genv lenv term.
  73                     (∀G1,L1,T1. ⦃G1, L1⦄ ⊢ ⬈*[h] 𝐒⦃T1⦄ →
  74                                 (∀G2,L2,T2. ⦃G1, L1, T1⦄ >[h] ⦃G2, L2, T2⦄ → Q G2 L2 T2) →
  75                                 Q G1 L1 T1
  76                     ) →
  77                     ∀G,L,T. ⦃G, L⦄ ⊢ ⬈*[h] 𝐒⦃T⦄ →  Q G L T.
  78 /4 width=4 by fsb_inv_csx, csx_fsb, fsb_ind_fpbg/ qed-.