matita/matita/contribs/lambdadelta/basic_2/rt_transition/cnx_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/lifts_teqx.ma".
  16 include "basic_2/rt_transition/cpx_drops.ma".
  17 include "basic_2/rt_transition/cnx.ma".
  18
  19 (* NORMAL TERMS FOR EXTENDED CONTEXT-SENSITIVE PARALLEL RT-TRANSITION *******)
  20
  21 (* Properties with generic slicing ******************************************)
  22
  23 lemma cnx_lref_atom (G) (L):
  24       ∀i. ⇩[i] L ≘ ⋆ → ❪G,L❫ ⊢ ⬈𝐍 #i.
  25 #G #L #i #Hi #X #H elim (cpx_inv_lref1_drops … H) -H // *
  26 #I #K #V1 #V2 #HLK lapply (drops_mono … Hi … HLK) -L #H destruct
  27 qed.
  28
  29 lemma cnx_lref_unit (G) (L):
  30       ∀I,K,i. ⇩[i] L ≘ K.ⓤ[I] → ❪G,L❫ ⊢ ⬈𝐍 #i.
  31 #G #L #I #K #i #HLK #X #H elim (cpx_inv_lref1_drops … H) -H // *
  32 #Z #Y #V1 #V2 #HLY lapply (drops_mono … HLK … HLY) -L #H destruct
  33 qed.
  34
  35 (* Basic_2A1: includes: cnx_lift *)
  36 lemma cnx_lifts (G): d_liftable1 … (cnx G).
  37 #G #K #T #HT #b #f #L #HLK #U #HTU #U0 #H
  38 elim (cpx_inv_lifts_sn … H … HLK … HTU) -b -L #T0 #HTU0 #HT0
  39 lapply (HT … HT0) -G -K /2 width=6 by teqx_lifts_bi/
  40 qed-.
  41
  42 (* Inversion lemmas with generic slicing ************************************)
  43
  44 (* Basic_2A1: was: cnx_inv_delta *)
  45 lemma cnx_inv_lref_pair (G) (L):
  46       ∀I,K,V,i. ⇩[i] L ≘ K.ⓑ[I]V → ❪G,L❫ ⊢ ⬈𝐍 #i → ⊥.
  47 #G #L #I #K #V #i #HLK #H
  48 elim (lifts_total V (𝐔❨↑i❩)) #W #HVW
  49 lapply (H W ?) -H /2 width=7 by cpx_delta_drops/ -HLK
  50 #H lapply (teqx_inv_lref1 … H) -H #H destruct
  51 /2 width=5 by lifts_inv_lref2_uni_lt/
  52 qed-.
  53
  54 (* Basic_2A1: includes: cnx_inv_lift *)
  55 lemma cnx_inv_lifts (G): d_deliftable1 … (cnx G).
  56 #G #L #U #HU #b #f #K #HLK #T #HTU #T0 #H
  57 elim (cpx_lifts_sn … H … HLK … HTU) -b -K #U0 #HTU0 #HU0
  58 lapply (HU … HU0) -G -L /2 width=6 by teqx_inv_lifts_bi/
  59 qed-.