matita/matita/contribs/lambdadelta/basic_2/rt_computation/lfsx_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/static/lfdeq_length.ma".
  16 include "basic_2/static/lfdeq_drops.ma".
  17 include "basic_2/rt_transition/lfpx_length.ma".
  18 include "basic_2/rt_transition/lfpx_drops.ma".
  19 include "basic_2/rt_computation/lfsx_fqup.ma".
  20
  21 (* STRONGLY NORMALIZING LOCAL ENV.S FOR UNCOUNTED PARALLEL RT-TRANSITION ****)
  22
  23 (* Properties with generic relocation ***************************************)
  24
  25 (* Note: this uses length *)
  26 (* Basic_2A1: uses: lsx_lift_le lsx_lift_ge *)
  27 lemma lfsx_lifts: ∀h,o,G. d_liftable1_isuni … (λL,T. G ⊢ ⬈*[h, o, T] 𝐒⦃L⦄).
  28 #h #o #G #K #T #H @(lfsx_ind … H) -K
  29 #K1 #_ #IH #b #f #L1 #HLK1 #Hf #U #HTU @lfsx_intro
  30 #L2 #HL12 #HnL12 elim (lfpx_drops_conf … HLK1 … HL12 … HTU)
  31 /5 width=9 by lfdeq_lifts_bi, lfpx_fwd_length/
  32 qed-.
  33
  34 (* Inversion lemmas on relocation *******************************************)
  35
  36 (* Basic_2A1: uses: lsx_inv_lift_le lsx_inv_lift_be lsx_inv_lift_ge *)
  37 lemma lfsx_inv_lifts: ∀h,o,G. d_deliftable1_isuni … (λL,T. G ⊢ ⬈*[h, o, T] 𝐒⦃L⦄).
  38 #h #o #G #L #U #H @(lfsx_ind … H) -L
  39 #L1 #_ #IH #b #f #K1 #HLK1 #Hf #T #HTU @lfsx_intro
  40 #K2 #HK12 #HnK12 elim (drops_lfpx_trans … HLK1 … HK12 … HTU) -HK12
  41 /4 width=10 by lfdeq_inv_lifts_bi/
  42 qed-.
  43
  44 (* Advanced properties ******************************************************)
  45
  46 (* Basic_2A1: uses: lsx_lref_free *)
  47 lemma lfsx_lref_atom: ∀h,o,G,L,i. ⬇*[Ⓕ, 𝐔❴i❵] L ≘ ⋆ → G ⊢ ⬈*[h, o, #i] 𝐒⦃L⦄.
  48 #h #o #G #L1 #i #HL1
  49 @(lfsx_lifts … (#0) … HL1) -HL1 //
  50 qed.
  51
  52 (* Basic_2A1: uses: lsx_lref_skip *)
  53 lemma lfsx_lref_unit: ∀h,o,I,G,L,K,i. ⬇*[i] L ≘ K.ⓤ{I} → G ⊢ ⬈*[h, o, #i] 𝐒⦃L⦄.
  54 #h #o #I #G #L1 #K1 #i #HL1
  55 @(lfsx_lifts … (#0) … HL1) -HL1 //
  56 qed.
  57
  58 (* Advanced forward lemmas **************************************************)
  59
  60 (* Basic_2A1: uses: lsx_fwd_lref_be *)
  61 lemma lfsx_fwd_lref_pair: ∀h,o,G,L,i. G ⊢ ⬈*[h, o, #i] 𝐒⦃L⦄ →
  62                           ∀I,K,V. ⬇*[i] L ≘ K.ⓑ{I}V → G ⊢ ⬈*[h, o, V] 𝐒⦃K⦄.
  63 #h #o #G #L #i #HL #I #K #V #HLK
  64 lapply (lfsx_inv_lifts … HL … HLK … (#0) ?) -L
  65 /2 width=2 by lfsx_fwd_pair/
  66 qed-.