matita/matita/contribs/lambdadelta/basic_2/rt_computation/rdsx_fqup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/rdeq_fqup.ma".
  16 include "basic_2/rt_computation/rdsx.ma".
  17
  18 (* STRONGLY NORMALIZING REFERRED LOCAL ENV.S FOR UNBOUND RT-TRANSITION ******)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 (* Basic_2A1: uses: lsx_atom *)
  23 lemma lfsx_atom (h) (G) (T): G ⊢ ⬈*[h, T] 𝐒⦃⋆⦄.
  24 #h #G #T
  25 @rdsx_intro #Y #H #HnT
  26 lapply (lpx_inv_atom_sn … H) -H #H destruct
  27 elim HnT -HnT //
  28 qed.
  29
  30 (* Advanced forward lemmas **************************************************)
  31
  32 (* Basic_2A1: uses: lsx_fwd_bind_dx *)
  33 (* Note: the exclusion binder (ⓧ) makes this more elegant and much simpler *)
  34 (* Note: the old proof without the exclusion binder requires lreq *)
  35 lemma rdsx_fwd_bind_dx (h) (G):
  36                        ∀p,I,L,V,T. G ⊢ ⬈*[h, ⓑ{p,I}V.T] 𝐒⦃L⦄ →
  37                        G ⊢ ⬈*[h, T] 𝐒⦃L.ⓧ⦄.
  38 #h #G #p #I #L #V #T #H
  39 @(rdsx_ind … H) -L #L1 #_ #IH
  40 @rdsx_intro #Y #H #HT
  41 elim (lpx_inv_unit_sn … H) -H #L2 #HL12 #H destruct
  42 /4 width=4 by rdeq_fwd_bind_dx_void/
  43 qed-.
  44
  45 (* Advanced inversion lemmas ************************************************)
  46
  47 (* Basic_2A1: uses: lsx_inv_bind *)
  48 lemma rdsx_inv_bind (h) (G):
  49       ∀p,I,L,V,T. G ⊢ ⬈*[h, ⓑ{p,I}V.T] 𝐒⦃L⦄ →
  50       ∧∧ G ⊢ ⬈*[h, V] 𝐒⦃L⦄ & G ⊢ ⬈*[h, T] 𝐒⦃L.ⓧ⦄.
  51 /3 width=4 by rdsx_fwd_pair_sn, rdsx_fwd_bind_dx, conj/ qed-.