matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpg_drops.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/relocation/drops_drops.ma".
  16 include "basic_2/s_computation/fqup_weight.ma".
  17 include "basic_2/s_computation/fqup_drops.ma".
  18 include "basic_2/rt_transition/cpg.ma".
  19
  20 (* COUNTED CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS ***************)
  21
  22 (* Advanced properties ******************************************************)
  23
  24 lemma cpg_delta_drops: ∀c,h,G,K,V,V2,i,L,T2. ⬇*[i] L ≡ K.ⓓV → ⦃G, K⦄ ⊢ V ⬈[c, h] V2 →
  25                        ⬆*[⫯i] V2 ≡ T2 →  ⦃G, L⦄ ⊢ #i ⬈[c, h] T2.
  26 #c #h #G #K #V #V2 #i elim i -i
  27 [ #L #T2 #HLK lapply (drops_fwd_isid … HLK ?) // #H destruct /3 width=3 by cpg_delta/
  28 | #i #IH #L0 #T0 #H0 #HV2 #HVT2
  29   elim (drops_inv_succ … H0) -H0 #I #L #V0 #HLK #H destruct
  30   elim (lifts_split_trans … HVT2 (𝐔❴⫯i❵) (𝐔❴1❵) ?) -HVT2 /3 width=3 by cpg_lref/
  31 ]
  32 qed.
  33
  34 lemma cpg_ell_drops: ∀c,h,G,K,V,V2,i,L,T2. ⬇*[i] L ≡ K.ⓛV → ⦃G, K⦄ ⊢ V ⬈[c, h] V2 →
  35                      ⬆*[⫯i] V2 ≡ T2 →  ⦃G, L⦄ ⊢ #i ⬈[(↓c)+𝟘𝟙, h] T2.
  36 #c #h #G #K #V #V2 #i elim i -i
  37 [ #L #T2 #HLK lapply (drops_fwd_isid … HLK ?) // #H destruct /3 width=3 by cpg_ell/
  38 | #i #IH #L0 #T0 #H0 #HV2 #HVT2
  39   elim (drops_inv_succ … H0) -H0 #I #L #V0 #HLK #H destruct
  40   elim (lifts_split_trans … HVT2 (𝐔❴⫯i❵) (𝐔❴1❵) ?) -HVT2 /3 width=3 by cpg_lref/
  41 ]
  42 qed.
  43
  44 (* Advanced inversion lemmas ************************************************)
  45
  46 lemma cpg_inv_lref1_drops: ∀c,h,G,i,L,T2. ⦃G, L⦄ ⊢ #i ⬈[c, h] T2 →
  47                            ∨∨ T2 = #i ∧ c = 𝟘𝟘
  48                             | ∃∃cV,K,V,V2. ⬇*[i] L ≡ K.ⓓV & ⦃G, K⦄ ⊢ V ⬈[cV, h] V2 &
  49                                            ⬆*[⫯i] V2 ≡ T2 & c = cV
  50                             | ∃∃cV,K,V,V2. ⬇*[i] L ≡ K.ⓛV & ⦃G, K⦄ ⊢ V ⬈[cV, h] V2 &
  51                                            ⬆*[⫯i] V2 ≡ T2 & c = (↓cV) + 𝟘𝟙.
  52 #c #h #G #i elim i -i
  53 [ #L #T2 #H elim (cpg_inv_zero1 … H) -H * /3 width=1 by or3_intro0, conj/
  54   /4 width=8 by drops_refl, ex4_4_intro, or3_intro2, or3_intro1/
  55 | #i #IH #L #T2 #H elim (cpg_inv_lref1 … H) -H * /3 width=1 by or3_intro0, conj/
  56   #I #K #V #V2 #H #HVT2 #H0 destruct elim (IH … H) -IH -H
  57   [ * #H1 #H2 destruct lapply (lifts_inv_lref1_uni … HVT2) -HVT2 #H destruct /3 width=1 by or3_intro0, conj/ ] *
  58   #cV #L #W #W2 #HKL #HW2 #HWV2 #H destruct
  59   lapply (lifts_trans … HWV2 … HVT2 ??) -V2
  60   /4 width=8 by drops_drop, ex4_4_intro, or3_intro2, or3_intro1/
  61 ]
  62 qed-.
  63
  64 lemma cpg_inv_atom1_drops: ∀c,h,I,G,L,T2. ⦃G, L⦄ ⊢ ⓪{I} ⬈[c, h] T2 →
  65                            ∨∨ T2 = ⓪{I} ∧ c = 𝟘𝟘
  66                             | ∃∃s. T2 = ⋆(next h s) & I = Sort s & c = 𝟘𝟙
  67                             | ∃∃cV,i,K,V,V2. ⬇*[i] L ≡ K.ⓓV & ⦃G, K⦄ ⊢ V ⬈[cV, h] V2 &
  68                                              ⬆*[⫯i] V2 ≡ T2 & I = LRef i & c = cV
  69                             | ∃∃cV,i,K,V,V2. ⬇*[i] L ≡ K.ⓛV & ⦃G, K⦄ ⊢ V ⬈[cV, h] V2 &
  70                                              ⬆*[⫯i] V2 ≡ T2 & I = LRef i & c = (↓cV) + 𝟘𝟙.
  71 #c #h * #n #G #L #T2 #H
  72 [ elim (cpg_inv_sort1 … H) -H *
  73   /3 width=3 by or4_intro0, or4_intro1, ex3_intro, conj/
  74 | elim (cpg_inv_lref1_drops … H) -H *
  75   /3 width=10 by or4_intro0, or4_intro2, or4_intro3, ex5_5_intro, conj/
  76 | elim (cpg_inv_gref1 … H) -H
  77   /3 width=1 by or4_intro0, conj/
  78 ]
  79 qed-.
  80
  81 (* Properties with generic slicing for local environments *******************)
  82
  83 lemma cpg_lifts: ∀c,h,G. d_liftable2 (cpg h c G).
  84 #c #h #G #K #T generalize in match c; -c
  85 @(fqup_wf_ind_eq … G K T) -G -K -T #G0 #K0 #T0 #IH #G #K * *
  86 [ #s #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct -IH
  87   lapply (lifts_inv_sort1 … H1) -H1 #H destruct
  88   elim (cpg_inv_sort1 … H2) -H2 * #H1 #H2 destruct
  89   /2 width=3 by cpg_atom, cpg_ess, lifts_sort, ex2_intro/
  90 | #i1 #HG #HK #HT #c #T2 #H2 #b #f #L #HLK #X1 #H1 destruct
  91   elim (cpg_inv_lref1_drops … H2) -H2 *
  92   [ #H1 #H2 destruct /2 width=3 by ex2_intro/ ]
  93   #cV #K0 #V #V2 #HK0 #HV2 #HVT2 #H destruct
  94   elim (lifts_inv_lref1 … H1) -H1 #i2 #Hf #H destruct
  95   lapply (drops_trans … HLK … HK0 ??) -HLK [3,6: |*: // ] #H
  96   elim (drops_split_trans … H) -H [1,6: |*: /2 width=6 by after_uni_dx/ ] #Y #HL0 #HY
  97   lapply (drops_inv_tls_at … Hf … HY) -HY #HY
  98   elim (drops_inv_skip2 … HY) -HY #L0 #W #HLK0 #HVW #H destruct
  99   elim (IH … HV2 … HLK0 … HVW) -IH /2 width=2 by fqup_lref/ -K -K0 -V #W2 #HVW2 #HW2
 100   elim (lifts_total W2 (𝐔❴⫯i2❵)) #U2 #HWU2
 101   lapply (lifts_trans … HVW2 … HWU2 ??) -HVW2 [3,6: |*: // ] #HVU2
 102   lapply (lifts_conf … HVT2 … HVU2 f ?) -V2 [1,3: /2 width=3 by after_uni_succ_sn/ ]
 103   /4 width=8 by cpg_ell_drops, cpg_delta_drops, drops_inv_gen, ex2_intro/
 104 | #l #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct -IH
 105   lapply (lifts_inv_gref1 … H1) -H1 #H destruct
 106   elim (cpg_inv_gref1 … H2) -H2 #H1 #H2 destruct
 107   /2 width=3 by cpg_atom, lifts_gref, ex2_intro/
 108 | #p #I #V1 #T1 #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct
 109   elim (lifts_inv_bind1 … H1) -H1 #W1 #U1 #HVW1 #HTU1 #H destruct
 110   elim (cpg_inv_bind1 … H2) -H2 *
 111   [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 112     elim (IH … HV12 … HLK … HVW1) -HV12 //
 113     elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip/ ]
 114     /3 width=5 by cpg_bind, lifts_bind, ex2_intro/
 115   | #cT #T2 #HT12 #HXT2 #H1 #H2 #H3 destruct
 116     elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip/ ] #U2 #HTU2 #HU12
 117     lapply (lifts_trans … HXT2 … HTU2 ??) -T2 [3: |*: // ] #HXU2
 118     elim (lifts_split_trans … HXU2 f (𝐔❴⫯O❵)) [2: /2 width=1 by after_uni_one_dx/ ]
 119     /3 width=5 by cpg_zeta, ex2_intro/
 120   ]
 121 | #I #V1 #T1 #HG #HK #HT #c #X2 #H2 #b #f #L #HLK #X1 #H1 destruct
 122   elim (lifts_inv_flat1 … H1) -H1 #W1 #U1 #HVW1 #HTU1 #H destruct
 123   elim (cpg_inv_flat1 … H2) -H2 *
 124   [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 125     elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 //
 126     elim (IH … HT12 … HLK … HTU1) -IH -HT12 -HLK -HTU1 //
 127     /3 width=5 by cpg_flat, lifts_flat, ex2_intro/
 128   | #cT #HT12 #H1 #H2 destruct
 129     elim (IH … HT12 … HLK … HTU1) -IH -HT12 -HLK -HTU1 //
 130     /3 width=3 by cpg_eps, ex2_intro/
 131   | #cV #HV12 #H1 #H2 destruct
 132     elim (IH … HV12 … HLK … HVW1) -IH -HV12 -HLK -HVW1 //
 133     /3 width=3 by cpg_ee, ex2_intro/
 134   | #cV #cY #cT #a #V2 #Y1 #Y2 #T0 #T2 #HV12 #HY12 #HT12 #H1 #H2 #H3 #H4 destruct
 135     elim (lifts_inv_bind1 … HTU1) -HTU1 #Z1 #U0 #HYZ1 #HTU1 #H destruct
 136     elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 //
 137     elim (IH … HY12 … HLK … HYZ1) -HY12 //
 138     elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip/ ]
 139     /4 width=7 by cpg_beta, lifts_bind, lifts_flat, ex2_intro/
 140   | #cV #cY #cT #a #V2 #V20 #Y1 #Y2 #T0 #T2 #HV12 #HV20 #HY12 #HT12 #H1 #H2 #H3 #H4 destruct
 141     elim (lifts_inv_bind1 … HTU1) -HTU1 #Z1 #U0 #HYZ1 #HTU1 #H destruct
 142     elim (IH … HV12 … HLK … HVW1) -HV12 -HVW1 // #W2 #HVW2 #HW12
 143     elim (IH … HY12 … HLK … HYZ1) -HY12 //
 144     elim (IH … HT12 … HTU1) -IH -HT12 -HTU1 [ |*: /3 width=3 by drops_skip/ ]
 145     elim (lifts_total W2 (𝐔❴1❵)) #W20 #HW20
 146     lapply (lifts_trans … HVW2 … HW20 ??) -HVW2 [3: |*: // ] #H
 147     lapply (lifts_conf … HV20 … H (↑f) ?) -V2 /2 width=3 by after_uni_one_sn/
 148     /4 width=9 by cpg_theta, lifts_bind, lifts_flat, ex2_intro/
 149   ]
 150 ]
 151 qed-.
 152
 153 (* Inversion lemmas with generic slicing for local environments *************)
 154
 155 lemma cpg_inv_lifts1: ∀c,h,G. d_deliftable2_sn (cpg h c G).
 156 #c #h #G #L #U generalize in match c; -c
 157 @(fqup_wf_ind_eq … G L U) -G -L -U #G0 #L0 #U0 #IH #G #L * *
 158 [ #s #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct -IH
 159   lapply (lifts_inv_sort2 … H1) -H1 #H destruct
 160   elim (cpg_inv_sort1 … H2) -H2 * #H1 #H2 destruct
 161   /2 width=3 by cpg_atom, cpg_ess, lifts_sort, ex2_intro/
 162 | #i2 #HG #HL #HU #c #U2 #H2 #b #f #K #HLK #X1 #H1 destruct
 163   elim (cpg_inv_lref1_drops … H2) -H2 *
 164   [ #H1 #H2 destruct /2 width=3 by ex2_intro/ ]
 165   #cW #L0 #W #W2 #HL0 #HW2 #HWU2 #H destruct
 166   elim (lifts_inv_lref2 … H1) -H1 #i1 #Hf #H destruct
 167   lapply (drops_split_div … HLK (𝐔❴i1❵) ???) -HLK [4,8: * |*: // ] #Y0 #HK0 #HLY0
 168   lapply (drops_conf … HL0 … HLY0 ??) -HLY0 [3,6: |*: /2 width=6 by after_uni_dx/ ] #HLY0
 169   lapply (drops_inv_tls_at … Hf … HLY0) -HLY0 #HLY0
 170   elim (drops_inv_skip1 … HLY0) -HLY0 #K0 #V #HLK0 #HVW #H destruct
 171   elim (IH … HW2 … HLK0 … HVW) -IH /2 width=2 by fqup_lref/ -L -L0 -W #V2 #HVW2 #HV2
 172   lapply (lifts_trans … HVW2 … HWU2 ??) -W2 [3,6: |*: // ] #HVU2
 173   elim (lifts_split_trans … HVU2 ? f) -HVU2 [1,4: |*: /2 width=4 by after_uni_succ_sn/ ]
 174   /4 width=8 by cpg_ell_drops, cpg_delta_drops, drops_inv_F, ex2_intro/
 175 | #l #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct -IH
 176   lapply (lifts_inv_gref2 … H1) -H1 #H destruct
 177   elim (cpg_inv_gref1 … H2) -H2 #H1 #H2 destruct
 178   /2 width=3 by cpg_atom, lifts_gref, ex2_intro/
 179 | #p #I #W1 #U1 #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct
 180   elim (lifts_inv_bind2 … H1) -H1 #V1 #T1 #HVW1 #HTU1 #H destruct
 181   elim (cpg_inv_bind1 … H2) -H2 *
 182   [ #cW #cU #W2 #U2 #HW12 #HU12 #H1 #H2 destruct
 183     elim (IH … HW12 … HLK … HVW1) -HW12 //
 184     elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip/ ]
 185     /3 width=5 by cpg_bind, lifts_bind, ex2_intro/
 186   | #cU #U2 #HU12 #HXU2 #H1 #H2 #H3 destruct
 187     elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip/ ] #T2 #HTU2 #HT12
 188     elim (lifts_div4_one … HTU2 … HXU2) -U2 /3 width=5 by cpg_zeta, ex2_intro/
 189   ]
 190 | #I #W1 #U1 #HG #HL #HU #c #X2 #H2 #b #f #K #HLK #X1 #H1 destruct
 191   elim (lifts_inv_flat2 … H1) -H1 #V1 #T1 #HVW1 #HTU1 #H destruct
 192   elim (cpg_inv_flat1 … H2) -H2 *
 193   [ #cW #cU #W2 #U2 #HW12 #HU12 #H1 #H2 destruct
 194     elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 //
 195     elim (IH … HU12 … HLK … HTU1) -IH -HU12 -HLK -HTU1 //
 196     /3 width=5 by cpg_flat, lifts_flat, ex2_intro/
 197   | #cU #HU12 #H1 #H2 destruct
 198     elim (IH … HU12 … HLK … HTU1) -IH -HU12 -HLK -HTU1 //
 199     /3 width=3 by cpg_eps, ex2_intro/
 200   | #cW #HW12 #H1 #H2 destruct
 201     elim (IH … HW12 … HLK … HVW1) -IH -HW12 -HLK -HVW1 //
 202     /3 width=3 by cpg_ee, ex2_intro/
 203   | #cW #cZ #cU #a #W2 #Z1 #Z2 #U0 #U2 #HW12 #HZ12 #HU12 #H1 #H2 #H3 #H4 destruct
 204     elim (lifts_inv_bind2 … HTU1) -HTU1 #Y1 #T0 #HYZ1 #HTU1 #H destruct
 205     elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 //
 206     elim (IH … HZ12 … HLK … HYZ1) -HZ12 //
 207     elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip/ ]
 208     /4 width=7 by cpg_beta, lifts_bind, lifts_flat, ex2_intro/
 209   | #cW #cZ #cU #a #W2 #W20 #Z1 #Z2 #U0 #U2 #HW12 #HW20 #HZ12 #HU12 #H1 #H2 #H3 #H4 destruct
 210     elim (lifts_inv_bind2 … HTU1) -HTU1 #Y1 #T0 #HYZ1 #HTU1 #H destruct
 211     elim (IH … HW12 … HLK … HVW1) -HW12 -HVW1 // #V2 #HVW2 #HV12
 212     elim (IH … HZ12 … HLK … HYZ1) -HZ12 //
 213     elim (IH … HU12 … HTU1) -IH -HU12 -HTU1 [ |*: /3 width=3 by drops_skip/ ]
 214     lapply (lifts_trans … HVW2 … HW20 ??) -W2 [3: |*: // ] #H
 215     elim (lifts_split_trans … H ? (↑f)) -H [ |*: /2 width=3 by after_uni_one_sn/ ]
 216     /4 width=9 by cpg_theta, lifts_bind, lifts_flat, ex2_intro/
 217   ]
 218 ]
 219 qed-.