matita/matita/contribs/lambdadelta/basic_2/rt_computation/jsx_rsx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/rsx_drops.ma".
  16 include "basic_2/rt_computation/rsx_lpxs.ma".
  17 include "basic_2/rt_computation/jsx.ma".
  18
  19 (* COMPATIBILITY OF STRONG NORMALIZATION FOR UNBOUND RT-TRANSITION **********)
  20
  21 (* Properties with strongly normalizing referred local environments *********)
  22
  23 (* Basic_2A1: uses: lsx_cpx_trans_lcosx *)
  24 lemma rsx_cpx_trans_jsx (h) (G):
  25       ∀L0,T1,T2. ⦃G,L0⦄ ⊢ T1 ⬈[h] T2 →
  26       ∀f,L. G ⊢ L0 ⊒[h,f] L →
  27       G ⊢ ⬈*[h,T1] 𝐒⦃L⦄ → G ⊢ ⬈*[h,T2] 𝐒⦃L⦄.
  28 #h #G #L0 #T1 #T2 #H @(cpx_ind … H) -G -L0 -T1 -T2
  29 [ //
  30 | //
  31 | #I0 #G #K0 #V1 #V2 #W2 #_ #IH #HVW2 #g #L #HK0 #HL
  32   elim (jsx_inv_pair_sn_gen … HK0) -HK0 *
  33   [ #f #K #HK0 #H1 #H2 destruct
  34     /4 width=8 by rsx_lifts, rsx_fwd_pair, drops_refl, drops_drop/
  35   | #f #K #HV1 #HK0 #H1 #H2 destruct
  36     /4 width=8 by rsx_lifts, drops_refl, drops_drop/
  37   ]
  38 | #I0 #G #K0 #T #U #i #_ #IH #HTU #g #L #HK0 #HL
  39   elim (jsx_fwd_bind_sn … HK0) -HK0 #I #K #HK0 #H destruct
  40   /6 width=8 by rsx_inv_lifts, rsx_lifts, drops_refl, drops_drop/
  41 | #p #I0 #G #L0 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #f #L #HL0 #HL
  42   elim (rsx_inv_bind_void … HL) -HL
  43   /4 width=2 by jsx_pair, rsx_bind_void/
  44 | #I0 #G #L0 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #f #L #HL0 #HL
  45   elim (rsx_inv_flat … HL) -HL /3 width=2 by rsx_flat/
  46 | #G #L0 #V #U1 #T1 #T2 #HTU1 #_ #IHT12 #f #L #HL0 #HL
  47   elim (rsx_inv_bind_void … HL) -HL #HV #HU1
  48   /5 width=8 by rsx_inv_lifts, drops_refl, drops_drop/
  49 | #G #L0 #V #T1 #T2 #_ #IHT12 #f #L #HL0 #HL
  50   elim (rsx_inv_flat … HL) -HL /2 width=2 by/
  51 | #G #L0 #V1 #V2 #T #_ #IHV12 #f #L #HL0 #HL
  52   elim (rsx_inv_flat … HL) -HL /2 width=2 by/
  53 | #p #G #L0 #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #f #L #HL0 #HL
  54   elim (rsx_inv_flat … HL) -HL #HV1 #HL
  55   elim (rsx_inv_bind_void … HL) -HL #HW1 #HT1
  56   /4 width=2 by jsx_pair, rsx_bind_void, rsx_flat/
  57 | #p #G #L0 #V1 #V2 #U2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #HVU2 #f #L #HL0 #HL
  58   elim (rsx_inv_flat … HL) -HL #HV1 #HL
  59   elim (rsx_inv_bind_void … HL) -HL #HW1 #HT1
  60   /6 width=8 by jsx_pair, rsx_lifts, rsx_bind_void, rsx_flat, drops_refl, drops_drop/
  61 ]
  62 qed-.
  63
  64 (* Advanced properties of strongly normalizing referred local environments **)
  65
  66 (* Basic_2A1: uses: lsx_cpx_trans_O *)
  67 lemma rsx_cpx_trans (h) (G):
  68       ∀L,T1,T2. ⦃G,L⦄ ⊢ T1 ⬈[h] T2 →
  69       G ⊢ ⬈*[h,T1] 𝐒⦃L⦄ → G ⊢ ⬈*[h,T2] 𝐒⦃L⦄.
  70 /3 width=6 by rsx_cpx_trans_jsx, jsx_refl/ qed-.
  71
  72 lemma rsx_cpxs_trans (h) (G):
  73       ∀L,T1,T2. ⦃G,L⦄ ⊢ T1 ⬈*[h] T2 →
  74       G ⊢ ⬈*[h,T1] 𝐒⦃L⦄ → G ⊢ ⬈*[h,T2] 𝐒⦃L⦄.
  75 #h #G #L #T1 #T2 #H
  76 @(cpxs_ind_dx ???????? H) -T1 //
  77 /3 width=3 by rsx_cpx_trans/
  78 qed-.