matita/matita/contribs/lambdadelta/basic_2/rt_computation/jsx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_4_3.ma".
  16 include "basic_2/notation/relations/topredtysnstrong_4.ma".
  17 include "basic_2/rt_computation/rsx.ma".
  18
  19 (* COMPATIBILITY OF STRONG NORMALIZATION FOR UNBOUND RT-TRANSITION **********)
  20
  21 (* Note: this should be an instance of a more general sex *)
  22 (* Basic_2A1: uses: lcosx *)
  23 inductive jsx (h) (G): relation lenv ≝
  24 | jsx_atom: jsx h G (⋆) (⋆)
  25 | jsx_bind: ∀I,K1,K2. jsx h G K1 K2 →
  26             jsx h G (K1.ⓘ{I}) (K2.ⓘ{I})
  27 | jsx_pair: ∀I,K1,K2,V. jsx h G K1 K2 →
  28             G ⊢ ⬈*[h,V] 𝐒⦃K2⦄ → jsx h G (K1.ⓑ{I}V) (K2.ⓧ)
  29 .
  30
  31 interpretation
  32   "strong normalization for unbound parallel rt-transition (compatibility)"
  33   'ToPRedTySNStrong h G L1 L2 = (jsx h G L1 L2).
  34
  35 (* Basic inversion lemmas ***************************************************)
  36
  37 fact jsx_inv_atom_sn_aux (h) (G):
  38      ∀L1,L2. G ⊢ L1 ⊒[h] L2 → L1 = ⋆ → L2 = ⋆.
  39 #h #G #L1 #L2 * -L1 -L2
  40 [ //
  41 | #I #K1 #K2 #_ #H destruct
  42 | #I #K1 #K2 #V #_ #_ #H destruct
  43 ]
  44 qed-.
  45
  46 lemma jsx_inv_atom_sn (h) (G): ∀L2. G ⊢ ⋆ ⊒[h] L2 → L2 = ⋆.
  47 /2 width=5 by jsx_inv_atom_sn_aux/ qed-.
  48
  49 fact jsx_inv_bind_sn_aux (h) (G):
  50      ∀L1,L2. G ⊢ L1 ⊒[h] L2 →
  51      ∀I,K1. L1 = K1.ⓘ{I} →
  52      ∨∨ ∃∃K2. G ⊢ K1 ⊒[h] K2 & L2 = K2.ⓘ{I}
  53       | ∃∃J,K2,V. G ⊢ K1 ⊒[h] K2 & G ⊢ ⬈*[h,V] 𝐒⦃K2⦄  & I = BPair J V & L2 = K2.ⓧ.
  54 #h #G #L1 #L2 * -L1 -L2
  55 [ #J #L1 #H destruct
  56 | #I #K1 #K2 #HK12 #J #L1 #H destruct /3 width=3 by ex2_intro, or_introl/
  57 | #I #K1 #K2 #V #HK12 #HV #J #L1 #H destruct /3 width=7 by ex4_3_intro, or_intror/
  58 ]
  59 qed-.
  60
  61 lemma jsx_inv_bind_sn (h) (G):
  62      ∀I,K1,L2. G ⊢ K1.ⓘ{I} ⊒[h] L2 →
  63      ∨∨ ∃∃K2. G ⊢ K1 ⊒[h] K2 & L2 = K2.ⓘ{I}
  64       | ∃∃J,K2,V. G ⊢ K1 ⊒[h] K2 & G ⊢ ⬈*[h,V] 𝐒⦃K2⦄  & I = BPair J V & L2 = K2.ⓧ.
  65 /2 width=3 by jsx_inv_bind_sn_aux/ qed-.
  66
  67 (* Advanced inversion lemmas ************************************************)
  68
  69 (* Basic_2A1: uses: lcosx_inv_pair *)
  70 lemma jsx_inv_pair_sn (h) (G):
  71       ∀I,K1,L2,V. G ⊢ K1.ⓑ{I}V ⊒[h] L2 →
  72       ∨∨ ∃∃K2. G ⊢ K1 ⊒[h] K2 & L2 = K2.ⓑ{I}V
  73        | ∃∃K2. G ⊢ K1 ⊒[h] K2 & G ⊢ ⬈*[h,V] 𝐒⦃K2⦄ & L2 = K2.ⓧ.
  74 #h #G #I #K1 #L2 #V #H elim (jsx_inv_bind_sn … H) -H *
  75 [ /3 width=3 by ex2_intro, or_introl/
  76 | #J #K2 #X #HK12 #HX #H1 #H2 destruct /3 width=4 by ex3_intro, or_intror/
  77 ]
  78 qed-.
  79
  80 lemma jsx_inv_void_sn (h) (G):
  81       ∀K1,L2. G ⊢ K1.ⓧ ⊒[h] L2 →
  82       ∃∃K2. G ⊢ K1 ⊒[h] K2 & L2 = K2.ⓧ.
  83 #h #G #K1 #L2 #H elim (jsx_inv_bind_sn … H) -H *
  84 /2 width=3 by ex2_intro/
  85 qed-.
  86
  87 (* Advanced forward lemmas **************************************************)
  88
  89 lemma jsx_fwd_bind_sn (h) (G):
  90       ∀I1,K1,L2. G ⊢ K1.ⓘ{I1} ⊒[h] L2 →
  91       ∃∃I2,K2. G ⊢ K1 ⊒[h] K2 & L2 = K2.ⓘ{I2}.
  92 #h #G #I1 #K1 #L2 #H elim (jsx_inv_bind_sn … H) -H *
  93 /2 width=4 by ex2_2_intro/
  94 qed-.
  95
  96 (* Advanced properties ******************************************************)
  97
  98 (* Basic_2A1: uses: lcosx_O *)
  99 lemma jsx_refl (h) (G): reflexive … (jsx h G).
 100 #h #G #L elim L -L /2 width=1 by jsx_atom, jsx_bind/
 101 qed.
 102
 103 (* Basic_2A1: removed theorems 2:
 104               lcosx_drop_trans_lt lcosx_inv_succ
 105 *)