matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpg_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "static_2/relocation/drops_drops.ma".
  16 include "static_2/s_computation/fqup_weight.ma".
  17 include "static_2/s_computation/fqup_drops.ma".
  18 include "basic_2/rt_transition/cpg.ma".
  19
  20 (* BOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS *****************)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 lemma cpg_delta_drops: ∀Rt,c,h,G,K,V,V2,i,L,T2. ⬇*[i] L ≘ K.ⓓV → ⦃G, K⦄ ⊢ V ⬈[Rt, c, h] V2 →
  25                        ⬆*[↑i] V2 ≘ T2 →  ⦃G, L⦄ ⊢ #i ⬈[Rt, c, h] T2.
  26 #Rt #c #h #G #K #V #V2 #i elim i -i
  27 [ #L #T2 #HLK lapply (drops_fwd_isid … HLK ?) // #H destruct /3 width=3 by cpg_delta/
  28 | #i #IH #L0 #T0 #H0 #HV2 #HVT2
  29   elim (drops_inv_succ … H0) -H0 #I #L #HLK #H destruct
  30   elim (lifts_split_trans … HVT2 (𝐔❴↑i❵) (𝐔❴1❵) ?) -HVT2 /3 width=3 by cpg_lref/
  31 ]
  32 qed.
  33
  34 lemma cpg_ell_drops: ∀Rt,c,h,G,K,V,V2,i,L,T2. ⬇*[i] L ≘ K.ⓛV → ⦃G, K⦄ ⊢ V ⬈[Rt,c, h] V2 →
  35                      ⬆*[↑i] V2 ≘ T2 →  ⦃G, L⦄ ⊢ #i ⬈[Rt, c+𝟘𝟙, h] T2.
  36 #Rt #c #h #G #K #V #V2 #i elim i -i
  37 [ #L #T2 #HLK lapply (drops_fwd_isid … HLK ?) // #H destruct /3 width=3 by cpg_ell/
  38 | #i #IH #L0 #T0 #H0 #HV2 #HVT2
  39   elim (drops_inv_succ … H0) -H0 #I #L #HLK #H destruct
  40   elim (lifts_split_trans … HVT2 (𝐔❴↑i❵) (𝐔❴1❵) ?) -HVT2 /3 width=3 by cpg_lref/
  41 ]
  42 qed.
  43
  44 (* Advanced inversion lemmas ************************************************)
  45
  46 lemma cpg_inv_lref1_drops: ∀Rt,c,h,G,i,L,T2. ⦃G, L⦄ ⊢ #i ⬈[Rt,c, h] T2 →
  47                            ∨∨ T2 = #i ∧ c = 𝟘𝟘
  48                             | ∃∃cV,K,V,V2. ⬇*[i] L ≘ K.ⓓV & ⦃G, K⦄ ⊢ V ⬈[Rt, cV, h] V2 &
  49                                            ⬆*[↑i] V2 ≘ T2 & c = cV
  50                             | ∃∃cV,K,V,V2. ⬇*[i] L ≘ K.ⓛV & ⦃G, K⦄ ⊢ V ⬈[Rt, cV, h] V2 &
  51                                            ⬆*[↑i] V2 ≘ T2 & c = cV + 𝟘𝟙.
  52 #Rt #c #h #G #i elim i -i
  53 [ #L #T2 #H elim (cpg_inv_zero1 … H) -H * /3 width=1 by or3_intro0, conj/
  54   /4 width=8 by drops_refl, ex4_4_intro, or3_intro2, or3_intro1/
  55 | #i #IH #L #T2 #H elim (cpg_inv_lref1 … H) -H * /3 width=1 by or3_intro0, conj/
  56   #I #K #V2 #H #HVT2 #H0 destruct elim (IH … H) -IH -H
  57   [ * #H1 #H2 destruct lapply (lifts_inv_lref1_uni … HVT2) -HVT2 #H destruct /3 width=1 by or3_intro0, conj/ ] *
  58   #cV #L #W #W2 #HKL #HW2 #HWV2 #H destruct
  59   lapply (lifts_trans … HWV2 … HVT2 ??) -V2
  60   /4 width=8 by drops_drop, ex4_4_intro, or3_intro2, or3_intro1/
  61 ]
  62 qed-.
  63
  64 lemma cpg_inv_atom1_drops: ∀Rt,c,h,I,G,L,T2. ⦃G, L⦄ ⊢ ⓪{I} ⬈[Rt, c, h] T2 →
  65                            ∨∨ T2 = ⓪{I} ∧ c = 𝟘𝟘
  66                             | ∃∃s. T2 = ⋆(next h s) & I = Sort s & c = 𝟘𝟙
  67                             | ∃∃cV,i,K,V,V2. ⬇*[i] L ≘ K.ⓓV & ⦃G, K⦄ ⊢ V ⬈[Rt, cV, h] V2 &
  68                                              ⬆*[↑i] V2 ≘ T2 & I = LRef i & c = cV
  69                             | ∃∃cV,i,K,V,V2. ⬇*[i] L ≘ K.ⓛV & ⦃G, K⦄ ⊢ V ⬈[Rt, cV, h] V2 &
  70                                              ⬆*[↑i] V2 ≘ T2 & I = LRef i & c = cV + 𝟘𝟙.
  71 #Rt #c #h * #n #G #L #T2 #H
  72 [ elim (cpg_inv_sort1 … H) -H *
  73   /3 width=3 by or4_intro0, or4_intro1, ex3_intro, conj/
  74 | elim (cpg_inv_lref1_drops … H) -H *
  75   /3 width=10 by or4_intro0, or4_intro2, or4_intro3, ex5_5_intro, conj/
  76 | elim (cpg_inv_gref1 … H) -H
  77   /3 width=1 by or4_intro0, conj/
  78 ]
  79 qed-.
  80
  81 (* Properties with generic slicing for local environments *******************)
  82
  83 (* Note: it should use drops_split_trans_pair2 *)
  84 lemma cpg_lifts_sn: ∀Rt. reflexive … Rt →
  85                     ∀c,h,G. d_liftable2_sn … lifts (cpg Rt h c G).
  86 #Rt #HRt #c #h #G #K #T generalize in match c; -c
  87 @(fqup_wf_ind_eq (Ⓣ) … G K T) -G -K -T #G0 #K0 #T0 #IH #G #K * *
  88 [ #s #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct -IH
  89   lapply (lifts_inv_sort1 … H1) -H1 #H destruct
  90   elim (cpg_inv_sort1 … H2) -H2 * #H1 #H2 destruct
  91   /2 width=3 by cpg_atom, cpg_ess, lifts_sort, ex2_intro/
  92 | #i1 #HG #HK #HT #c #T2 #H2 #b #f #L #HLK #X1 #H1 destruct
  93   elim (cpg_inv_lref1_drops … H2) -H2 *
  94   [ #H1 #H2 destruct /3 width=3 by cpg_refl, ex2_intro/ ]
  95   #cV #K0 #V #V2 #HK0 #HV2 #HVT2 #H destruct
  96   elim (lifts_inv_lref1 … H1) -H1 #i2 #Hf #H destruct
  97   lapply (drops_trans … HLK … HK0 ??) -HLK [3,6: |*: // ] #H
  98   elim (drops_split_trans … H) -H [1,6: |*: /2 width=6 by after_uni_dx/ ] #Y #HL0 #HY
  99   lapply (drops_tls_at … Hf … HY) -HY #HY
 100   elim (drops_inv_skip2 … HY) -HY #Z #L0 #HLK0 #HZ #H destruct
 101   elim (liftsb_inv_pair_sn … HZ) -HZ #W #HVW #H destruct
 102   elim (IH … HV2 … HLK0 … HVW) -IH /2 width=2 by fqup_lref/ -K -K0 -V #W2 #HVW2 #HW2
 103   elim (lifts_total W2 (𝐔❴↑i2❵)) #U2 #HWU2
 104   lapply (lifts_trans … HVW2 … HWU2 ??) -HVW2 [3,6: |*: // ] #HVU2
 105   lapply (lifts_conf … HVT2 … HVU2 f ?) -V2 [1,3: /2 width=3 by after_uni_succ_sn/ ]
 106   /4 width=8 by cpg_ell_drops, cpg_delta_drops, drops_inv_gen, ex2_intro/
 107 | #l #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct -IH
 108   lapply (lifts_inv_gref1 … H1) -H1 #H destruct
 109   elim (cpg_inv_gref1 … H2) -H2 #H1 #H2 destruct
 110   /2 width=3 by cpg_atom, lifts_gref, ex2_intro/
 111 | #p #I #V1 #T1 #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct
 112   elim (lifts_inv_bind1 … H1) -H1 #W1 #U1 #HVW1 #HTU1 #H destruct
 113   elim (cpg_inv_bind1 … H2) -H2 *
 114   [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 115     elim (IH … HV12 … HLK … HVW1) -HV12 //
 116     elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 117     /3 width=5 by cpg_bind, lifts_bind, ex2_intro/
 118   | #cT #T2 #HT12 #HXT2 #H1 #H2 #H3 destruct
 119     elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ] #U2 #HTU2 #HU12
 120     lapply (lifts_trans … HXT2 … HTU2 ??) -T2 [3: |*: // ] #HXU2
 121     elim (lifts_split_trans … HXU2 f (𝐔❴↑O❵)) [2: /2 width=1 by after_uni_one_dx/ ]
 122     /3 width=5 by cpg_zeta, ex2_intro/
 123   ]
 124 | * #V1 #T1 #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct
 125   elim (lifts_inv_flat1 … H1) -H1 #W1 #U1 #HVW1 #HTU1 #H destruct
 126   [ elim (cpg_inv_appl1 … H2) -H2 *
 127     [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 128       elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 //
 129       elim (IH … HT12 … HLK … HTU1) -IH -HT12 -HLK -HTU1 //
 130       /3 width=5 by cpg_appl, lifts_flat, ex2_intro/
 131     | #cV #cY #cT #a #V2 #Y1 #Y2 #T0 #T2 #HV12 #HY12 #HT12 #H1 #H2 #H3 destruct
 132       elim (lifts_inv_bind1 … HTU1) -HTU1 #Z1 #U0 #HYZ1 #HTU1 #H destruct
 133       elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 //
 134       elim (IH … HY12 … HLK … HYZ1) -HY12 //
 135       elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 136       /4 width=7 by cpg_beta, lifts_bind, lifts_flat, ex2_intro/
 137     | #cV #cY #cT #a #V2 #V20 #Y1 #Y2 #T0 #T2 #HV12 #HV20 #HY12 #HT12 #H1 #H2 #H3 destruct
 138       elim (lifts_inv_bind1 … HTU1) -HTU1 #Z1 #U0 #HYZ1 #HTU1 #H destruct
 139       elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 // #W2 #HVW2 #HW12
 140       elim (IH … HY12 … HLK … HYZ1) -HY12 //
 141       elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 142       elim (lifts_total W2 (𝐔❴1❵)) #W20 #HW20
 143       lapply (lifts_trans … HVW2 … HW20 ??) -HVW2 [3: |*: // ] #H
 144       lapply (lifts_conf … HV20 … H (⫯f) ?) -V2 /2 width=3 by after_uni_one_sn/
 145       /4 width=9 by cpg_theta, lifts_bind, lifts_flat, ex2_intro/
 146     ]
 147   | elim (cpg_inv_cast1 … H2) -H2 *
 148     [ #cV #cT #V2 #T2 #HV12 #HT12 #HcVT #H1 #H2 destruct
 149       elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 //
 150       elim (IH … HT12 … HLK … HTU1) -IH -HT12 -HLK -HTU1 //
 151       /3 width=5 by cpg_cast, lifts_flat, ex2_intro/
 152     | #cT #HT12 #H destruct
 153       elim (IH … HT12 … HLK … HTU1) -IH -HT12 -HLK -HTU1 //
 154       /3 width=3 by cpg_eps, ex2_intro/
 155     | #cV #HV12 #H destruct
 156       elim (IH … HV12 … HLK … HVW1) -IH -HV12 -HLK -HVW1 //
 157       /3 width=3 by cpg_ee, ex2_intro/
 158     ]
 159   ]
 160 ]
 161 qed-.
 162
 163 lemma cpg_lifts_bi: ∀Rt. reflexive … Rt →
 164                     ∀c,h,G. d_liftable2_bi … lifts (cpg Rt h c G).
 165 /3 width=12 by cpg_lifts_sn, d_liftable2_sn_bi, lifts_mono/ qed-.
 166
 167 (* Inversion lemmas with generic slicing for local environments *************)
 168
 169 lemma cpg_inv_lifts_sn: ∀Rt. reflexive … Rt →
 170                         ∀c,h,G. d_deliftable2_sn … lifts (cpg Rt h c G).
 171 #Rt #HRt #c #h #G #L #U generalize in match c; -c
 172 @(fqup_wf_ind_eq (Ⓣ) … G L U) -G -L -U #G0 #L0 #U0 #IH #G #L * *
 173 [ #s #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct -IH
 174   lapply (lifts_inv_sort2 … H1) -H1 #H destruct
 175   elim (cpg_inv_sort1 … H2) -H2 * #H1 #H2 destruct
 176   /2 width=3 by cpg_atom, cpg_ess, lifts_sort, ex2_intro/
 177 | #i2 #HG #HL #HU #c #U2 #H2 #b #f #K #HLK #X1 #H1 destruct
 178   elim (cpg_inv_lref1_drops … H2) -H2 *
 179   [ #H1 #H2 destruct /3 width=3 by cpg_refl, ex2_intro/ ]
 180   #cW #L0 #W #W2 #HL0 #HW2 #HWU2 #H destruct
 181   elim (lifts_inv_lref2 … H1) -H1 #i1 #Hf #H destruct
 182   lapply (drops_split_div … HLK (𝐔❴i1❵) ???) -HLK [4,8: * |*: // ] #Y0 #HK0 #HLY0
 183   lapply (drops_conf … HL0 … HLY0 ??) -HLY0 [3,6: |*: /2 width=6 by after_uni_dx/ ] #HLY0
 184   lapply (drops_tls_at … Hf … HLY0) -HLY0 #HLY0
 185   elim (drops_inv_skip1 … HLY0) -HLY0 #Z #K0 #HLK0 #HZ #H destruct
 186   elim (liftsb_inv_pair_dx … HZ) -HZ #V #HVW #H destruct
 187   elim (IH … HW2 … HLK0 … HVW) -IH /2 width=2 by fqup_lref/ -L -L0 -W #V2 #HVW2 #HV2
 188   lapply (lifts_trans … HVW2 … HWU2 ??) -W2 [3,6: |*: // ] #HVU2
 189   elim (lifts_split_trans … HVU2 ? f) -HVU2 [1,4: |*: /2 width=4 by after_uni_succ_sn/ ]
 190   /4 width=8 by cpg_ell_drops, cpg_delta_drops, drops_inv_F, ex2_intro/
 191 | #l #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct -IH
 192   lapply (lifts_inv_gref2 … H1) -H1 #H destruct
 193   elim (cpg_inv_gref1 … H2) -H2 #H1 #H2 destruct
 194   /2 width=3 by cpg_atom, lifts_gref, ex2_intro/
 195 | #p #I #W1 #U1 #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct
 196   elim (lifts_inv_bind2 … H1) -H1 #V1 #T1 #HVW1 #HTU1 #H destruct
 197   elim (cpg_inv_bind1 … H2) -H2 *
 198   [ #cW #cU #W2 #U2 #HW12 #HU12 #H1 #H2 destruct
 199     elim (IH … HW12 … HLK … HVW1) -HW12 //
 200     elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 201     /3 width=5 by cpg_bind, lifts_bind, ex2_intro/
 202   | #cU #U2 #HU12 #HXU2 #H1 #H2 #H3 destruct
 203     elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ] #T2 #HTU2 #HT12
 204     elim (lifts_div4_one … HTU2 … HXU2) -U2 /3 width=5 by cpg_zeta, ex2_intro/
 205   ]
 206 | * #W1 #U1 #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct
 207   elim (lifts_inv_flat2 … H1) -H1 #V1 #T1 #HVW1 #HTU1 #H destruct
 208   [ elim (cpg_inv_appl1 … H2) -H2 *
 209     [ #cW #cU #W2 #U2 #HW12 #HU12 #H1 #H2 destruct
 210       elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 //
 211       elim (IH … HU12 … HLK … HTU1) -IH -HU12 -HLK -HTU1 //
 212       /3 width=5 by cpg_appl, lifts_flat, ex2_intro/
 213     | #cW #cZ #cU #a #W2 #Z1 #Z2 #U0 #U2 #HW12 #HZ12 #HU12 #H1 #H2 #H3 destruct
 214       elim (lifts_inv_bind2 … HTU1) -HTU1 #Y1 #T0 #HYZ1 #HTU1 #H destruct
 215       elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 //
 216       elim (IH … HZ12 … HLK … HYZ1) -HZ12 //
 217       elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 218       /4 width=7 by cpg_beta, lifts_bind, lifts_flat, ex2_intro/
 219     | #cW #cZ #cU #a #W2 #W20 #Z1 #Z2 #U0 #U2 #HW12 #HW20 #HZ12 #HU12 #H1 #H2 #H3 destruct
 220       elim (lifts_inv_bind2 … HTU1) -HTU1 #Y1 #T0 #HYZ1 #HTU1 #H destruct
 221       elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 // #V2 #HVW2 #HV12
 222       elim (IH … HZ12 … HLK … HYZ1) -HZ12 //
 223       elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip, ext2_pair/ ]
 224       lapply (lifts_trans … HVW2 … HW20 ??) -W2 [3: |*: // ] #H
 225       elim (lifts_split_trans … H ? (⫯f)) -H [ |*: /2 width=3 by after_uni_one_sn/ ]
 226       /4 width=9 by cpg_theta, lifts_bind, lifts_flat, ex2_intro/
 227     ]
 228   | elim (cpg_inv_cast1 … H2) -H2 *
 229     [ #cW #cU #W2 #U2 #HW12 #HU12 #HcWU #H1 #H2 destruct
 230       elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 //
 231       elim (IH … HU12 … HLK … HTU1) -IH -HU12 -HLK -HTU1 //
 232       /3 width=5 by cpg_cast, lifts_flat, ex2_intro/
 233     | #cU #HU12 #H destruct
 234       elim (IH … HU12 … HLK … HTU1) -IH -HU12 -HLK -HTU1 //
 235       /3 width=3 by cpg_eps, ex2_intro/
 236     | #cW #HW12 #H destruct
 237       elim (IH … HW12 … HLK … HVW1) -IH -HW12 -HLK -HVW1 //
 238       /3 width=3 by cpg_ee, ex2_intro/
 239     ]
 240   ]
 241 ]
 242 qed-.
 243
 244 lemma cpg_inv_lifts_bi: ∀Rt. reflexive … Rt →
 245                         ∀c,h,G. d_deliftable2_bi … lifts (cpg Rt h c G).
 246 /3 width=12 by cpg_inv_lifts_sn, d_deliftable2_sn_bi, lifts_inj/ qed-.