matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpg_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "ground/xoa/ex_5_5.ma".
  16 include "static_2/relocation/drops_drops.ma".
  17 include "static_2/s_computation/fqup_weight.ma".
  18 include "static_2/s_computation/fqup_drops.ma".
  19 include "basic_2/rt_transition/cpg.ma".
  20
  21 (* BOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS *****************)
  22
  23 (* Advanced properties ******************************************************)
  24
  25 lemma cpg_delta_drops: ∀Rt,c,h,G,K,V,V2,i,L,T2. ⇩[i] L ≘ K.ⓓV → ❪G,K❫ ⊢ V ⬈[Rt,c,h] V2 →
  26                        ⇧[↑i] V2 ≘ T2 →  ❪G,L❫ ⊢ #i ⬈[Rt,c,h] T2.
  27 #Rt #c #h #G #K #V #V2 #i elim i -i
  28 [ #L #T2 #HLK lapply (drops_fwd_isid … HLK ?) // #H destruct /3 width=3 by cpg_delta/
  29 | #i #IH #L0 #T0 #H0 #HV2 #HVT2
  30   elim (drops_inv_succ … H0) -H0 #I #L #HLK #H destruct
  31   elim (lifts_split_trans … HVT2 (𝐔❨↑i❩) (𝐔❨1❩) ?) -HVT2 /3 width=3 by cpg_lref/
  32 ]
  33 qed.
  34
  35 lemma cpg_ell_drops: ∀Rt,c,h,G,K,V,V2,i,L,T2. ⇩[i] L ≘ K.ⓛV → ❪G,K❫ ⊢ V ⬈[Rt,c,h] V2 →
  36                      ⇧[↑i] V2 ≘ T2 →  ❪G,L❫ ⊢ #i ⬈[Rt,c+𝟘𝟙,h] T2.
  37 #Rt #c #h #G #K #V #V2 #i elim i -i
  38 [ #L #T2 #HLK lapply (drops_fwd_isid … HLK ?) // #H destruct /3 width=3 by cpg_ell/
  39 | #i #IH #L0 #T0 #H0 #HV2 #HVT2
  40   elim (drops_inv_succ … H0) -H0 #I #L #HLK #H destruct
  41   elim (lifts_split_trans … HVT2 (𝐔❨↑i❩) (𝐔❨1❩) ?) -HVT2 /3 width=3 by cpg_lref/
  42 ]
  43 qed.
  44
  45 (* Advanced inversion lemmas ************************************************)
  46
  47 lemma cpg_inv_lref1_drops: ∀Rt,c,h,G,i,L,T2. ❪G,L❫ ⊢ #i ⬈[Rt,c,h] T2 →
  48                            ∨∨ T2 = #i ∧ c = 𝟘𝟘
  49                             | ∃∃cV,K,V,V2. ⇩[i] L ≘ K.ⓓV & ❪G,K❫ ⊢ V ⬈[Rt,cV,h] V2 &
  50                                            ⇧[↑i] V2 ≘ T2 & c = cV
  51                             | ∃∃cV,K,V,V2. ⇩[i] L ≘ K.ⓛV & ❪G,K❫ ⊢ V ⬈[Rt,cV,h] V2 &
  52                                            ⇧[↑i] V2 ≘ T2 & c = cV + 𝟘𝟙.
  53 #Rt #c #h #G #i elim i -i
  54 [ #L #T2 #H elim (cpg_inv_zero1 … H) -H * /3 width=1 by or3_intro0, conj/
  55   /4 width=8 by drops_refl, ex4_4_intro, or3_intro2, or3_intro1/
  56 | #i #IH #L #T2 #H elim (cpg_inv_lref1 … H) -H * /3 width=1 by or3_intro0, conj/
  57   #I #K #V2 #H #HVT2 #H0 destruct elim (IH … H) -IH -H
  58   [ * #H1 #H2 destruct
  59     lapply (lifts_inv_lref1_uni … HVT2) -HVT2 #H destruct
  60     /3 width=1 by or3_intro0, conj/
  61   ] *
  62   #cV #L #W #W2 #HKL #HW2 #HWV2 #H destruct
  63   lapply (lifts_trans … HWV2 … HVT2 (𝐔❨↑↑i❩) ?) -V2 [1,3: // ] #H (**) (* explicit rtmap *)
  64   /4 width=8 by drops_drop, ex4_4_intro, or3_intro2, or3_intro1/
  65 ]
  66 qed-.
  67
  68 lemma cpg_inv_atom1_drops: ∀Rt,c,h,I,G,L,T2. ❪G,L❫ ⊢ ⓪[I] ⬈[Rt,c,h] T2 →
  69                            ∨∨ T2 = ⓪[I] ∧ c = 𝟘𝟘
  70                             | ∃∃s. T2 = ⋆(⫯[h]s) & I = Sort s & c = 𝟘𝟙
  71                             | ∃∃cV,i,K,V,V2. ⇩[i] L ≘ K.ⓓV & ❪G,K❫ ⊢ V ⬈[Rt,cV,h] V2 &
  72                                              ⇧[↑i] V2 ≘ T2 & I = LRef i & c = cV
  73                             | ∃∃cV,i,K,V,V2. ⇩[i] L ≘ K.ⓛV & ❪G,K❫ ⊢ V ⬈[Rt,cV,h] V2 &
  74                                              ⇧[↑i] V2 ≘ T2 & I = LRef i & c = cV + 𝟘𝟙.
  75 #Rt #c #h * #n #G #L #T2 #H
  76 [ elim (cpg_inv_sort1 … H) -H *
  77   /3 width=3 by or4_intro0, or4_intro1, ex3_intro, conj/
  78 | elim (cpg_inv_lref1_drops … H) -H *
  79   /3 width=10 by or4_intro0, or4_intro2, or4_intro3, ex5_5_intro, conj/
  80 | elim (cpg_inv_gref1 … H) -H
  81   /3 width=1 by or4_intro0, conj/
  82 ]
  83 qed-.
  84
  85 (* Properties with generic slicing for local environments *******************)
  86
  87 (* Note: it should use drops_split_trans_pair2 *)
  88 lemma cpg_lifts_sn: ∀Rt. reflexive … Rt →
  89                     ∀c,h,G. d_liftable2_sn … lifts (cpg Rt h c G).
  90 #Rt #HRt #c #h #G #K #T generalize in match c; -c
  91 @(fqup_wf_ind_eq (Ⓣ) … G K T) -G -K -T #G0 #K0 #T0 #IH #G #K * *
  92 [ #s #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct -IH
  93   lapply (lifts_inv_sort1 … H1) -H1 #H destruct
  94   elim (cpg_inv_sort1 … H2) -H2 * #H1 #H2 destruct
  95   /2 width=3 by cpg_atom, cpg_ess, lifts_sort, ex2_intro/
  96 | #i1 #HG #HK #HT #c #T2 #H2 #b #f #L #HLK #X1 #H1 destruct
  97   elim (cpg_inv_lref1_drops … H2) -H2 *
  98   [ #H1 #H2 destruct /3 width=3 by cpg_refl, ex2_intro/ ]
  99   #cV #K0 #V #V2 #HK0 #HV2 #HVT2 #H destruct
 100   elim (lifts_inv_lref1 … H1) -H1 #i2 #Hf #H destruct
 101   lapply (drops_trans … HLK … HK0 ??) -HLK [3,6: |*: // ] #H
 102   elim (drops_split_trans … H) -H [1,6: |*: /2 width=6 by after_uni_dx/ ] #Y #HL0 #HY
 103   lapply (drops_tls_at … Hf … HY) -HY #HY
 104   elim (drops_inv_skip2 … HY) -HY #Z #L0 #HLK0 #HZ #H destruct
 105   elim (liftsb_inv_pair_sn … HZ) -HZ #W #HVW #H destruct
 106   elim (IH … HV2 … HLK0 … HVW) -IH /2 width=2 by fqup_lref/ -K -K0 -V #W2 #HVW2 #HW2
 107   elim (lifts_total W2 (𝐔❨↑i2❩)) #U2 #HWU2
 108   lapply (lifts_trans … HVW2 … HWU2 ??) -HVW2 [3,6: |*: // ] #HVU2
 109   lapply (lifts_conf … HVT2 … HVU2 f ?) -V2 [1,3: /2 width=3 by after_uni_succ_sn/ ]
 110   /4 width=8 by cpg_ell_drops, cpg_delta_drops, drops_inv_gen, ex2_intro/
 111 | #l #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct -IH
 112   lapply (lifts_inv_gref1 … H1) -H1 #H destruct
 113   elim (cpg_inv_gref1 … H2) -H2 #H1 #H2 destruct
 114   /2 width=3 by cpg_atom, lifts_gref, ex2_intro/
 115 | #p #I #V1 #T1 #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct
 116   elim (lifts_inv_bind1 … H1) -H1 #W1 #U1 #HVW1 #HTU1 #H destruct
 117   elim (cpg_inv_bind1 … H2) -H2 *
 118   [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 119     elim (IH … HV12 … HLK … HVW1) -HV12 //
 120     elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 121     /3 width=5 by cpg_bind, lifts_bind, ex2_intro/
 122   | #cT #T2 #HT21 #HTX2 #H1 #H2 #H3 destruct
 123     elim (lifts_trans4_one … HT21 … HTU1) -HTU1 #U2 #HTU2 #HU21
 124     elim (IH … HTX2 … HLK … HTU2) [| /3 width=1 by fqup_zeta/ ] -K -V1 -T1 -T2
 125     /3 width=5 by cpg_zeta, ex2_intro/
 126   ]
 127 | * #V1 #T1 #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct
 128   elim (lifts_inv_flat1 … H1) -H1 #W1 #U1 #HVW1 #HTU1 #H destruct
 129   [ elim (cpg_inv_appl1 … H2) -H2 *
 130     [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 131       elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 //
 132       elim (IH … HT12 … HLK … HTU1) -IH -HT12 -HLK -HTU1 //
 133       /3 width=5 by cpg_appl, lifts_flat, ex2_intro/
 134     | #cV #cY #cT #a #V2 #Y1 #Y2 #T0 #T2 #HV12 #HY12 #HT12 #H1 #H2 #H3 destruct
 135       elim (lifts_inv_bind1 … HTU1) -HTU1 #Z1 #U0 #HYZ1 #HTU1 #H destruct
 136       elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 //
 137       elim (IH … HY12 … HLK … HYZ1) -HY12 //
 138       elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 139       /4 width=7 by cpg_beta, lifts_bind, lifts_flat, ex2_intro/
 140     | #cV #cY #cT #a #V2 #V20 #Y1 #Y2 #T0 #T2 #HV12 #HV20 #HY12 #HT12 #H1 #H2 #H3 destruct
 141       elim (lifts_inv_bind1 … HTU1) -HTU1 #Z1 #U0 #HYZ1 #HTU1 #H destruct
 142       elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 // #W2 #HVW2 #HW12
 143       elim (IH … HY12 … HLK … HYZ1) -HY12 //
 144       elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 145       elim (lifts_total W2 (𝐔❨1❩)) #W20 #HW20
 146       lapply (lifts_trans … HVW2 … HW20 ??) -HVW2 [3: |*: // ] #H
 147       lapply (lifts_conf … HV20 … H (⫯f) ?) -V2 /2 width=3 by after_uni_one_sn/
 148       /4 width=9 by cpg_theta, lifts_bind, lifts_flat, ex2_intro/
 149     ]
 150   | elim (cpg_inv_cast1 … H2) -H2 *
 151     [ #cV #cT #V2 #T2 #HV12 #HT12 #HcVT #H1 #H2 destruct
 152       elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 //
 153       elim (IH … HT12 … HLK … HTU1) -IH -HT12 -HLK -HTU1 //
 154       /3 width=5 by cpg_cast, lifts_flat, ex2_intro/
 155     | #cT #HT12 #H destruct
 156       elim (IH … HT12 … HLK … HTU1) -IH -HT12 -HLK -HTU1 //
 157       /3 width=3 by cpg_eps, ex2_intro/
 158     | #cV #HV12 #H destruct
 159       elim (IH … HV12 … HLK … HVW1) -IH -HV12 -HLK -HVW1 //
 160       /3 width=3 by cpg_ee, ex2_intro/
 161     ]
 162   ]
 163 ]
 164 qed-.
 165
 166 lemma cpg_lifts_bi: ∀Rt. reflexive … Rt →
 167                     ∀c,h,G. d_liftable2_bi … lifts (cpg Rt h c G).
 168 /3 width=12 by cpg_lifts_sn, d_liftable2_sn_bi, lifts_mono/ qed-.
 169
 170 (* Inversion lemmas with generic slicing for local environments *************)
 171
 172 lemma cpg_inv_lifts_sn: ∀Rt. reflexive … Rt →
 173                         ∀c,h,G. d_deliftable2_sn … lifts (cpg Rt h c G).
 174 #Rt #HRt #c #h #G #L #U generalize in match c; -c
 175 @(fqup_wf_ind_eq (Ⓣ) … G L U) -G -L -U #G0 #L0 #U0 #IH #G #L * *
 176 [ #s #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct -IH
 177   lapply (lifts_inv_sort2 … H1) -H1 #H destruct
 178   elim (cpg_inv_sort1 … H2) -H2 * #H1 #H2 destruct
 179   /2 width=3 by cpg_atom, cpg_ess, lifts_sort, ex2_intro/
 180 | #i2 #HG #HL #HU #c #U2 #H2 #b #f #K #HLK #X1 #H1 destruct
 181   elim (cpg_inv_lref1_drops … H2) -H2 *
 182   [ #H1 #H2 destruct /3 width=3 by cpg_refl, ex2_intro/ ]
 183   #cW #L0 #W #W2 #HL0 #HW2 #HWU2 #H destruct
 184   elim (lifts_inv_lref2 … H1) -H1 #i1 #Hf #H destruct
 185   lapply (drops_split_div … HLK (𝐔❨i1❩) ???) -HLK [4,8: * |*: // ] #Y0 #HK0 #HLY0
 186   lapply (drops_conf … HL0 … HLY0 ??) -HLY0 [3,6: |*: /2 width=6 by after_uni_dx/ ] #HLY0
 187   lapply (drops_tls_at … Hf … HLY0) -HLY0 #HLY0
 188   elim (drops_inv_skip1 … HLY0) -HLY0 #Z #K0 #HLK0 #HZ #H destruct
 189   elim (liftsb_inv_pair_dx … HZ) -HZ #V #HVW #H destruct
 190   elim (IH … HW2 … HLK0 … HVW) -IH /2 width=2 by fqup_lref/ -L -L0 -W #V2 #HVW2 #HV2
 191   lapply (lifts_trans … HVW2 … HWU2 ??) -W2 [3,6: |*: // ] #HVU2
 192   elim (lifts_split_trans … HVU2 ? f) -HVU2 [1,4: |*: /2 width=4 by after_uni_succ_sn/ ]
 193   /4 width=8 by cpg_ell_drops, cpg_delta_drops, drops_inv_F, ex2_intro/
 194 | #l #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct -IH
 195   lapply (lifts_inv_gref2 … H1) -H1 #H destruct
 196   elim (cpg_inv_gref1 … H2) -H2 #H1 #H2 destruct
 197   /2 width=3 by cpg_atom, lifts_gref, ex2_intro/
 198 | #p #I #W1 #U1 #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct
 199   elim (lifts_inv_bind2 … H1) -H1 #V1 #T1 #HVW1 #HTU1 #H destruct
 200   elim (cpg_inv_bind1 … H2) -H2 *
 201   [ #cW #cU #W2 #U2 #HW12 #HU12 #H1 #H2 destruct
 202     elim (IH … HW12 … HLK … HVW1) -HW12 //
 203     elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 204     /3 width=5 by cpg_bind, lifts_bind, ex2_intro/
 205   | #cU #U2 #HU21 #HUX2 #H1 #H2 #H3 destruct
 206     elim (lifts_div4_one … HTU1 … HU21) -HTU1 #T2 #HT21 #HTU2
 207     elim (IH … HUX2 … HLK … HTU2) [| /3 width=1 by fqup_zeta/ ] -L -W1 -U1 -U2
 208     /3 width=5 by cpg_zeta, ex2_intro/
 209   ]
 210 | * #W1 #U1 #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct
 211   elim (lifts_inv_flat2 … H1) -H1 #V1 #T1 #HVW1 #HTU1 #H destruct
 212   [ elim (cpg_inv_appl1 … H2) -H2 *
 213     [ #cW #cU #W2 #U2 #HW12 #HU12 #H1 #H2 destruct
 214       elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 //
 215       elim (IH … HU12 … HLK … HTU1) -IH -HU12 -HLK -HTU1 //
 216       /3 width=5 by cpg_appl, lifts_flat, ex2_intro/
 217     | #cW #cZ #cU #a #W2 #Z1 #Z2 #U0 #U2 #HW12 #HZ12 #HU12 #H1 #H2 #H3 destruct
 218       elim (lifts_inv_bind2 … HTU1) -HTU1 #Y1 #T0 #HYZ1 #HTU1 #H destruct
 219       elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 //
 220       elim (IH … HZ12 … HLK … HYZ1) -HZ12 //
 221       elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 222       /4 width=7 by cpg_beta, lifts_bind, lifts_flat, ex2_intro/
 223     | #cW #cZ #cU #a #W2 #W20 #Z1 #Z2 #U0 #U2 #HW12 #HW20 #HZ12 #HU12 #H1 #H2 #H3 destruct
 224       elim (lifts_inv_bind2 … HTU1) -HTU1 #Y1 #T0 #HYZ1 #HTU1 #H destruct
 225       elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 // #V2 #HVW2 #HV12
 226       elim (IH … HZ12 … HLK … HYZ1) -HZ12 //
 227       elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 228       lapply (lifts_trans … HVW2 … HW20 ??) -W2 [3: |*: // ] #H
 229       elim (lifts_split_trans … H ? (⫯f)) -H [ |*: /2 width=3 by after_uni_one_sn/ ]
 230       /4 width=9 by cpg_theta, lifts_bind, lifts_flat, ex2_intro/
 231     ]
 232   | elim (cpg_inv_cast1 … H2) -H2 *
 233     [ #cW #cU #W2 #U2 #HW12 #HU12 #HcWU #H1 #H2 destruct
 234       elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 //
 235       elim (IH … HU12 … HLK … HTU1) -IH -HU12 -HLK -HTU1 //
 236       /3 width=5 by cpg_cast, lifts_flat, ex2_intro/
 237     | #cU #HU12 #H destruct
 238       elim (IH … HU12 … HLK … HTU1) -IH -HU12 -HLK -HTU1 //
 239       /3 width=3 by cpg_eps, ex2_intro/
 240     | #cW #HW12 #H destruct
 241       elim (IH … HW12 … HLK … HVW1) -IH -HW12 -HLK -HVW1 //
 242       /3 width=3 by cpg_ee, ex2_intro/
 243     ]
 244   ]
 245 ]
 246 qed-.
 247
 248 lemma cpg_inv_lifts_bi: ∀Rt. reflexive … Rt →
 249                         ∀c,h,G. d_deliftable2_bi … lifts (cpg Rt h c G).
 250 /3 width=12 by cpg_inv_lifts_sn, d_deliftable2_sn_bi, lifts_inj/ qed-.