matita/matita/contribs/lambdadelta/basic_2/rt_computation/lpxs_lpx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/lex_tc.ma".
  16 include "basic_2/rt_computation/cpxs_lpx.ma".
  17 include "basic_2/rt_computation/lpxs.ma".
  18
  19 (* UNBOUND PARALLEL RT-COMPUTATION FOR FULL LOCAL ENVIRONMENTS **************)
  20
  21 (* Properties with unbound rt-transition for full local environments ********)
  22
  23 lemma lpx_lpxs (h) (G): ∀L1,L2. ⦃G, L1⦄ ⊢ ⬈[h] L2 → ⦃G, L1⦄ ⊢ ⬈*[h] L2.
  24 /3 width=3 by lpx_cpxs_trans, lex_CTC_inj/ qed.
  25
  26 (* Basic_2A1: was: lpxs_strap2 *)
  27 lemma lpxs_step_sn (h) (G): ∀L1,L. ⦃G, L1⦄ ⊢ ⬈[h] L →
  28                             ∀L2. ⦃G, L⦄ ⊢ ⬈*[h] L2 → ⦃G, L1⦄ ⊢ ⬈*[h] L2.
  29 /3 width=3 by lpx_cpxs_trans, lex_CTC_step_sn/ qed-.
  30
  31 (* Basic_2A1: was: lpxs_strap1 *)
  32 lemma lpxs_step_dx (h) (G): ∀L1,L. ⦃G, L1⦄ ⊢ ⬈*[h] L →
  33                             ∀L2. ⦃G, L⦄ ⊢ ⬈[h] L2 → ⦃G, L1⦄ ⊢ ⬈*[h] L2.
  34 /3 width=3 by lpx_cpxs_trans, lex_CTC_step_dx/ qed-.
  35
  36 (* Eliminators with unbound rt-transition for full local environments *******)
  37
  38 (* Basic_2A1: was: lpxs_ind_dx *)
  39 lemma lpxs_ind_sn (h) (G) (L2): ∀Q:predicate lenv. Q L2 →
  40                                 (∀L1,L. ⦃G, L1⦄ ⊢ ⬈[h] L → ⦃G, L⦄ ⊢ ⬈*[h] L2 → Q L → Q L1) →
  41                                 ∀L1. ⦃G, L1⦄ ⊢ ⬈*[h] L2 → Q L1.
  42 /3 width=7 by lpx_cpxs_trans, cpx_refl, lex_CTC_ind_sn/ qed-.
  43
  44 (* Basic_2A1: was: lpxs_ind *)
  45 lemma lpxs_ind_dx (h) (G) (L1): ∀Q:predicate lenv. Q L1 →
  46                                 (∀L,L2. ⦃G, L1⦄ ⊢ ⬈*[h] L → ⦃G, L⦄ ⊢ ⬈[h] L2 → Q L → Q L2) →
  47                                 ∀L2. ⦃G, L1⦄ ⊢ ⬈*[h] L2 → Q L2.
  48 /3 width=7 by lpx_cpxs_trans, cpx_refl, lex_CTC_ind_dx/ qed-.
  49
  50 (* Properties with context-sensitive extended rt-transition for terms *******)
  51
  52 lemma lpxs_cpx_trans (h) (G): s_r_transitive … (cpx h G) (λ_.lpxs h G).
  53 #h #G #L2 #T1 #T2 #HT12 #L1 #HL12
  54 @(s_r_trans_CTC2 ???????? HT12) -HT12
  55 /2 width=4 by lpx_cpxs_trans, lex_inv_CTC/
  56 qed-.
  57
  58 (* Properties with context-sensitive extended rt-computation for terms ******)
  59
  60 (* Note: alternative proof by s_r_to_s_rs_trans *)
  61 lemma lpxs_cpxs_trans (h) (G): s_rs_transitive … (cpx h G) (λ_.lpxs h G).
  62 #h #G @s_r_trans_CTC1 /2 width=3 by lpxs_cpx_trans/
  63 qed-.
  64
  65 (* Advanced properties ******************************************************)
  66
  67 (* Basic_2A1: was: lpxs_pair2 *)
  68 lemma lpxs_pair_dx (h) (G): ∀L1,L2. ⦃G, L1⦄ ⊢ ⬈*[h] L2 →
  69                             ∀V1,V2. ⦃G, L2⦄ ⊢ V1 ⬈*[h] V2 →
  70                             ∀I. ⦃G, L1.ⓑ{I}V1⦄ ⊢ ⬈*[h] L2.ⓑ{I}V2.
  71 /3 width=3 by lpxs_pair, lpxs_cpxs_trans/ qed.