matita/matita/contribs/lambdadelta/basic_2/rt_computation/jsx_rsx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/rsx_drops.ma".
  16 include "basic_2/rt_computation/rsx_lpxs.ma".
  17 include "basic_2/rt_computation/jsx.ma".
  18
  19 (* COMPATIBILITY OF STRONG NORMALIZATION FOR UNBOUND RT-TRANSITION **********)
  20
  21 (* Properties with strongly normalizing referred local environments *********)
  22
  23 (* Basic_2A1: uses: lsx_cpx_trans_lcosx *)
  24 lemma rsx_cpx_trans_jsx (h) (G):
  25       ∀L0,T1,T2. ❪G,L0❫ ⊢ T1 ⬈[h] T2 →
  26       ∀L. G ⊢ L0 ⊒[h] L → G ⊢ ⬈*[h,T1] 𝐒❪L❫ → G ⊢ ⬈*[h,T2] 𝐒❪L❫.
  27 #h #G #L0 #T1 #T2 #H @(cpx_ind … H) -G -L0 -T1 -T2
  28 [ //
  29 | //
  30 | #I0 #G #K0 #V1 #V2 #W2 #_ #IH #HVW2 #L #HK0 #HL
  31   elim (jsx_inv_pair_sn … HK0) -HK0 *
  32   [ #K #HK0 #H destruct
  33     /4 width=8 by rsx_lifts, rsx_fwd_pair, drops_refl, drops_drop/
  34   | #K #HK0 #HV1 #H destruct
  35     /4 width=8 by rsx_lifts, drops_refl, drops_drop/
  36   ]
  37 | #I0 #G #K0 #T #U #i #_ #IH #HTU #L #HK0 #HL
  38   elim (jsx_fwd_bind_sn … HK0) -HK0 #I #K #HK0 #H destruct
  39   /6 width=8 by rsx_inv_lifts, rsx_lifts, drops_refl, drops_drop/
  40 | #p #I0 #G #L0 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #HL0 #HL
  41   elim (rsx_inv_bind_void … HL) -HL
  42   /4 width=2 by jsx_pair, rsx_bind_void/
  43 | #I0 #G #L0 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #L #HL0 #HL
  44   elim (rsx_inv_flat … HL) -HL /3 width=2 by rsx_flat/
  45 | #G #L0 #V #U1 #T1 #T2 #HTU1 #_ #IHT12 #L #HL0 #HL
  46   elim (rsx_inv_bind_void … HL) -HL #HV #HU1
  47   /5 width=8 by rsx_inv_lifts, drops_refl, drops_drop/
  48 | #G #L0 #V #T1 #T2 #_ #IHT12 #L #HL0 #HL
  49   elim (rsx_inv_flat … HL) -HL /2 width=2 by/
  50 | #G #L0 #V1 #V2 #T #_ #IHV12 #L #HL0 #HL
  51   elim (rsx_inv_flat … HL) -HL /2 width=2 by/
  52 | #p #G #L0 #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #L #HL0 #HL
  53   elim (rsx_inv_flat … HL) -HL #HV1 #HL
  54   elim (rsx_inv_bind_void … HL) -HL #HW1 #HT1
  55   /4 width=2 by jsx_pair, rsx_bind_void, rsx_flat/
  56 | #p #G #L0 #V1 #V2 #U2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #HVU2 #L #HL0 #HL
  57   elim (rsx_inv_flat … HL) -HL #HV1 #HL
  58   elim (rsx_inv_bind_void … HL) -HL #HW1 #HT1
  59   /6 width=8 by jsx_pair, rsx_lifts, rsx_bind_void, rsx_flat, drops_refl, drops_drop/
  60 ]
  61 qed-.
  62
  63 (* Advanced properties of strongly normalizing referred local environments **)
  64
  65 (* Basic_2A1: uses: lsx_cpx_trans_O *)
  66 lemma rsx_cpx_trans (h) (G):
  67       ∀L,T1,T2. ❪G,L❫ ⊢ T1 ⬈[h] T2 →
  68       G ⊢ ⬈*[h,T1] 𝐒❪L❫ → G ⊢ ⬈*[h,T2] 𝐒❪L❫.
  69 /3 width=6 by rsx_cpx_trans_jsx, jsx_refl/ qed-.
  70
  71 lemma rsx_cpxs_trans (h) (G):
  72       ∀L,T1,T2. ❪G,L❫ ⊢ T1 ⬈*[h] T2 →
  73       G ⊢ ⬈*[h,T1] 𝐒❪L❫ → G ⊢ ⬈*[h,T2] 𝐒❪L❫.
  74 #h #G #L #T1 #T2 #H
  75 @(cpxs_ind_dx ???????? H) -T1 //
  76 /3 width=3 by rsx_cpx_trans/
  77 qed-.