matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpg.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground_2/xoa/ex_3_3.ma".
  16 include "ground_2/xoa/ex_4_2.ma".
  17 include "ground_2/xoa/ex_4_4.ma".
  18 include "ground_2/xoa/ex_5_2.ma".
  19 include "ground_2/xoa/ex_6_9.ma".
  20 include "ground_2/xoa/ex_7_10.ma".
  21 include "ground_2/xoa/or_5.ma".
  22 include "ground_2/steps/rtc_max.ma".
  23 include "ground_2/steps/rtc_plus.ma".
  24 include "basic_2/notation/relations/predty_7.ma".
  25 include "static_2/syntax/sh.ma".
  26 include "static_2/syntax/lenv.ma".
  27 include "static_2/syntax/genv.ma".
  28 include "static_2/relocation/lifts.ma".
  29
  30 (* BOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS *****************)
  31
  32 (* avtivate genv *)
  33 inductive cpg (Rt:relation rtc) (h): rtc → relation4 genv lenv term term ≝
  34 | cpg_atom : ∀I,G,L. cpg Rt h (𝟘𝟘) G L (⓪[I]) (⓪[I])
  35 | cpg_ess  : ∀G,L,s. cpg Rt h (𝟘𝟙) G L (⋆s) (⋆(⫯[h]s))
  36 | cpg_delta: ∀c,G,L,V1,V2,W2. cpg Rt h c G L V1 V2 →
  37              ⇧*[1] V2 ≘ W2 → cpg Rt h c G (L.ⓓV1) (#0) W2
  38 | cpg_ell  : ∀c,G,L,V1,V2,W2. cpg Rt h c G L V1 V2 →
  39              ⇧*[1] V2 ≘ W2 → cpg Rt h (c+𝟘𝟙) G (L.ⓛV1) (#0) W2
  40 | cpg_lref : ∀c,I,G,L,T,U,i. cpg Rt h c G L (#i) T →
  41              ⇧*[1] T ≘ U → cpg Rt h c G (L.ⓘ[I]) (#↑i) U
  42 | cpg_bind : ∀cV,cT,p,I,G,L,V1,V2,T1,T2.
  43              cpg Rt h cV G L V1 V2 → cpg Rt h cT G (L.ⓑ[I]V1) T1 T2 →
  44              cpg Rt h ((↕*cV)∨cT) G L (ⓑ[p,I]V1.T1) (ⓑ[p,I]V2.T2)
  45 | cpg_appl : ∀cV,cT,G,L,V1,V2,T1,T2.
  46              cpg Rt h cV G L V1 V2 → cpg Rt h cT G L T1 T2 →
  47              cpg Rt h ((↕*cV)∨cT) G L (ⓐV1.T1) (ⓐV2.T2)
  48 | cpg_cast : ∀cU,cT,G,L,U1,U2,T1,T2. Rt cU cT →
  49              cpg Rt h cU G L U1 U2 → cpg Rt h cT G L T1 T2 →
  50              cpg Rt h (cU∨cT) G L (ⓝU1.T1) (ⓝU2.T2)
  51 | cpg_zeta : ∀c,G,L,V,T1,T,T2. ⇧*[1] T ≘ T1 → cpg Rt h c G L T T2 →
  52              cpg Rt h (c+𝟙𝟘) G L (+ⓓV.T1) T2
  53 | cpg_eps  : ∀c,G,L,V,T1,T2. cpg Rt h c G L T1 T2 → cpg Rt h (c+𝟙𝟘) G L (ⓝV.T1) T2
  54 | cpg_ee   : ∀c,G,L,V1,V2,T. cpg Rt h c G L V1 V2 → cpg Rt h (c+𝟘𝟙) G L (ⓝV1.T) V2
  55 | cpg_beta : ∀cV,cW,cT,p,G,L,V1,V2,W1,W2,T1,T2.
  56              cpg Rt h cV G L V1 V2 → cpg Rt h cW G L W1 W2 → cpg Rt h cT G (L.ⓛW1) T1 T2 →
  57              cpg Rt h (((↕*cV)∨(↕*cW)∨cT)+𝟙𝟘) G L (ⓐV1.ⓛ[p]W1.T1) (ⓓ[p]ⓝW2.V2.T2)
  58 | cpg_theta: ∀cV,cW,cT,p,G,L,V1,V,V2,W1,W2,T1,T2.
  59              cpg Rt h cV G L V1 V → ⇧*[1] V ≘ V2 → cpg Rt h cW G L W1 W2 →
  60              cpg Rt h cT G (L.ⓓW1) T1 T2 →
  61              cpg Rt h (((↕*cV)∨(↕*cW)∨cT)+𝟙𝟘) G L (ⓐV1.ⓓ[p]W1.T1) (ⓓ[p]W2.ⓐV2.T2)
  62 .
  63
  64 interpretation
  65    "bound context-sensitive parallel rt-transition (term)"
  66    'PRedTy Rt c h G L T1 T2 = (cpg Rt h c G L T1 T2).
  67
  68 (* Basic properties *********************************************************)
  69
  70 (* Note: this is "∀Rt. reflexive … Rt → ∀h,g,L. reflexive … (cpg Rt h (𝟘𝟘) L)" *)
  71 lemma cpg_refl: ∀Rt. reflexive … Rt → ∀h,G,T,L. ❪G,L❫ ⊢ T ⬈[Rt,𝟘𝟘,h] T.
  72 #Rt #HRt #h #G #T elim T -T // * /2 width=1 by cpg_bind/
  73 * /2 width=1 by cpg_appl, cpg_cast/
  74 qed.
  75
  76 (* Basic inversion lemmas ***************************************************)
  77
  78 fact cpg_inv_atom1_aux: ∀Rt,c,h,G,L,T1,T2. ❪G,L❫ ⊢ T1 ⬈[Rt,c,h] T2 → ∀J. T1 = ⓪[J] →
  79                         ∨∨ T2 = ⓪[J] ∧ c = 𝟘𝟘
  80                          | ∃∃s. J = Sort s & T2 = ⋆(⫯[h]s) & c = 𝟘𝟙
  81                          | ∃∃cV,K,V1,V2. ❪G,K❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ⇧*[1] V2 ≘ T2 &
  82                                          L = K.ⓓV1 & J = LRef 0 & c = cV
  83                          | ∃∃cV,K,V1,V2. ❪G,K❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ⇧*[1] V2 ≘ T2 &
  84                                          L = K.ⓛV1 & J = LRef 0 & c = cV+𝟘𝟙
  85                          | ∃∃I,K,T,i. ❪G,K❫ ⊢ #i ⬈[Rt,c,h] T & ⇧*[1] T ≘ T2 &
  86                                       L = K.ⓘ[I] & J = LRef (↑i).
  87 #Rt #c #h #G #L #T1 #T2 * -c -G -L -T1 -T2
  88 [ #I #G #L #J #H destruct /3 width=1 by or5_intro0, conj/
  89 | #G #L #s #J #H destruct /3 width=3 by or5_intro1, ex3_intro/
  90 | #c #G #L #V1 #V2 #W2 #HV12 #VW2 #J #H destruct /3 width=8 by or5_intro2, ex5_4_intro/
  91 | #c #G #L #V1 #V2 #W2 #HV12 #VW2 #J #H destruct /3 width=8 by or5_intro3, ex5_4_intro/
  92 | #c #I #G #L #T #U #i #HT #HTU #J #H destruct /3 width=8 by or5_intro4, ex4_4_intro/
  93 | #cV #cT #p #I #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  94 | #cV #cT #G #L #V1 #V2 #T1 #T2 #_ #_ #J #H destruct
  95 | #cU #cT #G #L #U1 #U2 #T1 #T2 #_ #_ #_ #J #H destruct
  96 | #c #G #L #V #T1 #T #T2 #_ #_ #J #H destruct
  97 | #c #G #L #V #T1 #T2 #_ #J #H destruct
  98 | #c #G #L #V1 #V2 #T #_ #J #H destruct
  99 | #cV #cW #cT #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #J #H destruct
 100 | #cV #cW #cT #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #J #H destruct
 101 ]
 102 qed-.
 103
 104 lemma cpg_inv_atom1: ∀Rt,c,h,J,G,L,T2. ❪G,L❫ ⊢ ⓪[J] ⬈[Rt,c,h] T2 →
 105                      ∨∨ T2 = ⓪[J] ∧ c = 𝟘𝟘
 106                       | ∃∃s. J = Sort s & T2 = ⋆(⫯[h]s) & c = 𝟘𝟙
 107                       | ∃∃cV,K,V1,V2. ❪G,K❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ⇧*[1] V2 ≘ T2 &
 108                                       L = K.ⓓV1 & J = LRef 0 & c = cV
 109                       | ∃∃cV,K,V1,V2. ❪G,K❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ⇧*[1] V2 ≘ T2 &
 110                                       L = K.ⓛV1 & J = LRef 0 & c = cV+𝟘𝟙
 111                       | ∃∃I,K,T,i. ❪G,K❫ ⊢ #i ⬈[Rt,c,h] T & ⇧*[1] T ≘ T2 &
 112                                    L = K.ⓘ[I] & J = LRef (↑i).
 113 /2 width=3 by cpg_inv_atom1_aux/ qed-.
 114
 115 lemma cpg_inv_sort1: ∀Rt,c,h,G,L,T2,s. ❪G,L❫ ⊢ ⋆s ⬈[Rt,c,h] T2 →
 116                      ∨∨ T2 = ⋆s ∧ c = 𝟘𝟘 | T2 = ⋆(⫯[h]s) ∧ c = 𝟘𝟙.
 117 #Rt #c #h #G #L #T2 #s #H
 118 elim (cpg_inv_atom1 … H) -H * /3 width=1 by or_introl, conj/
 119 [ #s0 #H destruct /3 width=1 by or_intror, conj/
 120 |2,3: #cV #K #V1 #V2 #_ #_ #_ #H destruct
 121 | #I #K #T #i #_ #_ #_ #H destruct
 122 ]
 123 qed-.
 124
 125 lemma cpg_inv_zero1: ∀Rt,c,h,G,L,T2. ❪G,L❫ ⊢ #0 ⬈[Rt,c,h] T2 →
 126                      ∨∨ T2 = #0 ∧ c = 𝟘𝟘
 127                       | ∃∃cV,K,V1,V2. ❪G,K❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ⇧*[1] V2 ≘ T2 &
 128                                       L = K.ⓓV1 & c = cV
 129                       | ∃∃cV,K,V1,V2. ❪G,K❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ⇧*[1] V2 ≘ T2 &
 130                                       L = K.ⓛV1 & c = cV+𝟘𝟙.
 131 #Rt #c #h #G #L #T2 #H
 132 elim (cpg_inv_atom1 … H) -H * /3 width=1 by or3_intro0, conj/
 133 [ #s #H destruct
 134 |2,3: #cV #K #V1 #V2 #HV12 #HVT2 #H1 #_ #H2 destruct /3 width=8 by or3_intro1, or3_intro2, ex4_4_intro/
 135 | #I #K #T #i #_ #_ #_ #H destruct
 136 ]
 137 qed-.
 138
 139 lemma cpg_inv_lref1: ∀Rt,c,h,G,L,T2,i. ❪G,L❫ ⊢ #↑i ⬈[Rt,c,h] T2 →
 140                      ∨∨ T2 = #(↑i) ∧ c = 𝟘𝟘
 141                       | ∃∃I,K,T. ❪G,K❫ ⊢ #i ⬈[Rt,c,h] T & ⇧*[1] T ≘ T2 & L = K.ⓘ[I].
 142 #Rt #c #h #G #L #T2 #i #H
 143 elim (cpg_inv_atom1 … H) -H * /3 width=1 by or_introl, conj/
 144 [ #s #H destruct
 145 |2,3: #cV #K #V1 #V2 #_ #_ #_ #H destruct
 146 | #I #K #T #j #HT #HT2 #H1 #H2 destruct /3 width=6 by ex3_3_intro, or_intror/
 147 ]
 148 qed-.
 149
 150 lemma cpg_inv_gref1: ∀Rt,c,h,G,L,T2,l. ❪G,L❫ ⊢ §l ⬈[Rt,c,h] T2 → T2 = §l ∧ c = 𝟘𝟘.
 151 #Rt #c #h #G #L #T2 #l #H
 152 elim (cpg_inv_atom1 … H) -H * /2 width=1 by conj/
 153 [ #s #H destruct
 154 |2,3: #cV #K #V1 #V2 #_ #_ #_ #H destruct
 155 | #I #K #T #i #_ #_ #_ #H destruct
 156 ]
 157 qed-.
 158
 159 fact cpg_inv_bind1_aux: ∀Rt,c,h,G,L,U,U2. ❪G,L❫ ⊢ U ⬈[Rt,c,h] U2 →
 160                         ∀p,J,V1,U1. U = ⓑ[p,J]V1.U1 →
 161                         ∨∨ ∃∃cV,cT,V2,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L.ⓑ[J]V1❫ ⊢ U1 ⬈[Rt,cT,h] T2 &
 162                                           U2 = ⓑ[p,J]V2.T2 & c = ((↕*cV)∨cT)
 163                          | ∃∃cT,T. ⇧*[1] T ≘ U1 & ❪G,L❫ ⊢ T ⬈[Rt,cT,h] U2 &
 164                                    p = true & J = Abbr & c = cT+𝟙𝟘.
 165 #Rt #c #h #G #L #U #U2 * -c -G -L -U -U2
 166 [ #I #G #L #q #J #W #U1 #H destruct
 167 | #G #L #s #q #J #W #U1 #H destruct
 168 | #c #G #L #V1 #V2 #W2 #_ #_ #q #J #W #U1 #H destruct
 169 | #c #G #L #V1 #V2 #W2 #_ #_ #q #J #W #U1 #H destruct
 170 | #c #I #G #L #T #U #i #_ #_ #q #J #W #U1 #H destruct
 171 | #cV #cT #p #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #q #J #W #U1 #H destruct /3 width=8 by ex4_4_intro, or_introl/
 172 | #cV #cT #G #L #V1 #V2 #T1 #T2 #_ #_ #q #J #W #U1 #H destruct
 173 | #cU #cT #G #L #U1 #U2 #T1 #T2 #_ #_ #_ #q #J #W #U1 #H destruct
 174 | #c #G #L #V #T1 #T #T2 #HT1 #HT2 #q #J #W #U1 #H destruct /3 width=5 by ex5_2_intro, or_intror/
 175 | #c #G #L #V #T1 #T2 #_ #q #J #W #U1 #H destruct
 176 | #c #G #L #V1 #V2 #T #_ #q #J #W #U1 #H destruct
 177 | #cV #cW #cT #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #q #J #W #U1 #H destruct
 178 | #cV #cW #cT #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #_ #_ #_ #_ #q #J #W #U1 #H destruct
 179 ]
 180 qed-.
 181
 182 lemma cpg_inv_bind1: ∀Rt,c,h,p,I,G,L,V1,T1,U2. ❪G,L❫ ⊢ ⓑ[p,I]V1.T1 ⬈[Rt,c,h] U2 →
 183                      ∨∨ ∃∃cV,cT,V2,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L.ⓑ[I]V1❫ ⊢ T1 ⬈[Rt,cT,h] T2 &
 184                                        U2 = ⓑ[p,I]V2.T2 & c = ((↕*cV)∨cT)
 185                       | ∃∃cT,T. ⇧*[1] T ≘ T1 & ❪G,L❫ ⊢ T ⬈[Rt,cT,h] U2 &
 186                                 p = true & I = Abbr & c = cT+𝟙𝟘.
 187 /2 width=3 by cpg_inv_bind1_aux/ qed-.
 188
 189 lemma cpg_inv_abbr1: ∀Rt,c,h,p,G,L,V1,T1,U2. ❪G,L❫ ⊢ ⓓ[p]V1.T1 ⬈[Rt,c,h] U2 →
 190                      ∨∨ ∃∃cV,cT,V2,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L.ⓓV1❫ ⊢ T1 ⬈[Rt,cT,h] T2 &
 191                                        U2 = ⓓ[p]V2.T2 & c = ((↕*cV)∨cT)
 192                       | ∃∃cT,T. ⇧*[1] T ≘ T1 & ❪G,L❫ ⊢ T ⬈[Rt,cT,h] U2 &
 193                                 p = true & c = cT+𝟙𝟘.
 194 #Rt #c #h #p #G #L #V1 #T1 #U2 #H elim (cpg_inv_bind1 … H) -H *
 195 /3 width=8 by ex4_4_intro, ex4_2_intro, or_introl, or_intror/
 196 qed-.
 197
 198 lemma cpg_inv_abst1: ∀Rt,c,h,p,G,L,V1,T1,U2. ❪G,L❫ ⊢ ⓛ[p]V1.T1 ⬈[Rt,c,h] U2 →
 199                      ∃∃cV,cT,V2,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L.ⓛV1❫ ⊢ T1 ⬈[Rt,cT,h] T2 &
 200                                     U2 = ⓛ[p]V2.T2 & c = ((↕*cV)∨cT).
 201 #Rt #c #h #p #G #L #V1 #T1 #U2 #H elim (cpg_inv_bind1 … H) -H *
 202 [ /3 width=8 by ex4_4_intro/
 203 | #c #T #_ #_ #_ #H destruct
 204 ]
 205 qed-.
 206
 207 fact cpg_inv_appl1_aux: ∀Rt,c,h,G,L,U,U2. ❪G,L❫ ⊢ U ⬈[Rt,c,h] U2 →
 208                         ∀V1,U1. U = ⓐV1.U1 →
 209                         ∨∨ ∃∃cV,cT,V2,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L❫ ⊢ U1 ⬈[Rt,cT,h] T2 &
 210                                           U2 = ⓐV2.T2 & c = ((↕*cV)∨cT)
 211                          | ∃∃cV,cW,cT,p,V2,W1,W2,T1,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L❫ ⊢ W1 ⬈[Rt,cW,h] W2 & ❪G,L.ⓛW1❫ ⊢ T1 ⬈[Rt,cT,h] T2 &
 212                                                         U1 = ⓛ[p]W1.T1 & U2 = ⓓ[p]ⓝW2.V2.T2 & c = ((↕*cV)∨(↕*cW)∨cT)+𝟙𝟘
 213                          | ∃∃cV,cW,cT,p,V,V2,W1,W2,T1,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V & ⇧*[1] V ≘ V2 & ❪G,L❫ ⊢ W1 ⬈[Rt,cW,h] W2 & ❪G,L.ⓓW1❫ ⊢ T1 ⬈[Rt,cT,h] T2 &
 214                                                           U1 = ⓓ[p]W1.T1 & U2 = ⓓ[p]W2.ⓐV2.T2 & c = ((↕*cV)∨(↕*cW)∨cT)+𝟙𝟘.
 215 #Rt #c #h #G #L #U #U2 * -c -G -L -U -U2
 216 [ #I #G #L #W #U1 #H destruct
 217 | #G #L #s #W #U1 #H destruct
 218 | #c #G #L #V1 #V2 #W2 #_ #_ #W #U1 #H destruct
 219 | #c #G #L #V1 #V2 #W2 #_ #_ #W #U1 #H destruct
 220 | #c #I #G #L #T #U #i #_ #_ #W #U1 #H destruct
 221 | #cV #cT #p #I #G #L #V1 #V2 #T1 #T2 #_ #_ #W #U1 #H destruct
 222 | #cV #cT #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #W #U1 #H destruct /3 width=8 by or3_intro0, ex4_4_intro/
 223 | #cV #cT #G #L #V1 #V2 #T1 #T2 #_ #_ #_ #W #U1 #H destruct
 224 | #c #G #L #V #T1 #T #T2 #_ #_ #W #U1 #H destruct
 225 | #c #G #L #V #T1 #T2 #_ #W #U1 #H destruct
 226 | #c #G #L #V1 #V2 #T #_ #W #U1 #H destruct
 227 | #cV #cW #cT #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #W #U1 #H destruct /3 width=15 by or3_intro1, ex6_9_intro/
 228 | #cV #cW #cT #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #W #U1 #H destruct /3 width=17 by or3_intro2, ex7_10_intro/
 229 ]
 230 qed-.
 231
 232 lemma cpg_inv_appl1: ∀Rt,c,h,G,L,V1,U1,U2. ❪G,L❫ ⊢ ⓐV1.U1 ⬈[Rt,c,h] U2 →
 233                      ∨∨ ∃∃cV,cT,V2,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L❫ ⊢ U1 ⬈[Rt,cT,h] T2 &
 234                                        U2 = ⓐV2.T2 & c = ((↕*cV)∨cT)
 235                       | ∃∃cV,cW,cT,p,V2,W1,W2,T1,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L❫ ⊢ W1 ⬈[Rt,cW,h] W2 & ❪G,L.ⓛW1❫ ⊢ T1 ⬈[Rt,cT,h] T2 &
 236                                                      U1 = ⓛ[p]W1.T1 & U2 = ⓓ[p]ⓝW2.V2.T2 & c = ((↕*cV)∨(↕*cW)∨cT)+𝟙𝟘
 237                       | ∃∃cV,cW,cT,p,V,V2,W1,W2,T1,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V & ⇧*[1] V ≘ V2 & ❪G,L❫ ⊢ W1 ⬈[Rt,cW,h] W2 & ❪G,L.ⓓW1❫ ⊢ T1 ⬈[Rt,cT,h] T2 &
 238                                                        U1 = ⓓ[p]W1.T1 & U2 = ⓓ[p]W2.ⓐV2.T2 & c = ((↕*cV)∨(↕*cW)∨cT)+𝟙𝟘.
 239 /2 width=3 by cpg_inv_appl1_aux/ qed-.
 240
 241 fact cpg_inv_cast1_aux: ∀Rt,c,h,G,L,U,U2. ❪G,L❫ ⊢ U ⬈[Rt,c,h] U2 →
 242                         ∀V1,U1. U = ⓝV1.U1 →
 243                         ∨∨ ∃∃cV,cT,V2,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L❫ ⊢ U1 ⬈[Rt,cT,h] T2 &
 244                                           Rt cV cT & U2 = ⓝV2.T2 & c = (cV∨cT)
 245                          | ∃∃cT. ❪G,L❫ ⊢ U1 ⬈[Rt,cT,h] U2 & c = cT+𝟙𝟘
 246                          | ∃∃cV. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] U2 & c = cV+𝟘𝟙.
 247 #Rt #c #h #G #L #U #U2 * -c -G -L -U -U2
 248 [ #I #G #L #W #U1 #H destruct
 249 | #G #L #s #W #U1 #H destruct
 250 | #c #G #L #V1 #V2 #W2 #_ #_ #W #U1 #H destruct
 251 | #c #G #L #V1 #V2 #W2 #_ #_ #W #U1 #H destruct
 252 | #c #I #G #L #T #U #i #_ #_ #W #U1 #H destruct
 253 | #cV #cT #p #I #G #L #V1 #V2 #T1 #T2 #_ #_ #W #U1 #H destruct
 254 | #cV #cT #G #L #V1 #V2 #T1 #T2 #_ #_ #W #U1 #H destruct
 255 | #cV #cT #G #L #V1 #V2 #T1 #T2 #HRt #HV12 #HT12 #W #U1 #H destruct /3 width=9 by or3_intro0, ex5_4_intro/
 256 | #c #G #L #V #T1 #T #T2 #_ #_ #W #U1 #H destruct
 257 | #c #G #L #V #T1 #T2 #HT12 #W #U1 #H destruct /3 width=3 by or3_intro1, ex2_intro/
 258 | #c #G #L #V1 #V2 #T #HV12 #W #U1 #H destruct /3 width=3 by or3_intro2, ex2_intro/
 259 | #cV #cW #cT #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #W #U1 #H destruct
 260 | #cV #cW #cT #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #W #U1 #H destruct
 261 ]
 262 qed-.
 263
 264 lemma cpg_inv_cast1: ∀Rt,c,h,G,L,V1,U1,U2. ❪G,L❫ ⊢ ⓝV1.U1 ⬈[Rt,c,h] U2 →
 265                      ∨∨ ∃∃cV,cT,V2,T2. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ❪G,L❫ ⊢ U1 ⬈[Rt,cT,h] T2 &
 266                                        Rt cV cT & U2 = ⓝV2.T2 & c = (cV∨cT)
 267                       | ∃∃cT. ❪G,L❫ ⊢ U1 ⬈[Rt,cT,h] U2 & c = cT+𝟙𝟘
 268                       | ∃∃cV. ❪G,L❫ ⊢ V1 ⬈[Rt,cV,h] U2 & c = cV+𝟘𝟙.
 269 /2 width=3 by cpg_inv_cast1_aux/ qed-.
 270
 271 (* Advanced inversion lemmas ************************************************)
 272
 273 lemma cpg_inv_zero1_pair: ∀Rt,c,h,I,G,K,V1,T2. ❪G,K.ⓑ[I]V1❫ ⊢ #0 ⬈[Rt,c,h] T2 →
 274                           ∨∨ T2 = #0 ∧ c = 𝟘𝟘
 275                            | ∃∃cV,V2. ❪G,K❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ⇧*[1] V2 ≘ T2 &
 276                                       I = Abbr & c = cV
 277                            | ∃∃cV,V2. ❪G,K❫ ⊢ V1 ⬈[Rt,cV,h] V2 & ⇧*[1] V2 ≘ T2 &
 278                                       I = Abst & c = cV+𝟘𝟙.
 279 #Rt #c #h #I #G #K #V1 #T2 #H elim (cpg_inv_zero1 … H) -H /2 width=1 by or3_intro0/
 280 * #z #Y #X1 #X2 #HX12 #HXT2 #H1 #H2 destruct /3 width=5 by or3_intro1, or3_intro2, ex4_2_intro/
 281 qed-.
 282
 283 lemma cpg_inv_lref1_bind: ∀Rt,c,h,I,G,K,T2,i. ❪G,K.ⓘ[I]❫ ⊢ #↑i ⬈[Rt,c,h] T2 →
 284                           ∨∨ T2 = #(↑i) ∧ c = 𝟘𝟘
 285                            | ∃∃T. ❪G,K❫ ⊢ #i ⬈[Rt,c,h] T & ⇧*[1] T ≘ T2.
 286 #Rt #c #h #I #G #L #T2 #i #H elim (cpg_inv_lref1 … H) -H /2 width=1 by or_introl/
 287 * #Z #Y #T #HT #HT2 #H destruct /3 width=3 by ex2_intro, or_intror/
 288 qed-.
 289
 290 (* Basic forward lemmas *****************************************************)
 291
 292 lemma cpg_fwd_bind1_minus: ∀Rt,c,h,I,G,L,V1,T1,T. ❪G,L❫ ⊢ -ⓑ[I]V1.T1 ⬈[Rt,c,h] T → ∀p.
 293                            ∃∃V2,T2. ❪G,L❫ ⊢ ⓑ[p,I]V1.T1 ⬈[Rt,c,h] ⓑ[p,I]V2.T2 &
 294                                     T = -ⓑ[I]V2.T2.
 295 #Rt #c #h #I #G #L #V1 #T1 #T #H #p elim (cpg_inv_bind1 … H) -H *
 296 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct /3 width=4 by cpg_bind, ex2_2_intro/
 297 | #c #T2 #_ #_ #H destruct
 298 ]
 299 qed-.