matita/matita/contribs/lambdadelta/basic_2/rt_computation/rdsx.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/predtysnstrong_4.ma".
  16 include "static_2/static/rdeq.ma".
  17 include "basic_2/rt_transition/lpx.ma".
  18
  19 (* STRONGLY NORMALIZING REFERRED LOCAL ENV.S FOR UNBOUND RT-TRANSITION ******)
  20
  21 definition rdsx (h) (G) (T): predicate lenv ≝
  22                              SN … (lpx h G) (rdeq T).
  23
  24 interpretation
  25    "strong normalization for unbound context-sensitive parallel rt-transition on referred entries (local environment)"
  26    'PRedTySNStrong h T G L = (rdsx h G T L).
  27
  28 (* Basic eliminators ********************************************************)
  29
  30 (* Basic_2A1: uses: lsx_ind *)
  31 lemma rdsx_ind (h) (G) (T):
  32                ∀Q:predicate lenv.
  33                (∀L1. G ⊢ ⬈*[h, T] 𝐒⦃L1⦄ →
  34                      (∀L2. ⦃G, L1⦄ ⊢ ⬈[h] L2 → (L1 ≛[T] L2 → ⊥) → Q L2) →
  35                      Q L1
  36                ) →
  37                ∀L. G ⊢ ⬈*[h, T] 𝐒⦃L⦄ →  Q L.
  38 #h #G #T #Q #H0 #L1 #H elim H -L1
  39 /5 width=1 by SN_intro/
  40 qed-.
  41
  42 (* Basic properties *********************************************************)
  43
  44 (* Basic_2A1: uses: lsx_intro *)
  45 lemma rdsx_intro (h) (G) (T):
  46                  ∀L1.
  47                  (∀L2. ⦃G, L1⦄ ⊢ ⬈[h] L2 → (L1 ≛[T] L2 → ⊥) → G ⊢ ⬈*[h, T] 𝐒⦃L2⦄) →
  48                  G ⊢ ⬈*[h, T] 𝐒⦃L1⦄.
  49 /5 width=1 by SN_intro/ qed.
  50
  51 (* Basic forward lemmas *****************************************************)
  52
  53 (* Basic_2A1: uses: lsx_fwd_pair_sn lsx_fwd_bind_sn lsx_fwd_flat_sn *)
  54 lemma rdsx_fwd_pair_sn (h) (G):
  55                        ∀I,L,V,T. G ⊢ ⬈*[h, ②{I}V.T] 𝐒⦃L⦄ →
  56                        G ⊢ ⬈*[h, V] 𝐒⦃L⦄.
  57 #h #G #I #L #V #T #H
  58 @(rdsx_ind … H) -L #L1 #_ #IHL1
  59 @rdsx_intro #L2 #HL12 #HnL12
  60 /4 width=3 by rdeq_fwd_pair_sn/
  61 qed-.
  62
  63 (* Basic_2A1: uses: lsx_fwd_flat_dx *)
  64 lemma rdsx_fwd_flat_dx (h) (G):
  65                        ∀I,L,V,T. G ⊢ ⬈*[h, ⓕ{I}V.T] 𝐒⦃L⦄ →
  66                        G ⊢ ⬈*[h, T] 𝐒⦃L⦄.
  67 #h #G #I #L #V #T #H
  68 @(rdsx_ind … H) -L #L1 #_ #IHL1
  69 @rdsx_intro #L2 #HL12 #HnL12
  70 /4 width=3 by rdeq_fwd_flat_dx/
  71 qed-.
  72
  73 fact rdsx_fwd_pair_aux (h) (G):
  74      ∀L. G ⊢ ⬈*[h, #0] 𝐒⦃L⦄ →
  75      ∀I,K,V. L = K.ⓑ{I}V → G ⊢ ⬈*[h, V] 𝐒⦃K⦄.
  76 #h #G #L #H
  77 @(rdsx_ind … H) -L #L1 #_ #IH #I #K1 #V #H destruct
  78 /5 width=5 by lpx_pair, rdsx_intro, rdeq_fwd_zero_pair/
  79 qed-.
  80
  81 lemma rdsx_fwd_pair (h) (G):
  82                     ∀I,K,V. G ⊢ ⬈*[h, #0] 𝐒⦃K.ⓑ{I}V⦄ → G ⊢ ⬈*[h, V] 𝐒⦃K⦄.
  83 /2 width=4 by rdsx_fwd_pair_aux/ qed-.
  84
  85 (* Basic inversion lemmas ***************************************************)
  86
  87 (* Basic_2A1: uses: lsx_inv_flat *)
  88 lemma rdsx_inv_flat (h) (G):
  89       ∀I,L,V,T. G ⊢ ⬈*[h, ⓕ{I}V.T] 𝐒⦃L⦄ →
  90       ∧∧ G ⊢ ⬈*[h, V] 𝐒⦃L⦄ & G ⊢ ⬈*[h, T] 𝐒⦃L⦄.
  91 /3 width=3 by rdsx_fwd_pair_sn, rdsx_fwd_flat_dx, conj/ qed-.
  92
  93 (* Basic_2A1: removed theorems 9:
  94               lsx_ge_up lsx_ge
  95               lsxa_ind lsxa_intro lsxa_lleq_trans lsxa_lpxs_trans lsxa_intro_lpx lsx_lsxa lsxa_inv_lsx
  96 *)