matita/matita/contribs/lambdadelta/basic_2/rt_computation/lpxs_lpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/lex_tc.ma".
  16 include "basic_2/rt_computation/cpxs_lpx.ma".
  17 include "basic_2/rt_computation/lpxs.ma".
  18
  19 (* EXTENDED PARALLEL RT-COMPUTATION FOR FULL LOCAL ENVIRONMENTS *************)
  20
  21 (* Properties with extended rt-transition for full local environments *******)
  22
  23 lemma lpx_lpxs (G):
  24       ∀L1,L2. ❪G,L1❫ ⊢ ⬈ L2 → ❪G,L1❫ ⊢ ⬈* L2.
  25 /3 width=3 by lpx_cpxs_trans, lex_CTC_inj/ qed.
  26
  27 (* Basic_2A1: was: lpxs_strap2 *)
  28 lemma lpxs_step_sn (G):
  29       ∀L1,L. ❪G,L1❫ ⊢ ⬈ L →
  30       ∀L2. ❪G,L❫ ⊢ ⬈* L2 → ❪G,L1❫ ⊢ ⬈* L2.
  31 /3 width=3 by lpx_cpxs_trans, lex_CTC_step_sn/ qed-.
  32
  33 (* Basic_2A1: was: lpxs_strap1 *)
  34 lemma lpxs_step_dx (G):
  35       ∀L1,L. ❪G,L1❫ ⊢ ⬈* L →
  36       ∀L2. ❪G,L❫ ⊢ ⬈ L2 → ❪G,L1❫ ⊢ ⬈* L2.
  37 /3 width=3 by lpx_cpxs_trans, lex_CTC_step_dx/ qed-.
  38
  39 (* Eliminators with extended rt-transition for full local environments ******)
  40
  41 (* Basic_2A1: was: lpxs_ind_dx *)
  42 lemma lpxs_ind_sn (G) (L2) (Q:predicate …):
  43       Q L2 →
  44       (∀L1,L. ❪G,L1❫ ⊢ ⬈ L → ❪G,L❫ ⊢ ⬈* L2 → Q L → Q L1) →
  45       ∀L1. ❪G,L1❫ ⊢ ⬈* L2 → Q L1.
  46 /3 width=7 by lpx_cpxs_trans, cpx_refl, lex_CTC_ind_sn/ qed-.
  47
  48 (* Basic_2A1: was: lpxs_ind *)
  49 lemma lpxs_ind_dx (G) (L1) (Q:predicate …):
  50       Q L1 →
  51       (∀L,L2. ❪G,L1❫ ⊢ ⬈* L → ❪G,L❫ ⊢ ⬈ L2 → Q L → Q L2) →
  52       ∀L2. ❪G,L1❫ ⊢ ⬈* L2 → Q L2.
  53 /3 width=7 by lpx_cpxs_trans, cpx_refl, lex_CTC_ind_dx/ qed-.
  54
  55 (* Properties with context-sensitive extended rt-transition for terms *******)
  56
  57 lemma lpxs_cpx_trans (G):
  58       s_r_transitive … (cpx G) (λ_.lpxs G).
  59 #G #L2 #T1 #T2 #HT12 #L1 #HL12
  60 @(s_r_trans_CTC2 ???????? HT12) -HT12
  61 /2 width=4 by lpx_cpxs_trans, lex_inv_CTC/
  62 qed-.
  63
  64 (* Properties with context-sensitive extended rt-computation for terms ******)
  65
  66 (* Note: alternative proof by s_r_to_s_rs_trans *)
  67 lemma lpxs_cpxs_trans (G):
  68       s_rs_transitive … (cpx G) (λ_.lpxs G).
  69 #G @s_r_trans_CTC1 /2 width=3 by lpxs_cpx_trans/
  70 qed-.
  71
  72 (* Advanced properties ******************************************************)
  73
  74 (* Basic_2A1: was: lpxs_pair2 *)
  75 lemma lpxs_pair_dx (G):
  76       ∀L1,L2. ❪G,L1❫ ⊢ ⬈* L2 →
  77       ∀V1,V2. ❪G,L2❫ ⊢ V1 ⬈* V2 →
  78       ∀I. ❪G,L1.ⓑ[I]V1❫ ⊢ ⬈* L2.ⓑ[I]V2.
  79 /3 width=3 by lpxs_pair, lpxs_cpxs_trans/ qed.