matita/matita/contribs/lambdadelta/basic_2/rt_transition/cnr_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/rt_transition/cpr_drops.ma".
  16 include "basic_2/rt_transition/cnr.ma".
  17
  18 (* NORMAL TERMS FOR CONTEXT-SENSITIVE R-TRANSITION **************************)
  19
  20 (* Advanced properties ******************************************************)
  21
  22 (* Basic_1: was only: nf2_csort_lref *)
  23 lemma cnr_lref_atom (h) (b) (G) (L):
  24       ∀i. ⬇*[b,𝐔❴i❵] L ≘ ⋆ → ⦃G, L⦄ ⊢ ➡[h] 𝐍⦃#i⦄.
  25 #h #b #G #L #i #Hi #X #H
  26 elim (cpr_inv_lref1_drops … H) -H // * #K #V1 #V2 #HLK
  27 lapply (drops_gen b … HLK) -HLK #HLK
  28 lapply (drops_mono … Hi … HLK) -L #H destruct
  29 qed.
  30
  31 (* Basic_1: was: nf2_lref_abst *)
  32 lemma cnr_lref_abst (h) (G) (L):
  33       ∀K,V,i. ⬇*[i] L ≘ K.ⓛV → ⦃G, L⦄ ⊢ ➡[h] 𝐍⦃#i⦄.
  34 #h #G #L #K #V #i #HLK #X #H
  35 elim (cpr_inv_lref1_drops … H) -H // *
  36 #K0 #V1 #V2 #HLK0 #_ #_
  37 lapply (drops_mono … HLK … HLK0) -L #H destruct
  38 qed.
  39
  40 lemma cnr_lref_unit (h) (I) (G) (L):
  41       ∀K,i. ⬇*[i] L ≘ K.ⓤ{I} → ⦃G, L⦄ ⊢ ➡[h] 𝐍⦃#i⦄.
  42 #h #I #G #L #K #i #HLK #X #H
  43 elim (cpr_inv_lref1_drops … H) -H // *
  44 #K0 #V1 #V2 #HLK0 #_ #_
  45 lapply (drops_mono … HLK … HLK0) -L #H destruct
  46 qed.
  47
  48 (* Properties with generic relocation ***************************************)
  49
  50 (* Basic_1: was: nf2_lift *)
  51 (* Basic_2A1: uses: cnr_lift *)
  52 lemma cnr_lifts (h) (G): d_liftable1 … (cnr h G).
  53 #h #G #K #T #HT #b #f #L #HLK #U #HTU #U0 #H
  54 elim (cpm_inv_lifts_sn … H … HLK … HTU) -b -L #T0 #HTU0 #HT0
  55 lapply (HT … HT0) -G -K #H destruct /2 width=4 by lifts_mono/
  56 qed-.
  57
  58 (* Advanced inversion lemmas ************************************************)
  59
  60 (* Basic_2A1: was: cnr_inv_delta *)
  61 lemma cnr_inv_lref_abbr (h) (G) (L):
  62       ∀K,V,i. ⬇*[i] L ≘ K.ⓓV → ⦃G, L⦄ ⊢ ➡[h] 𝐍⦃#i⦄ → ⊥.
  63 #h #G #L #K #V #i #HLK #H
  64 elim (lifts_total V 𝐔❴↑i❵) #W #HVW
  65 lapply (H W ?) -H [ /3 width=6 by cpm_delta_drops/ ] -HLK #H destruct
  66 elim (lifts_inv_lref2_uni_lt … HVW) -HVW //
  67 qed-.
  68
  69 (* Inversion lemmas with generic relocation *********************************)
  70
  71 (* Note: this was missing in Basic_1 *)
  72 (* Basic_2A1: uses: cnr_inv_lift *)
  73 lemma cnr_inv_lifts (h) (G): d_deliftable1 … (cnr h G).
  74 #h #G #L #U #HU #b #f #K #HLK #T #HTU #T0 #H
  75 elim (cpm_lifts_sn … H … HLK … HTU) -b -K #U0 #HTU0 #HU0
  76 lapply (HU … HU0) -G -L #H destruct /2 width=4 by lifts_inj/
  77 qed-.