matita/matita/contribs/lambdadelta/basic_2/rt_computation/lpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predtysnstar_4.ma".
  16 include "basic_2/relocation/lex.ma".
  17 include "basic_2/rt_computation/cpxs_ext.ma".
  18
  19 (* UNBOUND PARALLEL RT-COMPUTATION FOR FULL LOCAL ENVIRONMENTS **************)
  20
  21 definition lpxs (h) (G): relation lenv ≝
  22                          lex (cpxs h G).
  23
  24 interpretation
  25    "unbound parallel rt-computation on all entries (local environment)"
  26    'PRedTySnStar h G L1 L2 = (lpxs h G L1 L2).
  27
  28 (* Basic properties *********************************************************)
  29
  30 (* Basic_2A1: uses: lpxs_pair_refl *)
  31 lemma lpxs_bind_refl_dx (h) (G): ∀L1,L2. ⦃G, L1⦄ ⊢ ⬈*[h] L2 →
  32                                  ∀I. ⦃G, L1.ⓘ{I}⦄ ⊢ ⬈*[h] L2.ⓘ{I}.
  33 /2 width=1 by lex_bind_refl_dx/ qed.
  34
  35 lemma lpxs_pair (h) (G): ∀L1,L2. ⦃G, L1⦄ ⊢ ⬈*[h] L2 →
  36                          ∀V1,V2. ⦃G, L1⦄ ⊢ V1 ⬈*[h] V2 →
  37                          ∀I. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈*[h] L2.ⓑ{I}V2.
  38 /2 width=1 by lex_pair/ qed.
  39
  40 lemma lpxs_refl (h) (G): reflexive … (lpxs h G).
  41 /2 width=1 by lex_refl/ qed.
  42
  43 (* Basic inversion lemmas ***************************************************)
  44
  45 (* Basic_2A1: was: lpxs_inv_atom1 *)
  46 lemma lpxs_inv_atom_sn (h) (G): ∀L2. ⦃G, ⋆⦄ ⊢ ⬈*[h] L2 → L2 = ⋆.
  47 /2 width=2 by lex_inv_atom_sn/ qed-.
  48
  49 lemma lpxs_inv_bind_sn (h) (G): ∀I1,L2,K1. ⦃G, K1.ⓘ{I1}⦄ ⊢ ⬈*[h] L2 →
  50                                 ∃∃I2,K2. ⦃G, K1⦄ ⊢ ⬈*[h] K2 & ⦃G, K1⦄ ⊢ I1 ⬈*[h] I2 & L2 = K2.ⓘ{I2}.
  51 /2 width=1 by lex_inv_bind_sn/ qed-.
  52
  53 (* Basic_2A1: was: lpxs_inv_pair1 *)
  54 lemma lpxs_inv_pair_sn (h) (G): ∀I,L2,K1,V1. ⦃G, K1.ⓑ{I}V1⦄ ⊢ ⬈*[h] L2 →
  55                                 ∃∃K2,V2. ⦃G, K1⦄ ⊢ ⬈*[h] K2 & ⦃G, K1⦄ ⊢ V1 ⬈*[h] V2 & L2 = K2.ⓑ{I}V2.
  56 /2 width=1 by lex_inv_pair_sn/ qed-.
  57
  58 (* Basic_2A1: was: lpxs_inv_atom2 *)
  59 lemma lpxs_inv_atom_dx (h) (G): ∀L1. ⦃G, L1⦄ ⊢ ⬈*[h] ⋆ → L1 = ⋆.
  60 /2 width=2 by lex_inv_atom_dx/ qed-.
  61
  62 (* Basic_2A1: was: lpxs_inv_pair2 *)
  63 lemma lpxs_inv_pair_dx (h) (G): ∀I,L1,K2,V2. ⦃G, L1⦄ ⊢ ⬈*[h] K2.ⓑ{I}V2 →
  64                                 ∃∃K1,V1. ⦃G, K1⦄ ⊢ ⬈*[h] K2 & ⦃G, K1⦄ ⊢ V1 ⬈*[h] V2 & L1 = K1.ⓑ{I}V1.
  65 /2 width=1 by lex_inv_pair_dx/ qed-.
  66
  67 (* Basic eliminators ********************************************************)
  68
  69 (* Basic_2A1: was: lpxs_ind_alt *)
  70 lemma lpxs_ind (h) (G): ∀R:relation lenv.
  71                         R (⋆) (⋆) → (
  72                           ∀I,K1,K2.
  73                           ⦃G, K1⦄ ⊢ ⬈*[h] K2 →
  74                           R K1 K2 → R (K1.ⓘ{I}) (K2.ⓘ{I})
  75                         ) → (
  76                           ∀I,K1,K2,V1,V2.
  77                           ⦃G, K1⦄ ⊢ ⬈*[h] K2 → ⦃G, K1⦄ ⊢ V1 ⬈*[h] V2 →
  78                           R K1 K2 → R (K1.ⓑ{I}V1) (K2.ⓑ{I}V2)
  79                         ) →
  80                         ∀L1,L2. ⦃G, L1⦄ ⊢ ⬈*[h] L2 → R L1 L2.
  81 /3 width=4 by lex_ind/ qed-.