matita/matita/contribs/lambdadelta/basic_2/rt_computation/lsubsx_rdsx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_computation/rdsx_drops.ma".
  16 include "basic_2/rt_computation/rdsx_lpxs.ma".
  17 include "basic_2/rt_computation/lsubsx.ma".
  18
  19 (* CLEAR OF STRONGLY NORMALIZING ENTRIES FOR UNBOUND RT-TRANSITION **********)
  20
  21 (* Properties with strongly normalizing referred local environments *********)
  22
  23 (* Basic_2A1: uses: lsx_cpx_trans_lcosx *)
  24 lemma rdsx_cpx_trans_lsubsx (h) (o): ∀G,L0,T1,T2. ⦃G, L0⦄ ⊢ T1 ⬈[h] T2 →
  25                                      ∀f,L. G ⊢ L0 ⊆ⓧ[h, o, f] L →
  26                                      G ⊢ ⬈*[h, o, T1] 𝐒⦃L⦄ → G ⊢ ⬈*[h, o, T2] 𝐒⦃L⦄.
  27 #h #o #G #L0 #T1 #T2 #H @(cpx_ind … H) -G -L0 -T1 -T2 //
  28 [ #I0 #G #K0 #V1 #V2 #W2 #_ #IH #HVW2 #g #L #HK0 #HL
  29   elim (lsubsx_inv_pair_sn_gen … HK0) -HK0 *
  30   [ #f #K #HK0 #H1 #H2 destruct
  31     /4 width=8 by rdsx_lifts, rdsx_fwd_pair, drops_refl, drops_drop/
  32   | #f #K #HV1 #HK0 #H1 #H2 destruct
  33     /4 width=8 by rdsx_lifts, drops_refl, drops_drop/
  34   ]
  35 | #I0 #G #K0 #T #U #i #_ #IH #HTU #g #L #HK0 #HL
  36   elim (lsubsx_fwd_bind_sn … HK0) -HK0 #I #K #HK0 #H destruct
  37   /6 width=8 by rdsx_inv_lifts, rdsx_lifts, drops_refl, drops_drop/
  38 | #p #I0 #G #L0 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #f #L #HL0 #HL
  39   elim (rdsx_inv_bind … HL) -HL
  40   /4 width=2 by lsubsx_pair, rdsx_bind_void/
  41 | #I0 #G #L0 #V1 #V2 #T1 #T2 #_ #_ #IHV12 #IHT12 #f #L #HL0 #HL
  42   elim (rdsx_inv_flat … HL) -HL /3 width=2 by rdsx_flat/
  43 | #G #L0 #V #U1 #T1 #T2 #HTU1 #_ #IHT12 #f #L #HL0 #HL
  44   elim (rdsx_inv_bind … HL) -HL #HV #HU1
  45   /5 width=8 by rdsx_inv_lifts, drops_refl, drops_drop/
  46 | #G #L0 #V #T1 #T2 #_ #IHT12 #f #L #HL0 #HL
  47   elim (rdsx_inv_flat … HL) -HL /2 width=2 by/
  48 | #G #L0 #V1 #V2 #T #_ #IHV12 #f #L #HL0 #HL
  49   elim (rdsx_inv_flat … HL) -HL /2 width=2 by/
  50 | #p #G #L0 #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #f #L #HL0 #HL
  51   elim (rdsx_inv_flat … HL) -HL #HV1 #HL
  52   elim (rdsx_inv_bind … HL) -HL #HW1 #HT1
  53   /4 width=2 by lsubsx_pair, rdsx_bind_void, rdsx_flat/
  54 | #p #G #L0 #V1 #V2 #U2 #W1 #W2 #T1 #T2 #_ #_ #_ #IHV12 #IHW12 #IHT12 #HVU2 #f #L #HL0 #HL
  55   elim (rdsx_inv_flat … HL) -HL #HV1 #HL
  56   elim (rdsx_inv_bind … HL) -HL #HW1 #HT1
  57   /6 width=8 by lsubsx_pair, rdsx_lifts, rdsx_bind_void, rdsx_flat, drops_refl, drops_drop/
  58 ]
  59 qed-.
  60
  61 (* Advanced properties of strongly normalizing referred local environments **)
  62
  63 (* Basic_2A1: uses: lsx_cpx_trans_O *)
  64 lemma rdsx_cpx_trans (h) (o): ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ⬈[h] T2 →
  65                               G ⊢ ⬈*[h, o, T1] 𝐒⦃L⦄ → G ⊢ ⬈*[h, o, T2] 𝐒⦃L⦄.
  66 /3 width=6 by rdsx_cpx_trans_lsubsx, lsubsx_refl/ qed-.
  67
  68 lemma rdsx_cpxs_trans (h) (o): ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ⬈*[h] T2 →
  69                                G ⊢ ⬈*[h, o, T1] 𝐒⦃L⦄ → G ⊢ ⬈*[h, o, T2] 𝐒⦃L⦄.
  70 #h #o #G #L #T1 #T2 #H
  71 @(cpxs_ind_dx ???????? H) -T1 //
  72 /3 width=3 by rdsx_cpx_trans/
  73 qed-.