matita/matita/contribs/lambdadelta/basic_2/rt_computation/rsx_fqup.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/static/reqx_fqup.ma".
  16 include "basic_2/rt_computation/rsx.ma".
  17
  18 (* STRONGLY NORMALIZING REFERRED LOCAL ENV.S FOR UNBOUND RT-TRANSITION ******)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 (* Basic_2A1: uses: lsx_atom *)
  23 lemma lfsx_atom (h) (G) (T): G ⊢ ⬈*𝐒[h,T] ⋆.
  24 #h #G #T
  25 @rsx_intro #Y #H #HnT
  26 lapply (lpx_inv_atom_sn … H) -H #H destruct
  27 elim HnT -HnT //
  28 qed.
  29
  30 (* Advanced forward lemmas **************************************************)
  31
  32 (* Basic_2A1: uses: lsx_fwd_bind_dx *)
  33 (* Note: the exclusion binder (ⓧ) makes this more elegant and much simpler *)
  34 (* Note: the old proof without the exclusion binder requires lreq *)
  35 lemma rsx_fwd_bind_dx_void (h) (G):
  36       ∀p,I,L,V,T. G ⊢ ⬈*𝐒[h,ⓑ[p,I]V.T] L → G ⊢ ⬈*𝐒[h,T] L.ⓧ.
  37 #h #G #p #I #L #V #T #H
  38 @(rsx_ind … H) -L #L1 #_ #IH
  39 @rsx_intro #Y #H #HT
  40 elim (lpx_inv_unit_sn … H) -H #L2 #HL12 #H destruct
  41 /4 width=4 by reqx_fwd_bind_dx_void/
  42 qed-.
  43
  44 (* Advanced inversion lemmas ************************************************)
  45
  46 (* Basic_2A1: uses: lsx_inv_bind *)
  47 lemma rsx_inv_bind_void (h) (G):
  48       ∀p,I,L,V,T. G ⊢ ⬈*𝐒[h,ⓑ[p,I]V.T] L →
  49       ∧∧ G ⊢ ⬈*𝐒[h,V] L & G ⊢ ⬈*𝐒[h,T] L.ⓧ.
  50 /3 width=4 by rsx_fwd_pair_sn, rsx_fwd_bind_dx_void, conj/ qed-.