matita/matita/contribs/lambdadelta/basic_2/rt_transition/cnx_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/lifts_tdeq.ma".
  16 include "basic_2/rt_transition/cpx_drops.ma".
  17 include "basic_2/rt_transition/cnx.ma".
  18
  19 (* NORMAL TERMS FOR UNCOUNTED CONTEXT-SENSITIVE PARALLEL RT-TRANSITION ******)
  20
  21 (* Properties with generic slicing ******************************************)
  22
  23 lemma cnx_lref_atom: ∀h,o,G,L,i. ⬇*[i] L ≡ ⋆ → ⦃G, L⦄ ⊢ ⬈[h, o] 𝐍⦃#i⦄.
  24 #h #o #G #L #i #Hi #X #H elim (cpx_inv_lref1_drops … H) -H // *
  25 #I #K #V1 #V2 #HLK lapply (drops_mono … Hi … HLK) -L #H destruct
  26 qed.
  27
  28 (* Basic_2A1: includes: cnx_lift *)
  29 lemma cnx_lifts: ∀h,o,G. d_liftable1 … (cnx h o G).
  30 #h #o #G #K #T #HT #b #f #L #HLK #U #HTU #U0 #H
  31 elim (cpx_inv_lifts … H … HLK … HTU) -b -L #T0 #HTU0 #HT0
  32 lapply (HT … HT0) -G -K #HT0
  33 elim (tdeq_lifts … HT0 … HTU) -T #X #HX #HU
  34 <(lifts_mono … HX … HTU0) -T0 //
  35 qed-.
  36
  37 (* Inversion lemmas with generic slicing ************************************)
  38
  39 (* Basic_2A1: was: cnx_inv_delta *)
  40 lemma cnx_inv_lref_pair: ∀h,o,I,G,L,K,V,i. ⬇*[i] L ≡ K.ⓑ{I}V → ⦃G, L⦄ ⊢ ⬈[h, o] 𝐍⦃#i⦄ → ⊥.
  41 #h #o #I #G #L #K #V #i #HLK #H
  42 elim (lifts_total V (𝐔❴⫯i❵)) #W #HVW
  43 lapply (H W ?) -H /2 width=7 by cpx_delta_drops/ -HLK
  44 #H lapply (tdeq_inv_lref1 … H) -H #H destruct
  45 /2 width=5 by lifts_inv_lref2_uni_lt/
  46 qed-.
  47
  48 (* Basic_2A1: includes: cnx_inv_lift *)
  49 lemma cnx_inv_lifts: ∀h,o,G. d_deliftable1 … (cnx h o G).
  50 #h #o #G #L #U #HU #b #f #K #HLK #T #HTU #T0 #H
  51 elim (cpx_lifts … H … HLK … HTU) -b -K #U0 #HTU0 #HU0
  52 lapply (HU … HU0) -G -L #HU0
  53 elim (tdeq_inv_lifts … HU0 … HTU) -U #X #HX #HT
  54 <(lifts_inj … HX … HTU0) -U0 //
  55 qed-.