matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpm.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/pred_6.ma".
  16 include "basic_2/notation/relations/pred_5.ma".
  17 include "basic_2/rt_transition/cpg.ma".
  18
  19 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS ***************)
  20
  21 (* Basic_2A1: includes: cpr *)
  22 definition cpm (h) (G) (L) (n): relation2 term term ≝
  23                                 λT1,T2. ∃∃c. 𝐑𝐓⦃n, c⦄ & ⦃G, L⦄ ⊢ T1 ⬈[eq_t, c, h] T2.
  24
  25 interpretation
  26    "t-bound context-sensitive parallel rt-transition (term)"
  27    'PRed n h G L T1 T2 = (cpm h G L n T1 T2).
  28
  29 interpretation
  30    "context-sensitive parallel r-transition (term)"
  31    'PRed h G L T1 T2 = (cpm h G L O T1 T2).
  32
  33 (* Basic properties *********************************************************)
  34
  35 lemma cpm_ess: ∀h,G,L,s. ⦃G, L⦄ ⊢ ⋆s ➡[1, h] ⋆(next h s).
  36 /2 width=3 by cpg_ess, ex2_intro/ qed.
  37
  38 lemma cpm_delta: ∀n,h,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 →
  39                  ⬆*[1] V2 ≘ W2 → ⦃G, K.ⓓV1⦄ ⊢ #0 ➡[n, h] W2.
  40 #n #h #G #K #V1 #V2 #W2 *
  41 /3 width=5 by cpg_delta, ex2_intro/
  42 qed.
  43
  44 lemma cpm_ell: ∀n,h,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 →
  45                ⬆*[1] V2 ≘ W2 → ⦃G, K.ⓛV1⦄ ⊢ #0 ➡[↑n, h] W2.
  46 #n #h #G #K #V1 #V2 #W2 *
  47 /3 width=5 by cpg_ell, ex2_intro, isrt_succ/
  48 qed.
  49
  50 lemma cpm_lref: ∀n,h,I,G,K,T,U,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T →
  51                 ⬆*[1] T ≘ U → ⦃G, K.ⓘ{I}⦄ ⊢ #↑i ➡[n, h] U.
  52 #n #h #I #G #K #T #U #i *
  53 /3 width=5 by cpg_lref, ex2_intro/
  54 qed.
  55
  56 (* Basic_2A1: includes: cpr_bind *)
  57 lemma cpm_bind: ∀n,h,p,I,G,L,V1,V2,T1,T2.
  58                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 →
  59                 ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] ⓑ{p,I}V2.T2.
  60 #n #h #p #I #G #L #V1 #V2 #T1 #T2 * #cV #HcV #HV12 *
  61 /5 width=5 by cpg_bind, isrt_max_O1, isr_shift, ex2_intro/
  62 qed.
  63
  64 lemma cpm_appl: ∀n,h,G,L,V1,V2,T1,T2.
  65                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
  66                 ⦃G, L⦄ ⊢ ⓐV1.T1 ➡[n, h] ⓐV2.T2.
  67 #n #h #G #L #V1 #V2 #T1 #T2 * #cV #HcV #HV12 *
  68 /5 width=5 by isrt_max_O1, isr_shift, cpg_appl, ex2_intro/
  69 qed.
  70
  71 lemma cpm_cast: ∀n,h,G,L,U1,U2,T1,T2.
  72                 ⦃G, L⦄ ⊢ U1 ➡[n, h] U2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
  73                 ⦃G, L⦄ ⊢ ⓝU1.T1 ➡[n, h] ⓝU2.T2.
  74 #n #h #G #L #U1 #U2 #T1 #T2 * #cU #HcU #HU12 *
  75 /4 width=6 by cpg_cast, isrt_max_idem1, isrt_mono, ex2_intro/
  76 qed.
  77
  78 (* Basic_2A1: includes: cpr_zeta *)
  79 lemma cpm_zeta: ∀n,h,G,L,V,T1,T,T2. ⦃G, L.ⓓV⦄ ⊢ T1 ➡[n, h] T →
  80                 ⬆*[1] T2 ≘ T → ⦃G, L⦄ ⊢ +ⓓV.T1 ➡[n, h] T2.
  81 #n #h #G #L #V #T1 #T #T2 *
  82 /3 width=5 by cpg_zeta, isrt_plus_O2, ex2_intro/
  83 qed.
  84
  85 (* Basic_2A1: includes: cpr_eps *)
  86 lemma cpm_eps: ∀n,h,G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → ⦃G, L⦄ ⊢ ⓝV.T1 ➡[n, h] T2.
  87 #n #h #G #L #V #T1 #T2 *
  88 /3 width=3 by cpg_eps, isrt_plus_O2, ex2_intro/
  89 qed.
  90
  91 lemma cpm_ee: ∀n,h,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 → ⦃G, L⦄ ⊢ ⓝV1.T ➡[↑n, h] V2.
  92 #n #h #G #L #V1 #V2 #T *
  93 /3 width=3 by cpg_ee, isrt_succ, ex2_intro/
  94 qed.
  95
  96 (* Basic_2A1: includes: cpr_beta *)
  97 lemma cpm_beta: ∀n,h,p,G,L,V1,V2,W1,W2,T1,T2.
  98                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 →
  99                 ⦃G, L⦄ ⊢ ⓐV1.ⓛ{p}W1.T1 ➡[n, h] ⓓ{p}ⓝW2.V2.T2.
 100 #n #h #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 * #riV #rhV #HV12 * #riW #rhW #HW12 *
 101 /6 width=7 by cpg_beta, isrt_plus_O2, isrt_max, isr_shift, ex2_intro/
 102 qed.
 103
 104 (* Basic_2A1: includes: cpr_theta *)
 105 lemma cpm_theta: ∀n,h,p,G,L,V1,V,V2,W1,W2,T1,T2.
 106                  ⦃G, L⦄ ⊢ V1 ➡[h] V → ⬆*[1] V ≘ V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
 107                  ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 →
 108                  ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}W1.T1 ➡[n, h] ⓓ{p}W2.ⓐV2.T2.
 109 #n #h #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 * #riV #rhV #HV1 #HV2 * #riW #rhW #HW12 *
 110 /6 width=9 by cpg_theta, isrt_plus_O2, isrt_max, isr_shift, ex2_intro/
 111 qed.
 112
 113 (* Basic properties with r-transition ***************************************)
 114
 115 (* Note: this is needed by cpms_ind_sn and cpms_ind_dx *)
 116 (* Basic_1: includes by definition: pr0_refl *)
 117 (* Basic_2A1: includes: cpr_atom *)
 118 lemma cpr_refl: ∀h,G,L. reflexive … (cpm h G L 0).
 119 /3 width=3 by cpg_refl, ex2_intro/ qed.
 120
 121 (* Basic inversion lemmas ***************************************************)
 122
 123 lemma cpm_inv_atom1: ∀n,h,J,G,L,T2. ⦃G, L⦄ ⊢ ⓪{J} ➡[n, h] T2 →
 124                      ∨∨ T2 = ⓪{J} ∧ n = 0
 125                       | ∃∃s. T2 = ⋆(next h s) & J = Sort s & n = 1
 126                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 & ⬆*[1] V2 ≘ T2 &
 127                                    L = K.ⓓV1 & J = LRef 0
 128                       | ∃∃m,K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[m, h] V2 & ⬆*[1] V2 ≘ T2 &
 129                                      L = K.ⓛV1 & J = LRef 0 & n = ↑m
 130                       | ∃∃I,K,T,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T & ⬆*[1] T ≘ T2 &
 131                                    L = K.ⓘ{I} & J = LRef (↑i).
 132 #n #h #J #G #L #T2 * #c #Hc #H elim (cpg_inv_atom1 … H) -H *
 133 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or5_intro0, conj/
 134 | #s #H1 #H2 #H3 destruct /4 width=3 by isrt_inv_01, or5_intro1, ex3_intro/
 135 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 #H3 destruct
 136   /4 width=6 by or5_intro2, ex4_3_intro, ex2_intro/
 137 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 #H3 destruct
 138   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 139   /4 width=9 by or5_intro3, ex5_4_intro, ex2_intro/
 140 | #I #K #V2 #i #HV2 #HVT2 #H1 #H2 destruct
 141   /4 width=8 by or5_intro4, ex4_4_intro, ex2_intro/
 142 ]
 143 qed-.
 144
 145 lemma cpm_inv_sort1: ∀n,h,G,L,T2,s. ⦃G, L⦄ ⊢ ⋆s ➡[n,h] T2 →
 146                      ∨∨ T2 = ⋆s ∧ n = 0
 147                       | T2 = ⋆(next h s) ∧ n = 1.
 148 #n #h #G #L #T2 #s * #c #Hc #H elim (cpg_inv_sort1 … H) -H *
 149 #H1 #H2 destruct
 150 /4 width=1 by isrt_inv_01, isrt_inv_00, or_introl, or_intror, conj/
 151 qed-.
 152
 153 lemma cpm_inv_zero1: ∀n,h,G,L,T2. ⦃G, L⦄ ⊢ #0 ➡[n, h] T2 →
 154                      ∨∨ T2 = #0 ∧ n = 0
 155                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 & ⬆*[1] V2 ≘ T2 &
 156                                    L = K.ⓓV1
 157                       | ∃∃m,K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[m, h] V2 & ⬆*[1] V2 ≘ T2 &
 158                                      L = K.ⓛV1 & n = ↑m.
 159 #n #h #G #L #T2 * #c #Hc #H elim (cpg_inv_zero1 … H) -H *
 160 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or3_intro0, conj/
 161 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 destruct
 162   /4 width=8 by or3_intro1, ex3_3_intro, ex2_intro/
 163 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 destruct
 164   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 165   /4 width=8 by or3_intro2, ex4_4_intro, ex2_intro/
 166 ]
 167 qed-.
 168
 169 lemma cpm_inv_lref1: ∀n,h,G,L,T2,i. ⦃G, L⦄ ⊢ #↑i ➡[n, h] T2 →
 170                      ∨∨ T2 = #(↑i) ∧ n = 0
 171                       | ∃∃I,K,T. ⦃G, K⦄ ⊢ #i ➡[n, h] T & ⬆*[1] T ≘ T2 & L = K.ⓘ{I}.
 172 #n #h #G #L #T2 #i * #c #Hc #H elim (cpg_inv_lref1 … H) -H *
 173 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or_introl, conj/
 174 | #I #K #V2 #HV2 #HVT2 #H destruct
 175  /4 width=6 by ex3_3_intro, ex2_intro, or_intror/
 176 ]
 177 qed-.
 178
 179 lemma cpm_inv_gref1: ∀n,h,G,L,T2,l. ⦃G, L⦄ ⊢ §l ➡[n, h] T2 → T2 = §l ∧ n = 0.
 180 #n #h #G #L #T2 #l * #c #Hc #H elim (cpg_inv_gref1 … H) -H
 181 #H1 #H2 destruct /3 width=1 by isrt_inv_00, conj/
 182 qed-.
 183
 184 (* Basic_2A1: includes: cpr_inv_bind1 *)
 185 lemma cpm_inv_bind1: ∀n,h,p,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] U2 →
 186                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 &
 187                                  U2 = ⓑ{p,I}V2.T2
 188                       | ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡[n, h] T & ⬆*[1] U2 ≘ T &
 189                              p = true & I = Abbr.
 190 #n #h #p #I #G #L #V1 #T1 #U2 * #c #Hc #H elim (cpg_inv_bind1 … H) -H *
 191 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 192   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 193   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 194   /4 width=5 by ex3_2_intro, ex2_intro, or_introl/
 195 | #cT #T2 #HT12 #HUT2 #H1 #H2 #H3 destruct
 196   /5 width=3 by isrt_inv_plus_O_dx, ex4_intro, ex2_intro, or_intror/
 197 ]
 198 qed-.
 199
 200 (* Basic_1: includes: pr0_gen_abbr pr2_gen_abbr *)
 201 (* Basic_2A1: includes: cpr_inv_abbr1 *)
 202 lemma cpm_inv_abbr1: ∀n,h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{p}V1.T1 ➡[n, h] U2 →
 203                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ➡[n, h] T2 &
 204                                  U2 = ⓓ{p}V2.T2
 205                       | ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡[n, h] T & ⬆*[1] U2 ≘ T & p = true.
 206 #n #h #p #G #L #V1 #T1 #U2 * #c #Hc #H elim (cpg_inv_abbr1 … H) -H *
 207 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 208   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 209   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 210   /4 width=5 by ex3_2_intro, ex2_intro, or_introl/
 211 | #cT #T2 #HT12 #HUT2 #H1 #H2 destruct
 212   /5 width=3 by isrt_inv_plus_O_dx, ex3_intro, ex2_intro, or_intror/
 213 ]
 214 qed-.
 215
 216 (* Basic_1: includes: pr0_gen_abst pr2_gen_abst *)
 217 (* Basic_2A1: includes: cpr_inv_abst1 *)
 218 lemma cpm_inv_abst1: ∀n,h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{p}V1.T1 ➡[n, h] U2 →
 219                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡[n, h] T2 &
 220                               U2 = ⓛ{p}V2.T2.
 221 #n #h #p #G #L #V1 #T1 #U2 * #c #Hc #H elim (cpg_inv_abst1 … H) -H
 222 #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 223 elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 224 elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 225 /3 width=5 by ex3_2_intro, ex2_intro/
 226 qed-.
 227
 228 (* Basic_1: includes: pr0_gen_appl pr2_gen_appl *)
 229 (* Basic_2A1: includes: cpr_inv_appl1 *)
 230 lemma cpm_inv_appl1: ∀n,h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐ V1.U1 ➡[n, h] U2 →
 231                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ U1 ➡[n, h] T2 &
 232                                  U2 = ⓐV2.T2
 233                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ W1 ➡[h] W2 &
 234                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 &
 235                                             U1 = ⓛ{p}W1.T1 & U2 = ⓓ{p}ⓝW2.V2.T2
 236                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V & ⬆*[1] V ≘ V2 &
 237                                               ⦃G, L⦄ ⊢ W1 ➡[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 &
 238                                               U1 = ⓓ{p}W1.T1 & U2 = ⓓ{p}W2.ⓐV2.T2.
 239 #n #h #G #L #V1 #U1 #U2 * #c #Hc #H elim (cpg_inv_appl1 … H) -H *
 240 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 241   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 242   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 243   /4 width=5 by or3_intro0, ex3_2_intro, ex2_intro/
 244 | #cV #cW #cT #p #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #H1 #H2 #H3 destruct
 245   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 246   elim (isrt_inv_max … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 247   elim (isrt_inv_max … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 248   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 249   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 250   /4 width=11 by or3_intro1, ex5_6_intro, ex2_intro/
 251 | #cV #cW #cT #p #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #H1 #H2 #H3 destruct
 252   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 253   elim (isrt_inv_max … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 254   elim (isrt_inv_max … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 255   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 256   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 257   /4 width=13 by or3_intro2, ex6_7_intro, ex2_intro/
 258 ]
 259 qed-.
 260
 261 lemma cpm_inv_cast1: ∀n,h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝV1.U1 ➡[n, h] U2 →
 262                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 & ⦃G, L⦄ ⊢ U1 ➡[n, h] T2 &
 263                                  U2 = ⓝV2.T2
 264                       | ⦃G, L⦄ ⊢ U1 ➡[n, h] U2
 265                       | ∃∃m. ⦃G, L⦄ ⊢ V1 ➡[m, h] U2 & n = ↑m.
 266 #n #h #G #L #V1 #U1 #U2 * #c #Hc #H elim (cpg_inv_cast1 … H) -H *
 267 [ #cV #cT #V2 #T2 #HV12 #HT12 #HcVT #H1 #H2 destruct
 268   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 269   lapply (isrt_eq_t_trans … HcV HcVT) -HcVT #H
 270   lapply (isrt_inj … H HcT) -H #H destruct <idempotent_max
 271   /4 width=5 by or3_intro0, ex3_2_intro, ex2_intro/
 272 | #cU #U12 #H destruct
 273   /4 width=3 by isrt_inv_plus_O_dx, or3_intro1, ex2_intro/
 274 | #cU #H12 #H destruct
 275   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 276   /4 width=3 by or3_intro2, ex2_intro/
 277 ]
 278 qed-.
 279
 280 (* Basic forward lemmas *****************************************************)
 281
 282 (* Basic_2A1: includes: cpr_fwd_bind1_minus *)
 283 lemma cpm_fwd_bind1_minus: ∀n,h,I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ➡[n, h] T → ∀p.
 284                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] ⓑ{p,I}V2.T2 &
 285                                     T = -ⓑ{I}V2.T2.
 286 #n #h #I #G #L #V1 #T1 #T * #c #Hc #H #p elim (cpg_fwd_bind1_minus … H p) -H
 287 /3 width=4 by ex2_2_intro, ex2_intro/
 288 qed-.
 289
 290 (* Basic eliminators ********************************************************)
 291
 292 lemma cpm_ind (h): ∀Q:relation5 nat genv lenv term term.
 293                    (∀I,G,L. Q 0 G L (⓪{I}) (⓪{I})) →
 294                    (∀G,L,s. Q 1 G L (⋆s) (⋆(next h s))) →
 295                    (∀n,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 → Q n G K V1 V2 →
 296                      ⬆*[1] V2 ≘ W2 → Q n G (K.ⓓV1) (#0) W2
 297                    ) → (∀n,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 → Q n G K V1 V2 →
 298                      ⬆*[1] V2 ≘ W2 → Q (↑n) G (K.ⓛV1) (#0) W2
 299                    ) → (∀n,I,G,K,T,U,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T → Q n G K (#i) T →
 300                      ⬆*[1] T ≘ U → Q n G (K.ⓘ{I}) (#↑i) (U)
 301                    ) → (∀n,p,I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 →
 302                      Q 0 G L V1 V2 → Q n G (L.ⓑ{I}V1) T1 T2 → Q n G L (ⓑ{p,I}V1.T1) (ⓑ{p,I}V2.T2)
 303                    ) → (∀n,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
 304                      Q 0 G L V1 V2 → Q n G L T1 T2 → Q n G L (ⓐV1.T1) (ⓐV2.T2)
 305                    ) → (∀n,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
 306                      Q n G L V1 V2 → Q n G L T1 T2 → Q n G L (ⓝV1.T1) (ⓝV2.T2)
 307                    ) → (∀n,G,L,V,T1,T,T2. ⦃G, L.ⓓV⦄ ⊢ T1 ➡[n, h] T → Q n G (L.ⓓV) T1 T →
 308                      ⬆*[1] T2 ≘ T → Q n G L (+ⓓV.T1) T2
 309                    ) → (∀n,G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
 310                      Q n G L T1 T2 → Q n G L (ⓝV.T1) T2
 311                    ) → (∀n,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 →
 312                      Q n G L V1 V2 → Q (↑n) G L (ⓝV1.T) V2
 313                    ) → (∀n,p,G,L,V1,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 →
 314                      Q 0 G L V1 V2 → Q 0 G L W1 W2 → Q n G (L.ⓛW1) T1 T2 →
 315                      Q n G L (ⓐV1.ⓛ{p}W1.T1) (ⓓ{p}ⓝW2.V2.T2)
 316                    ) → (∀n,p,G,L,V1,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 →
 317                      Q 0 G L V1 V → Q 0 G L W1 W2 → Q n G (L.ⓓW1) T1 T2 →
 318                      ⬆*[1] V ≘ V2 → Q n G L (ⓐV1.ⓓ{p}W1.T1) (ⓓ{p}W2.ⓐV2.T2)
 319                    ) →
 320                    ∀n,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → Q n G L T1 T2.
 321 #h #Q #IH1 #IH2 #IH3 #IH4 #IH5 #IH6 #IH7 #IH8 #IH9 #IH10 #IH11 #IH12 #IH13 #n #G #L #T1 #T2
 322 * #c #HC #H generalize in match HC; -HC generalize in match n; -n
 323 elim H -c -G -L -T1 -T2
 324 [ #I #G #L #n #H <(isrt_inv_00 … H) -H //
 325 | #G #L #s #n #H <(isrt_inv_01 … H) -H //
 326 | /3 width=4 by ex2_intro/
 327 | #c #G #L #V1 #V2 #W2 #HV12 #HVW2 #IH #x #H
 328   elim (isrt_inv_plus_SO_dx … H) -H // #n #Hc #H destruct
 329   /3 width=4 by ex2_intro/
 330 | /3 width=4 by ex2_intro/
 331 | #cV #cT #p #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #IHV #IHT #n #H
 332   elim (isrt_inv_max_shift_sn … H) -H #HcV #HcT
 333   /3 width=3 by ex2_intro/
 334 | #cV #cT #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #IHV #IHT #n #H
 335   elim (isrt_inv_max_shift_sn … H) -H #HcV #HcT
 336   /3 width=3 by ex2_intro/
 337 | #cU #cT #G #L #U1 #U2 #T1 #T2 #HUT #HU12 #HT12 #IHU #IHT #n #H
 338   elim (isrt_inv_max_eq_t … H) -H // #HcV #HcT
 339   /3 width=3 by ex2_intro/
 340 | #c #G #L #V #T1 #T2 #T #HT12 #HT2 #IH #n #H
 341   lapply (isrt_inv_plus_O_dx … H ?) -H // #Hc
 342   /3 width=4 by ex2_intro/
 343 | #c #G #L #U #T1 #T2 #HT12 #IH #n #H
 344   lapply (isrt_inv_plus_O_dx … H ?) -H // #Hc
 345   /3 width=3 by ex2_intro/
 346 | #c #G #L #U1 #U2 #T #HU12 #IH #x #H
 347   elim (isrt_inv_plus_SO_dx … H) -H // #n #Hc #H destruct
 348   /3 width=3 by ex2_intro/
 349 | #cV #cW #cT #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #IHV #IHW #IHT #n #H
 350   lapply (isrt_inv_plus_O_dx … H ?) -H // >max_shift #H
 351   elim (isrt_inv_max_shift_sn … H) -H #H #HcT
 352   elim (isrt_O_inv_max … H) -H #HcV #HcW
 353   /3 width=3 by ex2_intro/
 354 | #cV #cW #cT #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #IHV #IHW #IHT #n #H
 355   lapply (isrt_inv_plus_O_dx … H ?) -H // >max_shift #H
 356   elim (isrt_inv_max_shift_sn … H) -H #H #HcT
 357   elim (isrt_O_inv_max … H) -H #HcV #HcW
 358   /3 width=4 by ex2_intro/
 359 ]
 360 qed-.