matita/matita/contribs/lambdadelta/basic_2/rt_computation/lprs_lpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/lprs_tc.ma".
  16
  17 (* PARALLEL R-COMPUTATION FOR FULL LOCAL ENVIRONMENTS ***********************)
  18
  19 (* Eliminators with r-transition for full local environments ****************)
  20
  21 (* Basic_2A1: was: lprs_ind_dx *)
  22 lemma lprs_ind_sn (h) (G) (L2): ∀R:predicate lenv. R L2 →
  23                                 (∀L1,L. ⦃G, L1⦄ ⊢ ➡[h] L → ⦃G, L⦄ ⊢ ➡*[h] L2 → R L → R L1) →
  24                                 ∀L1. ⦃G, L1⦄ ⊢ ➡*[h] L2 → R L1.
  25 /4 width=8 by lprs_inv_CTC, lprs_CTC, lpr_cprs_trans, cpr_refl, lex_CTC_ind_sn/ qed-.
  26
  27 (* Basic_2A1: was: lprs_ind *)
  28 lemma lprs_ind_dx (h) (G) (L1): ∀R:predicate lenv. R L1 →
  29                                 (∀L,L2. ⦃G, L1⦄ ⊢ ➡*[h] L → ⦃G, L⦄ ⊢ ➡[h] L2 → R L → R L2) →
  30                                 ∀L2. ⦃G, L1⦄ ⊢ ➡*[h] L2 → R L2.
  31 /4 width=8 by lprs_inv_CTC, lprs_CTC, lpr_cprs_trans, cpr_refl, lex_CTC_ind_dx/ qed-.
  32
  33 (* Properties with unbound rt-transition for full local environments ********)
  34
  35 lemma lpr_lprs (h) (G): ∀L1,L2. ⦃G, L1⦄ ⊢ ➡[h] L2 → ⦃G, L1⦄ ⊢ ➡*[h] L2.
  36 /4 width=3 by lprs_CTC, lpr_cprs_trans, lex_CTC_inj/ qed.
  37
  38 (* Basic_2A1: was: lprs_strap2 *)
  39 lemma lprs_step_sn (h) (G): ∀L1,L. ⦃G, L1⦄ ⊢ ➡[h] L →
  40                             ∀L2.⦃G, L⦄ ⊢ ➡*[h] L2 → ⦃G, L1⦄ ⊢ ➡*[h] L2.
  41 /4 width=3 by lprs_inv_CTC, lprs_CTC, lpr_cprs_trans, lex_CTC_step_sn/ qed-.
  42
  43 (* Basic_2A1: was: lpxs_strap1 *)
  44 lemma lprs_step_dx (h) (G): ∀L1,L. ⦃G, L1⦄ ⊢ ➡*[h] L →
  45                             ∀L2. ⦃G, L⦄ ⊢ ➡[h] L2 → ⦃G, L1⦄ ⊢ ➡*[h] L2.
  46 /4 width=3 by lprs_inv_CTC, lprs_CTC, lpr_cprs_trans, lex_CTC_step_dx/ qed-.
  47
  48 lemma lprs_strip (h) (G): confluent2 … (lprs h G) (lpr h G).
  49 #h #G #L0 #L1 #HL01 #L2 #HL02
  50 elim (TC_strip1 … L1 ?? HL02) -HL02
  51 [ /3 width=3 by lprs_TC, ex2_intro/ | skip
  52 | /2 width=1 by lprs_inv_TC/
  53 | /2 width=3 by lpr_conf/
  54 ]
  55 qed-.