matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpm.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/pred_6.ma".
  16 include "basic_2/notation/relations/pred_5.ma".
  17 include "basic_2/rt_transition/cpg.ma".
  18
  19 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS ***************)
  20
  21 (* Basic_2A1: includes: cpr *)
  22 definition cpm (h) (G) (L) (n): relation2 term term ≝
  23                                 λT1,T2. ∃∃c. 𝐑𝐓⦃n, c⦄ & ⦃G, L⦄ ⊢ T1 ⬈[eq_t, c, h] T2.
  24
  25 interpretation
  26    "t-bound context-sensitive parallel rt-transition (term)"
  27    'PRed n h G L T1 T2 = (cpm h G L n T1 T2).
  28
  29 interpretation
  30    "context-sensitive parallel r-transition (term)"
  31    'PRed h G L T1 T2 = (cpm h G L O T1 T2).
  32
  33 (* Basic properties *********************************************************)
  34
  35 lemma cpm_ess: ∀h,G,L,s. ⦃G, L⦄ ⊢ ⋆s ➡[1, h] ⋆(next h s).
  36 /2 width=3 by cpg_ess, ex2_intro/ qed.
  37
  38 lemma cpm_delta: ∀n,h,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 →
  39                  ⬆*[1] V2 ≘ W2 → ⦃G, K.ⓓV1⦄ ⊢ #0 ➡[n, h] W2.
  40 #n #h #G #K #V1 #V2 #W2 *
  41 /3 width=5 by cpg_delta, ex2_intro/
  42 qed.
  43
  44 lemma cpm_ell: ∀n,h,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 →
  45                ⬆*[1] V2 ≘ W2 → ⦃G, K.ⓛV1⦄ ⊢ #0 ➡[↑n, h] W2.
  46 #n #h #G #K #V1 #V2 #W2 *
  47 /3 width=5 by cpg_ell, ex2_intro, isrt_succ/
  48 qed.
  49
  50 lemma cpm_lref: ∀n,h,I,G,K,T,U,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T →
  51                 ⬆*[1] T ≘ U → ⦃G, K.ⓘ{I}⦄ ⊢ #↑i ➡[n, h] U.
  52 #n #h #I #G #K #T #U #i *
  53 /3 width=5 by cpg_lref, ex2_intro/
  54 qed.
  55
  56 (* Basic_2A1: includes: cpr_bind *)
  57 lemma cpm_bind: ∀n,h,p,I,G,L,V1,V2,T1,T2.
  58                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 →
  59                 ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] ⓑ{p,I}V2.T2.
  60 #n #h #p #I #G #L #V1 #V2 #T1 #T2 * #cV #HcV #HV12 *
  61 /5 width=5 by cpg_bind, isrt_max_O1, isr_shift, ex2_intro/
  62 qed.
  63
  64 lemma cpm_appl: ∀n,h,G,L,V1,V2,T1,T2.
  65                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
  66                 ⦃G, L⦄ ⊢ ⓐV1.T1 ➡[n, h] ⓐV2.T2.
  67 #n #h #G #L #V1 #V2 #T1 #T2 * #cV #HcV #HV12 *
  68 /5 width=5 by isrt_max_O1, isr_shift, cpg_appl, ex2_intro/
  69 qed.
  70
  71 lemma cpm_cast: ∀n,h,G,L,U1,U2,T1,T2.
  72                 ⦃G, L⦄ ⊢ U1 ➡[n, h] U2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
  73                 ⦃G, L⦄ ⊢ ⓝU1.T1 ➡[n, h] ⓝU2.T2.
  74 #n #h #G #L #U1 #U2 #T1 #T2 * #cU #HcU #HU12 *
  75 /4 width=6 by cpg_cast, isrt_max_idem1, isrt_mono, ex2_intro/
  76 qed.
  77
  78 (* Basic_2A1: includes: cpr_zeta *)
  79 lemma cpm_zeta (n) (h) (G) (L):
  80                ∀T1,T. ⬆*[1] T ≘ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡[n,h] T2 →
  81                ∀V. ⦃G, L⦄ ⊢ +ⓓV.T1 ➡[n, h] T2.
  82 #n #h #G #L #T1 #T #HT1 #T2 *
  83 /3 width=5 by cpg_zeta, isrt_plus_O2, ex2_intro/
  84 qed.
  85
  86 (* Basic_2A1: includes: cpr_eps *)
  87 lemma cpm_eps: ∀n,h,G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → ⦃G, L⦄ ⊢ ⓝV.T1 ➡[n, h] T2.
  88 #n #h #G #L #V #T1 #T2 *
  89 /3 width=3 by cpg_eps, isrt_plus_O2, ex2_intro/
  90 qed.
  91
  92 lemma cpm_ee: ∀n,h,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 → ⦃G, L⦄ ⊢ ⓝV1.T ➡[↑n, h] V2.
  93 #n #h #G #L #V1 #V2 #T *
  94 /3 width=3 by cpg_ee, isrt_succ, ex2_intro/
  95 qed.
  96
  97 (* Basic_2A1: includes: cpr_beta *)
  98 lemma cpm_beta: ∀n,h,p,G,L,V1,V2,W1,W2,T1,T2.
  99                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 →
 100                 ⦃G, L⦄ ⊢ ⓐV1.ⓛ{p}W1.T1 ➡[n, h] ⓓ{p}ⓝW2.V2.T2.
 101 #n #h #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 * #riV #rhV #HV12 * #riW #rhW #HW12 *
 102 /6 width=7 by cpg_beta, isrt_plus_O2, isrt_max, isr_shift, ex2_intro/
 103 qed.
 104
 105 (* Basic_2A1: includes: cpr_theta *)
 106 lemma cpm_theta: ∀n,h,p,G,L,V1,V,V2,W1,W2,T1,T2.
 107                  ⦃G, L⦄ ⊢ V1 ➡[h] V → ⬆*[1] V ≘ V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
 108                  ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 →
 109                  ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}W1.T1 ➡[n, h] ⓓ{p}W2.ⓐV2.T2.
 110 #n #h #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 * #riV #rhV #HV1 #HV2 * #riW #rhW #HW12 *
 111 /6 width=9 by cpg_theta, isrt_plus_O2, isrt_max, isr_shift, ex2_intro/
 112 qed.
 113
 114 (* Basic properties with r-transition ***************************************)
 115
 116 (* Note: this is needed by cpms_ind_sn and cpms_ind_dx *)
 117 (* Basic_1: includes by definition: pr0_refl *)
 118 (* Basic_2A1: includes: cpr_atom *)
 119 lemma cpr_refl: ∀h,G,L. reflexive … (cpm h G L 0).
 120 /3 width=3 by cpg_refl, ex2_intro/ qed.
 121
 122 (* Basic inversion lemmas ***************************************************)
 123
 124 lemma cpm_inv_atom1: ∀n,h,J,G,L,T2. ⦃G, L⦄ ⊢ ⓪{J} ➡[n, h] T2 →
 125                      ∨∨ T2 = ⓪{J} ∧ n = 0
 126                       | ∃∃s. T2 = ⋆(next h s) & J = Sort s & n = 1
 127                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 & ⬆*[1] V2 ≘ T2 &
 128                                    L = K.ⓓV1 & J = LRef 0
 129                       | ∃∃m,K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[m, h] V2 & ⬆*[1] V2 ≘ T2 &
 130                                      L = K.ⓛV1 & J = LRef 0 & n = ↑m
 131                       | ∃∃I,K,T,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T & ⬆*[1] T ≘ T2 &
 132                                    L = K.ⓘ{I} & J = LRef (↑i).
 133 #n #h #J #G #L #T2 * #c #Hc #H elim (cpg_inv_atom1 … H) -H *
 134 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or5_intro0, conj/
 135 | #s #H1 #H2 #H3 destruct /4 width=3 by isrt_inv_01, or5_intro1, ex3_intro/
 136 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 #H3 destruct
 137   /4 width=6 by or5_intro2, ex4_3_intro, ex2_intro/
 138 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 #H3 destruct
 139   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 140   /4 width=9 by or5_intro3, ex5_4_intro, ex2_intro/
 141 | #I #K #V2 #i #HV2 #HVT2 #H1 #H2 destruct
 142   /4 width=8 by or5_intro4, ex4_4_intro, ex2_intro/
 143 ]
 144 qed-.
 145
 146 lemma cpm_inv_sort1: ∀n,h,G,L,T2,s. ⦃G, L⦄ ⊢ ⋆s ➡[n,h] T2 →
 147                      ∧∧ T2 = ⋆(((next h)^n) s) & n ≤ 1.
 148 #n #h #G #L #T2 #s * #c #Hc #H
 149 elim (cpg_inv_sort1 … H) -H * #H1 #H2 destruct
 150 [ lapply (isrt_inv_00 … Hc) | lapply (isrt_inv_01 … Hc) ] -Hc
 151 #H destruct /2 width=1 by conj/
 152 qed-.
 153
 154 lemma cpm_inv_zero1: ∀n,h,G,L,T2. ⦃G, L⦄ ⊢ #0 ➡[n, h] T2 →
 155                      ∨∨ T2 = #0 ∧ n = 0
 156                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 & ⬆*[1] V2 ≘ T2 &
 157                                    L = K.ⓓV1
 158                       | ∃∃m,K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[m, h] V2 & ⬆*[1] V2 ≘ T2 &
 159                                      L = K.ⓛV1 & n = ↑m.
 160 #n #h #G #L #T2 * #c #Hc #H elim (cpg_inv_zero1 … H) -H *
 161 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or3_intro0, conj/
 162 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 destruct
 163   /4 width=8 by or3_intro1, ex3_3_intro, ex2_intro/
 164 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 destruct
 165   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 166   /4 width=8 by or3_intro2, ex4_4_intro, ex2_intro/
 167 ]
 168 qed-.
 169
 170 lemma cpm_inv_lref1: ∀n,h,G,L,T2,i. ⦃G, L⦄ ⊢ #↑i ➡[n, h] T2 →
 171                      ∨∨ T2 = #(↑i) ∧ n = 0
 172                       | ∃∃I,K,T. ⦃G, K⦄ ⊢ #i ➡[n, h] T & ⬆*[1] T ≘ T2 & L = K.ⓘ{I}.
 173 #n #h #G #L #T2 #i * #c #Hc #H elim (cpg_inv_lref1 … H) -H *
 174 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or_introl, conj/
 175 | #I #K #V2 #HV2 #HVT2 #H destruct
 176  /4 width=6 by ex3_3_intro, ex2_intro, or_intror/
 177 ]
 178 qed-.
 179
 180 lemma cpm_inv_gref1: ∀n,h,G,L,T2,l. ⦃G, L⦄ ⊢ §l ➡[n, h] T2 → T2 = §l ∧ n = 0.
 181 #n #h #G #L #T2 #l * #c #Hc #H elim (cpg_inv_gref1 … H) -H
 182 #H1 #H2 destruct /3 width=1 by isrt_inv_00, conj/
 183 qed-.
 184
 185 (* Basic_2A1: includes: cpr_inv_bind1 *)
 186 lemma cpm_inv_bind1: ∀n,h,p,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] U2 →
 187                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 &
 188                                  U2 = ⓑ{p,I}V2.T2
 189                       | ∃∃T. ⬆*[1] T ≘ T1 & ⦃G, L⦄ ⊢ T ➡[n, h] U2 &
 190                              p = true & I = Abbr.
 191 #n #h #p #I #G #L #V1 #T1 #U2 * #c #Hc #H elim (cpg_inv_bind1 … H) -H *
 192 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 193   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 194   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 195   /4 width=5 by ex3_2_intro, ex2_intro, or_introl/
 196 | #cT #T2 #HT21 #HTU2 #H1 #H2 #H3 destruct
 197   /5 width=5 by isrt_inv_plus_O_dx, ex4_intro, ex2_intro, or_intror/
 198 ]
 199 qed-.
 200
 201 (* Basic_1: includes: pr0_gen_abbr pr2_gen_abbr *)
 202 (* Basic_2A1: includes: cpr_inv_abbr1 *)
 203 lemma cpm_inv_abbr1: ∀n,h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{p}V1.T1 ➡[n, h] U2 →
 204                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ➡[n, h] T2 &
 205                                  U2 = ⓓ{p}V2.T2
 206                       | ∃∃T. ⬆*[1] T ≘ T1 & ⦃G, L⦄ ⊢ T ➡[n, h] U2 & p = true.
 207 #n #h #p #G #L #V1 #T1 #U2 #H
 208 elim (cpm_inv_bind1 … H) -H
 209 [ /3 width=1 by or_introl/
 210 | * /3 width=3 by ex3_intro, or_intror/
 211 ]
 212 qed-.
 213
 214 (* Basic_1: includes: pr0_gen_abst pr2_gen_abst *)
 215 (* Basic_2A1: includes: cpr_inv_abst1 *)
 216 lemma cpm_inv_abst1: ∀n,h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{p}V1.T1 ➡[n, h] U2 →
 217                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡[n, h] T2 &
 218                               U2 = ⓛ{p}V2.T2.
 219 #n #h #p #G #L #V1 #T1 #U2 #H
 220 elim (cpm_inv_bind1 … H) -H
 221 [ /3 width=1 by or_introl/
 222 | * #T #_ #_ #_ #H destruct
 223 ]
 224 qed-.
 225
 226 (* Basic_1: includes: pr0_gen_appl pr2_gen_appl *)
 227 (* Basic_2A1: includes: cpr_inv_appl1 *)
 228 lemma cpm_inv_appl1: ∀n,h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐ V1.U1 ➡[n, h] U2 →
 229                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ U1 ➡[n, h] T2 &
 230                                  U2 = ⓐV2.T2
 231                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ W1 ➡[h] W2 &
 232                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 &
 233                                             U1 = ⓛ{p}W1.T1 & U2 = ⓓ{p}ⓝW2.V2.T2
 234                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V & ⬆*[1] V ≘ V2 &
 235                                               ⦃G, L⦄ ⊢ W1 ➡[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 &
 236                                               U1 = ⓓ{p}W1.T1 & U2 = ⓓ{p}W2.ⓐV2.T2.
 237 #n #h #G #L #V1 #U1 #U2 * #c #Hc #H elim (cpg_inv_appl1 … H) -H *
 238 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 239   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 240   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 241   /4 width=5 by or3_intro0, ex3_2_intro, ex2_intro/
 242 | #cV #cW #cT #p #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #H1 #H2 #H3 destruct
 243   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 244   elim (isrt_inv_max … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 245   elim (isrt_inv_max … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 246   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 247   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 248   /4 width=11 by or3_intro1, ex5_6_intro, ex2_intro/
 249 | #cV #cW #cT #p #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #H1 #H2 #H3 destruct
 250   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 251   elim (isrt_inv_max … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 252   elim (isrt_inv_max … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 253   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 254   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 255   /4 width=13 by or3_intro2, ex6_7_intro, ex2_intro/
 256 ]
 257 qed-.
 258
 259 lemma cpm_inv_cast1: ∀n,h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝV1.U1 ➡[n, h] U2 →
 260                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 & ⦃G, L⦄ ⊢ U1 ➡[n, h] T2 &
 261                                  U2 = ⓝV2.T2
 262                       | ⦃G, L⦄ ⊢ U1 ➡[n, h] U2
 263                       | ∃∃m. ⦃G, L⦄ ⊢ V1 ➡[m, h] U2 & n = ↑m.
 264 #n #h #G #L #V1 #U1 #U2 * #c #Hc #H elim (cpg_inv_cast1 … H) -H *
 265 [ #cV #cT #V2 #T2 #HV12 #HT12 #HcVT #H1 #H2 destruct
 266   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 267   lapply (isrt_eq_t_trans … HcV HcVT) -HcVT #H
 268   lapply (isrt_inj … H HcT) -H #H destruct <idempotent_max
 269   /4 width=5 by or3_intro0, ex3_2_intro, ex2_intro/
 270 | #cU #U12 #H destruct
 271   /4 width=3 by isrt_inv_plus_O_dx, or3_intro1, ex2_intro/
 272 | #cU #H12 #H destruct
 273   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 274   /4 width=3 by or3_intro2, ex2_intro/
 275 ]
 276 qed-.
 277
 278 (* Basic forward lemmas *****************************************************)
 279
 280 (* Basic_2A1: includes: cpr_fwd_bind1_minus *)
 281 lemma cpm_fwd_bind1_minus: ∀n,h,I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ➡[n, h] T → ∀p.
 282                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] ⓑ{p,I}V2.T2 &
 283                                     T = -ⓑ{I}V2.T2.
 284 #n #h #I #G #L #V1 #T1 #T * #c #Hc #H #p elim (cpg_fwd_bind1_minus … H p) -H
 285 /3 width=4 by ex2_2_intro, ex2_intro/
 286 qed-.
 287
 288 (* Basic eliminators ********************************************************)
 289
 290 lemma cpm_ind (h): ∀Q:relation5 nat genv lenv term term.
 291                    (∀I,G,L. Q 0 G L (⓪{I}) (⓪{I})) →
 292                    (∀G,L,s. Q 1 G L (⋆s) (⋆(next h s))) →
 293                    (∀n,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 → Q n G K V1 V2 →
 294                      ⬆*[1] V2 ≘ W2 → Q n G (K.ⓓV1) (#0) W2
 295                    ) → (∀n,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 → Q n G K V1 V2 →
 296                      ⬆*[1] V2 ≘ W2 → Q (↑n) G (K.ⓛV1) (#0) W2
 297                    ) → (∀n,I,G,K,T,U,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T → Q n G K (#i) T →
 298                      ⬆*[1] T ≘ U → Q n G (K.ⓘ{I}) (#↑i) (U)
 299                    ) → (∀n,p,I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 →
 300                      Q 0 G L V1 V2 → Q n G (L.ⓑ{I}V1) T1 T2 → Q n G L (ⓑ{p,I}V1.T1) (ⓑ{p,I}V2.T2)
 301                    ) → (∀n,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
 302                      Q 0 G L V1 V2 → Q n G L T1 T2 → Q n G L (ⓐV1.T1) (ⓐV2.T2)
 303                    ) → (∀n,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
 304                      Q n G L V1 V2 → Q n G L T1 T2 → Q n G L (ⓝV1.T1) (ⓝV2.T2)
 305                    ) → (∀n,G,L,V,T1,T,T2. ⬆*[1] T ≘ T1 → ⦃G, L⦄ ⊢ T ➡[n, h] T2 →
 306                      Q n G L T T2 → Q n G L (+ⓓV.T1) T2
 307                    ) → (∀n,G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
 308                      Q n G L T1 T2 → Q n G L (ⓝV.T1) T2
 309                    ) → (∀n,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 →
 310                      Q n G L V1 V2 → Q (↑n) G L (ⓝV1.T) V2
 311                    ) → (∀n,p,G,L,V1,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 →
 312                      Q 0 G L V1 V2 → Q 0 G L W1 W2 → Q n G (L.ⓛW1) T1 T2 →
 313                      Q n G L (ⓐV1.ⓛ{p}W1.T1) (ⓓ{p}ⓝW2.V2.T2)
 314                    ) → (∀n,p,G,L,V1,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 →
 315                      Q 0 G L V1 V → Q 0 G L W1 W2 → Q n G (L.ⓓW1) T1 T2 →
 316                      ⬆*[1] V ≘ V2 → Q n G L (ⓐV1.ⓓ{p}W1.T1) (ⓓ{p}W2.ⓐV2.T2)
 317                    ) →
 318                    ∀n,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → Q n G L T1 T2.
 319 #h #Q #IH1 #IH2 #IH3 #IH4 #IH5 #IH6 #IH7 #IH8 #IH9 #IH10 #IH11 #IH12 #IH13 #n #G #L #T1 #T2
 320 * #c #HC #H generalize in match HC; -HC generalize in match n; -n
 321 elim H -c -G -L -T1 -T2
 322 [ #I #G #L #n #H <(isrt_inv_00 … H) -H //
 323 | #G #L #s #n #H <(isrt_inv_01 … H) -H //
 324 | /3 width=4 by ex2_intro/
 325 | #c #G #L #V1 #V2 #W2 #HV12 #HVW2 #IH #x #H
 326   elim (isrt_inv_plus_SO_dx … H) -H // #n #Hc #H destruct
 327   /3 width=4 by ex2_intro/
 328 | /3 width=4 by ex2_intro/
 329 | #cV #cT #p #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #IHV #IHT #n #H
 330   elim (isrt_inv_max_shift_sn … H) -H #HcV #HcT
 331   /3 width=3 by ex2_intro/
 332 | #cV #cT #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #IHV #IHT #n #H
 333   elim (isrt_inv_max_shift_sn … H) -H #HcV #HcT
 334   /3 width=3 by ex2_intro/
 335 | #cU #cT #G #L #U1 #U2 #T1 #T2 #HUT #HU12 #HT12 #IHU #IHT #n #H
 336   elim (isrt_inv_max_eq_t … H) -H // #HcV #HcT
 337   /3 width=3 by ex2_intro/
 338 | #c #G #L #V #T1 #T #T2 #HT1 #HT2 #IH #n #H
 339   lapply (isrt_inv_plus_O_dx … H ?) -H // #Hc
 340   /3 width=4 by ex2_intro/
 341 | #c #G #L #U #T1 #T2 #HT12 #IH #n #H
 342   lapply (isrt_inv_plus_O_dx … H ?) -H // #Hc
 343   /3 width=3 by ex2_intro/
 344 | #c #G #L #U1 #U2 #T #HU12 #IH #x #H
 345   elim (isrt_inv_plus_SO_dx … H) -H // #n #Hc #H destruct
 346   /3 width=3 by ex2_intro/
 347 | #cV #cW #cT #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #IHV #IHW #IHT #n #H
 348   lapply (isrt_inv_plus_O_dx … H ?) -H // >max_shift #H
 349   elim (isrt_inv_max_shift_sn … H) -H #H #HcT
 350   elim (isrt_O_inv_max … H) -H #HcV #HcW
 351   /3 width=3 by ex2_intro/
 352 | #cV #cW #cT #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #IHV #IHW #IHT #n #H
 353   lapply (isrt_inv_plus_O_dx … H ?) -H // >max_shift #H
 354   elim (isrt_inv_max_shift_sn … H) -H #H #HcT
 355   elim (isrt_O_inv_max … H) -H #HcV #HcW
 356   /3 width=4 by ex2_intro/
 357 ]
 358 qed-.