matita/matita/contribs/lambdadelta/basic_2/rt_transition/cnx_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/lifts_teqx.ma".
  16 include "basic_2/rt_transition/cpx_drops.ma".
  17 include "basic_2/rt_transition/cnx.ma".
  18
  19 (* NORMAL TERMS FOR UNBOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION ********)
  20
  21 (* Properties with generic slicing ******************************************)
  22
  23 lemma cnx_lref_atom: ∀h,G,L,i. ⇩[i] L ≘ ⋆ → ❪G,L❫ ⊢ ⬈𝐍[h] #i.
  24 #h #G #L #i #Hi #X #H elim (cpx_inv_lref1_drops … H) -H // *
  25 #I #K #V1 #V2 #HLK lapply (drops_mono … Hi … HLK) -L #H destruct
  26 qed.
  27
  28 lemma cnx_lref_unit: ∀h,I,G,L,K,i. ⇩[i] L ≘ K.ⓤ[I] → ❪G,L❫ ⊢ ⬈𝐍[h] #i.
  29 #h #I #G #L #K #i #HLK #X #H elim (cpx_inv_lref1_drops … H) -H // *
  30 #Z #Y #V1 #V2 #HLY lapply (drops_mono … HLK … HLY) -L #H destruct
  31 qed.
  32
  33 (* Basic_2A1: includes: cnx_lift *)
  34 lemma cnx_lifts: ∀h,G. d_liftable1 … (cnx h G).
  35 #h #G #K #T #HT #b #f #L #HLK #U #HTU #U0 #H
  36 elim (cpx_inv_lifts_sn … H … HLK … HTU) -b -L #T0 #HTU0 #HT0
  37 lapply (HT … HT0) -G -K /2 width=6 by teqx_lifts_bi/
  38 qed-.
  39
  40 (* Inversion lemmas with generic slicing ************************************)
  41
  42 (* Basic_2A1: was: cnx_inv_delta *)
  43 lemma cnx_inv_lref_pair:
  44       ∀h,I,G,L,K,V,i. ⇩[i] L ≘ K.ⓑ[I]V → ❪G,L❫ ⊢ ⬈𝐍[h] #i → ⊥.
  45 #h #I #G #L #K #V #i #HLK #H
  46 elim (lifts_total V (𝐔❨↑i❩)) #W #HVW
  47 lapply (H W ?) -H /2 width=7 by cpx_delta_drops/ -HLK
  48 #H lapply (teqx_inv_lref1 … H) -H #H destruct
  49 /2 width=5 by lifts_inv_lref2_uni_lt/
  50 qed-.
  51
  52 (* Basic_2A1: includes: cnx_inv_lift *)
  53 lemma cnx_inv_lifts: ∀h,G. d_deliftable1 … (cnx h G).
  54 #h #G #L #U #HU #b #f #K #HLK #T #HTU #T0 #H
  55 elim (cpx_lifts_sn … H … HLK … HTU) -b -K #U0 #HTU0 #HU0
  56 lapply (HU … HU0) -G -L /2 width=6 by teqx_inv_lifts_bi/
  57 qed-.