matita/matita/contribs/lambdadelta/basic_2/rt_computation/lpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predtysnstar_3.ma".
  16 include "static_2/relocation/lex.ma".
  17 include "basic_2/rt_computation/cpxs_ext.ma".
  18
  19 (* EXTENDED PARALLEL RT-COMPUTATION FOR FULL LOCAL ENVIRONMENTS *************)
  20
  21 definition lpxs (G): relation lenv ≝
  22            lex (cpxs G).
  23
  24 interpretation
  25   "extended parallel rt-computation on all entries (local environment)"
  26   'PRedTySnStar G L1 L2 = (lpxs G L1 L2).
  27
  28 (* Basic properties *********************************************************)
  29
  30 (* Basic_2A1: uses: lpxs_pair_refl *)
  31 lemma lpxs_bind_refl_dx (G):
  32       ∀L1,L2. ❪G,L1❫ ⊢ ⬈* L2 →
  33       ∀I. ❪G,L1.ⓘ[I]❫ ⊢ ⬈* L2.ⓘ[I].
  34 /2 width=1 by lex_bind_refl_dx/ qed.
  35
  36 lemma lpxs_pair (G):
  37       ∀L1,L2. ❪G,L1❫ ⊢ ⬈* L2 →
  38       ∀V1,V2. ❪G,L1❫ ⊢ V1 ⬈* V2 →
  39       ∀I. ❪G,L1.ⓑ[I]V1❫ ⊢ ⬈* L2.ⓑ[I]V2.
  40 /2 width=1 by lex_pair/ qed.
  41
  42 lemma lpxs_refl (G):
  43       reflexive … (lpxs G).
  44 /2 width=1 by lex_refl/ qed.
  45
  46 (* Basic inversion lemmas ***************************************************)
  47
  48 (* Basic_2A1: was: lpxs_inv_atom1 *)
  49 lemma lpxs_inv_atom_sn (G):
  50       ∀L2. ❪G,⋆❫ ⊢ ⬈* L2 → L2 = ⋆.
  51 /2 width=2 by lex_inv_atom_sn/ qed-.
  52
  53 lemma lpxs_inv_bind_sn (G):
  54       ∀I1,L2,K1. ❪G,K1.ⓘ[I1]❫ ⊢ ⬈* L2 →
  55       ∃∃I2,K2. ❪G,K1❫ ⊢ ⬈* K2 & ❪G,K1❫ ⊢ I1 ⬈* I2 & L2 = K2.ⓘ[I2].
  56 /2 width=1 by lex_inv_bind_sn/ qed-.
  57
  58 (* Basic_2A1: was: lpxs_inv_pair1 *)
  59 lemma lpxs_inv_pair_sn (G):
  60       ∀I,L2,K1,V1. ❪G,K1.ⓑ[I]V1❫ ⊢ ⬈* L2 →
  61       ∃∃K2,V2. ❪G,K1❫ ⊢ ⬈* K2 & ❪G,K1❫ ⊢ V1 ⬈* V2 & L2 = K2.ⓑ[I]V2.
  62 /2 width=1 by lex_inv_pair_sn/ qed-.
  63
  64 (* Basic_2A1: was: lpxs_inv_atom2 *)
  65 lemma lpxs_inv_atom_dx (G):
  66       ∀L1. ❪G,L1❫ ⊢ ⬈* ⋆ → L1 = ⋆.
  67 /2 width=2 by lex_inv_atom_dx/ qed-.
  68
  69 (* Basic_2A1: was: lpxs_inv_pair2 *)
  70 lemma lpxs_inv_pair_dx (G):
  71       ∀I,L1,K2,V2. ❪G,L1❫ ⊢ ⬈* K2.ⓑ[I]V2 →
  72       ∃∃K1,V1. ❪G,K1❫ ⊢ ⬈* K2 & ❪G,K1❫ ⊢ V1 ⬈* V2 & L1 = K1.ⓑ[I]V1.
  73 /2 width=1 by lex_inv_pair_dx/ qed-.
  74
  75 (* Basic eliminators ********************************************************)
  76
  77 (* Basic_2A1: was: lpxs_ind_alt *)
  78 lemma lpxs_ind (G) (Q:relation …):
  79       Q (⋆) (⋆) → (
  80         ∀I,K1,K2.
  81         ❪G,K1❫ ⊢ ⬈* K2 →
  82         Q K1 K2 → Q (K1.ⓘ[I]) (K2.ⓘ[I])
  83       ) → (
  84         ∀I,K1,K2,V1,V2.
  85         ❪G,K1❫ ⊢ ⬈* K2 → ❪G,K1❫ ⊢ V1 ⬈* V2 →
  86         Q K1 K2 → Q (K1.ⓑ[I]V1) (K2.ⓑ[I]V2)
  87       ) →
  88       ∀L1,L2. ❪G,L1❫ ⊢ ⬈* L2 → Q L1 L2.
  89 /3 width=4 by lex_ind/ qed-.