matita/matita/contribs/lambdadelta/basic_2/rt_computation/lfpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predtysnstar_5.ma".
  16 include "basic_2/i_static/tc_lfxs.ma".
  17 include "basic_2/rt_transition/lfpx.ma".
  18
  19 (* UNCOUNTED PARALLEL RT-COMPUTATION FOR LOCAL ENV.S ON REFERRED ENTRIES ****)
  20
  21 definition lfpxs: ∀h. relation4 genv term lenv lenv ≝
  22                   λh,G. tc_lfxs (cpx h G).
  23
  24 interpretation
  25    "uncounted parallel rt-computation on referred entries (local environment)"
  26    'PRedTySnStar h T G L1 L2 = (lfpxs h G T L1 L2).
  27
  28 (* Basic properties *********************************************************)
  29
  30 (* Basic_2A1: was just: lpx_lpxs *)
  31 lemma lfpx_lfpxs: ∀h,G,T,L1,L2. ⦃G, L1⦄ ⊢ ⬈[h, T] L2 → ⦃G, L1⦄ ⊢ ⬈*[h, T] L2.
  32 /2 width=1 by inj/ qed.
  33
  34 (* Basic_2A1: was just: lpxs_strap1 *)
  35 lemma lfpxs_step_dx: ∀h,G,T,L1,L,L2. ⦃G, L1⦄ ⊢ ⬈*[h, T] L → ⦃G, L⦄ ⊢ ⬈[h, T] L2 → ⦃G, L1⦄ ⊢ ⬈*[h, T] L2.
  36 /2 width=3 by tc_lfxs_step_dx/ qed.
  37
  38 (* Basic_2A1: was just: lpxs_strap2 *)
  39 lemma lfpxs_step_sn: ∀h,G,T,L1,L,L2. ⦃G, L1⦄ ⊢ ⬈[h, T] L → ⦃G, L⦄ ⊢ ⬈*[h, T] L2 → ⦃G, L1⦄ ⊢ ⬈*[h, T] L2.
  40 /2 width=3 by tc_lfxs_step_sn/ qed.
  41
  42 (* Basic inversion lemmas ***************************************************)
  43
  44 (* Basic_2A1: uses: lpxs_inv_atom1 *)
  45 lemma lfpxs_inv_atom1: ∀h,I,G,L2. ⦃G, ⋆⦄ ⊢ ⬈*[h, ⓪{I}] L2 → L2 = ⋆.
  46 /2 width=3 by tc_lfxs_inv_atom_sn/ qed-.
  47
  48 (* Basic_2A1: uses: lpxs_inv_atom2 *)
  49 lemma lfpxs_inv_atom2: ∀h,I,G,L1. ⦃G, L1⦄ ⊢ ⬈*[h, ⓪{I}] ⋆ → L1 = ⋆.
  50 /2 width=3 by tc_lfxs_inv_atom_dx/ qed-.
  51
  52 (* Basic forward lemmas *****************************************************)
  53
  54 lemma lfpxs_fwd_pair_sn: ∀h,I,G,L1,L2,V,T. ⦃G, L1⦄ ⊢ ⬈*[h, ②{I}V.T] L2 → ⦃G, L1⦄ ⊢ ⬈*[h, V] L2.
  55 /2 width=3 by tc_lfxs_fwd_pair_sn/ qed-.
  56
  57 lemma lfpxs_fwd_flat_dx: ∀h,I,G,L1,L2,V,T. ⦃G, L1⦄ ⊢ ⬈*[h, ⓕ{I}V.T] L2 → ⦃G, L1⦄ ⊢ ⬈*[h, T] L2.
  58 /2 width=3 by tc_lfxs_fwd_flat_dx/ qed-.