matita/matita/contribs/lambdadelta/basic_2/rt_computation/lpxs_reqg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/lpx_reqg.ma".
  16 include "basic_2/rt_computation/lpxs_lpx.ma".
  17
  18 (* EXTENDED PARALLEL RT-COMPUTATION FOR FULL LOCAL ENVIRONMENTS *************)
  19
  20 (* Properties with generic equivalence on referred entries ******************)
  21
  22 (* Basic_2A1: uses: lleq_lpxs_trans *)
  23 lemma reqg_lpxs_trans (S) (G) (T:term):
  24       reflexive … S → symmetric … S →
  25       ∀L2,K2. ❪G,L2❫ ⊢ ⬈* K2 → ∀L1. L1 ≛[S,T] L2 →
  26       ∃∃K1. ❪G,L1❫ ⊢ ⬈* K1 & K1 ≛[S,T] K2.
  27 #S #G #T #H1S #H2S #L2 #K2 #H @(lpxs_ind_sn … H) -L2 /2 width=3 by ex2_intro/
  28 #L #L2 #HL2 #_ #IH #L1 #HT
  29 elim (reqg_lpx_trans … HL2 … HT) // -L #L #HL1 #HT
  30 elim (IH … HT) -L2 #K #HLK #HT
  31 /3 width=3 by lpxs_step_sn, ex2_intro/
  32 qed-.
  33
  34 (* Basic_2A1: uses: lpxs_nlleq_inv_step_sn *)
  35 lemma lpxs_rneqg_inv_step_sn (S) (G) (T:term):
  36       reflexive … S → symmetric … S → Transitive … S →
  37       (∀s1,s2. Decidable (S s1 s2)) →
  38       ∀L1,L2. ❪G,L1❫ ⊢ ⬈* L2 → (L1 ≛[S,T] L2 → ⊥) →
  39       ∃∃L,L0. ❪G,L1❫ ⊢ ⬈ L & L1 ≛[S,T] L → ⊥ & ❪G,L❫ ⊢ ⬈* L0 & L0 ≛[S,T] L2.
  40 #S #G #T #H1S #H2S #H3S #H4S #L1 #L2 #H @(lpxs_ind_sn … H) -L1
  41 [ #H elim H -H /2 width=1 by reqg_refl/
  42 | #L1 #L #H1 #H2 #IH2 #H12 elim (reqg_dec S … L1 L T) // #H
  43   [ -H1 -H2 elim IH2 -IH2 /3 width=3 by reqg_trans/ -H12
  44     #L0 #L3 #H1 #H2 #H3 #H4 lapply (reqg_rneqg_trans … H … H2) -H2 //
  45     #H2 elim (reqg_lpx_trans … H1 … H) -L //
  46     #L #H1 #H lapply (rneqg_reqg_div … H … H2) -H2 //
  47     #H2 elim (reqg_lpxs_trans … H3 … H) -L0
  48     /3 width=8 by reqg_trans, ex4_2_intro/
  49   | -H12 -IH2 /3 width=6 by reqg_refl, ex4_2_intro/
  50   ]
  51 ]
  52 qed-.