matita/matita/contribs/lambdadelta/basic_2/rt_computation/rsx_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/reqx_drops.ma".
  16 include "basic_2/rt_transition/lpx_drops.ma".
  17 include "basic_2/rt_computation/rsx_length.ma".
  18 include "basic_2/rt_computation/rsx_fqup.ma".
  19
  20 (* STRONGLY NORMALIZING REFERRED LOCAL ENV.S FOR UNBOUND RT-TRANSITION ******)
  21
  22 (* Properties with generic relocation ***************************************)
  23
  24 (* Note: this uses length *)
  25 (* Basic_2A1: uses: lsx_lift_le lsx_lift_ge *)
  26 lemma rsx_lifts (h) (G):
  27       d_liftable1_isuni … (λL,T. G ⊢ ⬈*𝐒[h,T] L).
  28 #h #G #K #T #H @(rsx_ind … H) -K
  29 #K1 #_ #IH #b #f #L1 #HLK1 #Hf #U #HTU @rsx_intro
  30 #L2 #HL12 #HnL12 elim (lpx_drops_conf … HLK1 … HL12)
  31 /5 width=9 by reqx_lifts_bi, lpx_fwd_length/
  32 qed-.
  33
  34 (* Inversion lemmas on relocation *******************************************)
  35
  36 (* Basic_2A1: uses: lsx_inv_lift_le lsx_inv_lift_be lsx_inv_lift_ge *)
  37 lemma rsx_inv_lifts (h) (G):
  38       d_deliftable1_isuni … (λL,T. G ⊢ ⬈*𝐒[h,T] L).
  39 #h #G #L #U #H @(rsx_ind … H) -L
  40 #L1 #_ #IH #b #f #K1 #HLK1 #Hf #T #HTU @rsx_intro
  41 #K2 #HK12 #HnK12 elim (drops_lpx_trans … HLK1 … HK12) -HK12
  42 /4 width=10 by reqx_inv_lifts_bi/
  43 qed-.
  44
  45 (* Advanced properties ******************************************************)
  46
  47 (* Basic_2A1: uses: lsx_lref_free *)
  48 lemma rsx_lref_atom_drops (h) (G):
  49       ∀L,i. ⇩*[Ⓕ,𝐔❨i❩] L ≘ ⋆ → G ⊢ ⬈*𝐒[h,#i] L.
  50 #h #G #L1 #i #HL1
  51 @(rsx_lifts … (#0) … HL1) -HL1 //
  52 qed.
  53
  54 (* Basic_2A1: uses: lsx_lref_skip *)
  55 lemma rsx_lref_unit_drops (h) (G):
  56       ∀I,L,K,i. ⇩[i] L ≘ K.ⓤ[I] → G ⊢ ⬈*𝐒[h,#i] L.
  57 #h #G #I #L1 #K1 #i #HL1
  58 @(rsx_lifts … (#0) … HL1) -HL1 //
  59 qed.
  60
  61 (* Advanced forward lemmas **************************************************)
  62
  63 (* Basic_2A1: uses: lsx_fwd_lref_be *)
  64 lemma rsx_fwd_lref_pair_drops (h) (G):
  65       ∀L,i. G ⊢ ⬈*𝐒[h,#i] L →
  66       ∀I,K,V. ⇩[i] L ≘ K.ⓑ[I]V → G ⊢ ⬈*𝐒[h,V] K.
  67 #h #G #L #i #HL #I #K #V #HLK
  68 lapply (rsx_inv_lifts … HL … HLK … (#0) ?) -L
  69 /2 width=2 by rsx_fwd_pair/
  70 qed-.