matita/matita/contribs/lambdadelta/basic_2/rt_equivalence/cpcs_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_equivalence/cpcs_cprs.ma".
  16
  17 (* CONTEXT-SENSITIVE PARALLEL R-EQUIVALENCE FOR TERMS ***********************)
  18
  19 (* Properties with generic slicing for local environments *******************)
  20
  21 (* Basic_1: was: pc3_lift *)
  22 (* Basic_2A1: was: cpcs_lift *)
  23 lemma cpcs_lifts_bi (h) (G): d_liftable2_bi … lifts (cpcs h G).
  24 #h #G #K #T1 #T2 #HT12 #b #f #L #HLK #U1 #HTU1 #U2 #HTU2
  25 elim (cpcs_inv_cprs … HT12) -HT12 #T #HT1 #HT2
  26 elim (lifts_total T f) #U #HU
  27 /3 width=12 by cprs_div, cpms_lifts_bi/
  28 qed-.
  29
  30 (* Inversion lemmas with generic slicing for local environments *************)
  31
  32 (* Basic_1: was: pc3_gen_lift *)
  33 (* Basic_2A1: was cpcs_inv_lift *)
  34 lemma cpcs_inv_lifts_bi (h) (G): d_deliftable2_bi … lifts (cpcs h G).
  35 #h #G #L #U1 #U2 #HU12 #b #f #K #HLK #T1 #HTU1 #T2 #HTU2
  36 elim (cpcs_inv_cprs … HU12) -HU12 #U #HU1 #HU2
  37 elim (cpms_inv_lifts_sn … HU1 … HLK … HTU1) -U1 #T #HTU #HT1
  38 lapply (cpms_inv_lifts_bi … HU2 … HLK … HTU2 … HTU) -L -U -U2 -b -f #HT2
  39 /2 width=3 by cprs_div/
  40 qed-.