matita/matita/contribs/lambdadelta/basic_2/rt_computation/lfpxs_lfdeq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/lfpx_lfdeq.ma".
  16 include "basic_2/rt_computation/lfpxs_fqup.ma".
  17
  18 (* UNCOUNTED PARALLEL RT-COMPUTATION FOR LOCAL ENV.S ON REFERRED ENTRIES ****)
  19
  20 (* Properties with degree-based equivalence on terms ************************)
  21
  22 lemma lfpxs_tdeq_trans: ∀h,o,G. s_r_confluent1 … (cdeq h o) (lfpxs h G).
  23 #h #o #G #L1 #T1 #T2 #HT12 #L2 #H @(lfpxs_ind_sn … H) -L2
  24 /3 width=6 by lfpxs_step_dx, lfpx_tdeq_conf/
  25 qed-.
  26
  27 lemma tdeq_lfpxs_trans: ∀h,o,T1,T2. T1 ≛[h, o] T2 →
  28                         ∀G,L1,L2. ⦃G, L1⦄ ⊢⬈*[h, T2] L2 → ⦃G, L1⦄ ⊢⬈*[h, T1] L2.
  29 /3 width=4 by lfpxs_tdeq_trans, tdeq_sym/ qed-.
  30
  31 (* Properties with degree-based equivalence on referred entries *************)
  32
  33 (* Basic_2A1: was: lleq_lpxs_trans *)
  34 lemma lfdeq_lfpxs_trans: ∀h,o,G,L2,K2,T. ⦃G, L2⦄ ⊢ ⬈*[h, T] K2 →
  35                          ∀L1. L1 ≛[h, o, T] L2 →
  36                          ∃∃K1. ⦃G, L1⦄ ⊢ ⬈*[h, T] K1 & K1 ≛[h, o, T] K2.
  37 #h #o #G #L2 #K2 #T #H @(lfpxs_ind_sn … H) -K2 /2 width=3 by ex2_intro/
  38 #K #K2 #_ #HK2 #IH #L1 #HT elim (IH … HT) -L2
  39 #L #HL1 #HT elim (lfdeq_lfpx_trans … HK2 … HT) -K
  40 /3 width=3 by lfpxs_step_dx, ex2_intro/
  41 qed-.
  42
  43 (* Basic_2A1: was: lpxs_nlleq_inv_step_sn *)
  44 lemma lfpxs_lfdneq_inv_step_sn: ∀h,o,G,L1,L2,T. ⦃G, L1⦄ ⊢ ⬈*[h, T] L2 → (L1 ≛[h, o, T] L2 → ⊥) →
  45                                 ∃∃L,L0. ⦃G, L1⦄ ⊢ ⬈[h, T] L & L1 ≛[h, o, T] L → ⊥ & ⦃G, L⦄ ⊢ ⬈*[h, T] L0 & L0 ≛[h, o, T] L2.
  46 #h #o #G #L1 #L2 #T #H @(lfpxs_ind_dx … H) -L1
  47 [ #H elim H -H //
  48 | #L1 #L #H1 #H2 #IH2 #H12 elim (lfdeq_dec h o L1 L T) #H
  49   [ -H1 -H2 elim IH2 -IH2 /3 width=3 by lfdeq_trans/ -H12
  50     #L0 #L3 #H1 #H2 #H3 #H4 lapply (lfdeq_lfdneq_trans … H … H2) -H2
  51     #H2 elim (lfdeq_lfpx_trans … H1 … H) -L
  52     #L #H1 #H lapply (lfdneq_lfdeq_div … H … H2) -H2
  53     #H2 elim (lfdeq_lfpxs_trans … H3 … H) -L0
  54     /3 width=8 by lfdeq_trans, ex4_2_intro/
  55   | -H12 -IH2 /3 width=6 by ex4_2_intro/
  56   ]
  57 ]
  58 qed-.