matita/matita/contribs/lambdadelta/basic_2/rt_computation/lpxs_cpxs.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/lpxs_lpx.ma".
  16
  17 (* UNBOUND PARALLEL RT-COMPUTATION FOR FULL LOCAL ENVIRONMENTS **************)
  18
  19 (* Properties with context-sensitive extended rt-computation for terms ******)
  20
  21 (* Basic_2A1: was: cpxs_bind2 *)
  22 lemma cpxs_bind_dx (h) (G): ∀L,V1,V2. ⦃G, L⦄ ⊢ V1 ⬈*[h] V2 →
  23                             ∀I,T1,T2. ⦃G, L.ⓑ{I}V2⦄ ⊢ T1 ⬈*[h] T2 →
  24                             ∀p. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ⬈*[h] ⓑ{p,I}V2.T2.
  25 /4 width=5 by lpxs_cpxs_trans, lpxs_pair, cpxs_bind/ qed.
  26
  27 (* Inversion lemmas with context-sensitive ext rt-computation for terms *****)
  28
  29 lemma cpxs_inv_abst1 (h) (G): ∀p,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{p}V1.T1 ⬈*[h] U2 →
  30                               ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈*[h] V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ⬈*[h] T2 &
  31                                        U2 = ⓛ{p}V2.T2.
  32 #h #G #p #L #V1 #T1 #U2 #H @(cpxs_ind … H) -U2 /2 width=5 by ex3_2_intro/
  33 #U0 #U2 #_ #HU02 * #V0 #T0 #HV10 #HT10 #H destruct
  34 elim (cpx_inv_abst1 … HU02) -HU02 #V2 #T2 #HV02 #HT02 #H destruct
  35 lapply (lpxs_cpx_trans … HT02 (L.ⓛV1) ?)
  36 /3 width=5 by lpxs_pair, cpxs_trans, cpxs_strap1, ex3_2_intro/
  37 qed-.
  38
  39 lemma cpxs_inv_abbr1 (h) (G): ∀p,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{p}V1.T1 ⬈*[h] U2 →
  40                               ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ⬈*[h] V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ⬈*[h] T2 &
  41                                           U2 = ⓓ{p}V2.T2
  42                                | ∃∃T2. ⦃G, L.ⓓV1⦄ ⊢ T1 ⬈*[h] T2 & ⬆*[1] U2 ≘ T2 & p = Ⓣ.
  43 #h #G #p #L #V1 #T1 #U2 #H @(cpxs_ind … H) -U2 /3 width=5 by ex3_2_intro, or_introl/
  44 #U0 #U2 #_ #HU02 * *
  45 [ #V0 #T0 #HV10 #HT10 #H destruct
  46   elim (cpx_inv_abbr1 … HU02) -HU02 *
  47   [ #V2 #T2 #HV02 #HT02 #H destruct
  48     lapply (lpxs_cpx_trans … HT02 (L.ⓓV1) ?)
  49     /4 width=5 by lpxs_pair, cpxs_trans, cpxs_strap1, ex3_2_intro, or_introl/
  50   | #T2 #HT02 #HUT2
  51     lapply (lpxs_cpx_trans … HT02 (L.ⓓV1) ?) -HT02
  52     /4 width=3 by lpxs_pair, cpxs_trans, ex3_intro, or_intror/
  53   ]
  54 | #U1 #HTU1 #HU01 #Hp
  55   elim (cpx_lifts_sn … HU02 (Ⓣ) … (L.ⓓV1) … HU01) -U0 /3 width=3 by drops_refl, drops_drop/ #U #HU2 #HU1
  56   /4 width=3 by cpxs_strap1, ex3_intro, or_intror/
  57 ]
  58 qed-.