matita/matita/contribs/lambdadelta/basic_2/rt_equivalence/cpes.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/pconvstar_7.ma".
  16 include "basic_2/rt_computation/cpms.ma".
  17
  18 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-EQUIVALENCE FOR TERMS **************)
  19
  20 (* Basic_2A1: uses: scpes *)
  21 definition cpes (h) (n1) (n2): relation4 genv lenv term term ≝
  22            λG,L,T1,T2.
  23            ∃∃T. ⦃G, L⦄ ⊢ T1 ➡*[n1,h] T & ⦃G, L⦄ ⊢ T2 ➡*[n2,h] T.
  24
  25 interpretation "t-bound context-sensitive parallel rt-equivalence (term)"
  26    'PConvStar h n1 n2 G L T1 T2 = (cpes h n1 n2 G L T1 T2).
  27
  28 (* Basic properties *********************************************************)
  29
  30 (* Basic_2A1: uses: scpds_div *)
  31 lemma cpms_div (h) (n1) (n2):
  32       ∀G,L,T1,T. ⦃G, L⦄ ⊢ T1 ➡*[n1,h] T →
  33       ∀T2. ⦃G, L⦄ ⊢ T2 ➡*[n2,h] T → ⦃G, L⦄ ⊢ T1 ⬌*[h,n1,n2] T2.
  34 /2 width=3 by ex2_intro/ qed.
  35
  36 lemma cpes_refl (h): ∀G,L. reflexive … (cpes h 0 0 G L).
  37 /2 width=3 by cpms_div/ qed.
  38
  39 (* Basic_2A1: uses: scpes_sym *)
  40 lemma cpes_sym (h) (n1) (n2):
  41       ∀G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ⬌*[h,n1,n2] T2 → ⦃G, L⦄ ⊢ T2 ⬌*[h,n2,n1] T1.
  42 #h #n1 #n2 #G #L #T1 #T2 * /2 width=3 by cpms_div/
  43 qed-.