matita/matita/contribs/lambdadelta/basic_2/rt_computation/rdsx_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/rdeq_drops.ma".
  16 include "basic_2/rt_transition/lpx_drops.ma".
  17 include "basic_2/rt_computation/rdsx_length.ma".
  18 include "basic_2/rt_computation/rdsx_fqup.ma".
  19
  20 (* STRONGLY NORMALIZING REFERRED LOCAL ENV.S FOR UNBOUND RT-TRANSITION ******)
  21
  22 (* Properties with generic relocation ***************************************)
  23
  24 (* Note: this uses length *)
  25 (* Basic_2A1: uses: lsx_lift_le lsx_lift_ge *)
  26 lemma rdsx_lifts (h) (o) (G): d_liftable1_isuni … (λL,T. G ⊢ ⬈*[h, o, T] 𝐒⦃L⦄).
  27 #h #o #G #K #T #H @(rdsx_ind … H) -K
  28 #K1 #_ #IH #b #f #L1 #HLK1 #Hf #U #HTU @rdsx_intro
  29 #L2 #HL12 #HnL12 elim (lpx_drops_conf … HLK1 … HL12)
  30 /5 width=9 by rdeq_lifts_bi, lpx_fwd_length/
  31 qed-.
  32
  33 (* Inversion lemmas on relocation *******************************************)
  34
  35 (* Basic_2A1: uses: lsx_inv_lift_le lsx_inv_lift_be lsx_inv_lift_ge *)
  36 lemma rdsx_inv_lifts (h) (o) (G): d_deliftable1_isuni … (λL,T. G ⊢ ⬈*[h, o, T] 𝐒⦃L⦄).
  37 #h #o #G #L #U #H @(rdsx_ind … H) -L
  38 #L1 #_ #IH #b #f #K1 #HLK1 #Hf #T #HTU @rdsx_intro
  39 #K2 #HK12 #HnK12 elim (drops_lpx_trans … HLK1 … HK12) -HK12
  40 /4 width=10 by rdeq_inv_lifts_bi/
  41 qed-.
  42
  43 (* Advanced properties ******************************************************)
  44
  45 (* Basic_2A1: uses: lsx_lref_free *)
  46 lemma rdsx_lref_atom (h) (o) (G): ∀L,i. ⬇*[Ⓕ, 𝐔❴i❵] L ≘ ⋆ → G ⊢ ⬈*[h, o, #i] 𝐒⦃L⦄.
  47 #h #o #G #L1 #i #HL1
  48 @(rdsx_lifts … (#0) … HL1) -HL1 //
  49 qed.
  50
  51 (* Basic_2A1: uses: lsx_lref_skip *)
  52 lemma rdsx_lref_unit (h) (o) (G): ∀I,L,K,i. ⬇*[i] L ≘ K.ⓤ{I} → G ⊢ ⬈*[h, o, #i] 𝐒⦃L⦄.
  53 #h #o #G #I #L1 #K1 #i #HL1
  54 @(rdsx_lifts … (#0) … HL1) -HL1 //
  55 qed.
  56
  57 (* Advanced forward lemmas **************************************************)
  58
  59 (* Basic_2A1: uses: lsx_fwd_lref_be *)
  60 lemma rdsx_fwd_lref_pair (h) (o) (G):
  61                          ∀L,i. G ⊢ ⬈*[h, o, #i] 𝐒⦃L⦄ →
  62                          ∀I,K,V. ⬇*[i] L ≘ K.ⓑ{I}V → G ⊢ ⬈*[h, o, V] 𝐒⦃K⦄.
  63 #h #o #G #L #i #HL #I #K #V #HLK
  64 lapply (rdsx_inv_lifts … HL … HLK … (#0) ?) -L
  65 /2 width=2 by rdsx_fwd_pair/
  66 qed-.