matita/matita/contribs/lambdadelta/basic_2/rt_computation/lpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predtysnstar_4.ma".
  16 include "basic_2/relocation/lex.ma".
  17 include "basic_2/rt_computation/cpxs_ext.ma".
  18
  19 (* UNCOUNTED PARALLEL RT-COMPUTATION FOR LOCAL ENVIRONMENTS *****************)
  20
  21 definition lpxs: ∀h. relation3 genv lenv lenv ≝
  22                  λh,G. lex (cpxs h G).
  23
  24 interpretation
  25    "uncounted parallel rt-computation (local environment)"
  26    'PRedTySnStar h G L1 L2 = (lpxs h G L1 L2).
  27
  28 (* Basic properties *********************************************************)
  29
  30 lemma lpxs_refl: ∀h,G. reflexive … (lpxs h G).
  31 /2 width=1 by lex_refl/ qed.
  32
  33 (* Basic inversion lemmas ***************************************************)
  34
  35 lemma lpxs_inv_bind_sn: ∀h,G,I1,L2,K1. ⦃G, K1.ⓘ{I1}⦄ ⊢⬈*[h] L2 →
  36                         ∃∃I2,K2. ⦃G, K1⦄ ⊢⬈*[h] K2 & ⦃G, K1⦄ ⊢ I1 ⬈*[h] I2 & L2 = K2.ⓘ{I2}.
  37 /2 width=1 by lex_inv_bind_sn/ qed-.
  38
  39 lemma lpxs_inv_pair_sn: ∀h,G,I,L2,K1,V1. ⦃G, K1.ⓑ{I}V1⦄ ⊢⬈*[h] L2 →
  40                         ∃∃K2,V2. ⦃G, K1⦄ ⊢⬈*[h] K2 & ⦃G, K1⦄ ⊢ V1 ⬈*[h] V2 & L2 = K2.ⓑ{I}V2.
  41 #h #G #I #L2 #K1 #V1 #H
  42 elim (lpxs_inv_bind_sn … H) -H #Y #K2 #HK12 #H0 #H destruct
  43 elim (ext2_inv_pair_sn … H0) -H0 #V2 #HV12 #H destruct
  44 /2 width=5 by ex3_2_intro/
  45 qed-.