matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpm.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/pred_6.ma".
  16 include "basic_2/notation/relations/pred_5.ma".
  17 include "basic_2/rt_transition/cpg.ma".
  18
  19 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS ***************)
  20
  21 (* Basic_2A1: includes: cpr *)
  22 definition cpm (h) (G) (L) (n): relation2 term term ≝
  23                                 λT1,T2. ∃∃c. 𝐑𝐓⦃n, c⦄ & ⦃G, L⦄ ⊢ T1 ⬈[eq_t, c, h] T2.
  24
  25 interpretation
  26    "t-bound context-sensitive parallel rt-transition (term)"
  27    'PRed n h G L T1 T2 = (cpm h G L n T1 T2).
  28
  29 interpretation
  30    "context-sensitive parallel r-transition (term)"
  31    'PRed h G L T1 T2 = (cpm h G L O T1 T2).
  32
  33 (* Basic properties *********************************************************)
  34
  35 lemma cpm_ess: ∀h,G,L,s. ⦃G, L⦄ ⊢ ⋆s ➡[1, h] ⋆(next h s).
  36 /2 width=3 by cpg_ess, ex2_intro/ qed.
  37
  38 lemma cpm_delta: ∀n,h,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 →
  39                  ⬆*[1] V2 ≘ W2 → ⦃G, K.ⓓV1⦄ ⊢ #0 ➡[n, h] W2.
  40 #n #h #G #K #V1 #V2 #W2 *
  41 /3 width=5 by cpg_delta, ex2_intro/
  42 qed.
  43
  44 lemma cpm_ell: ∀n,h,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 →
  45                ⬆*[1] V2 ≘ W2 → ⦃G, K.ⓛV1⦄ ⊢ #0 ➡[↑n, h] W2.
  46 #n #h #G #K #V1 #V2 #W2 *
  47 /3 width=5 by cpg_ell, ex2_intro, isrt_succ/
  48 qed.
  49
  50 lemma cpm_lref: ∀n,h,I,G,K,T,U,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T →
  51                 ⬆*[1] T ≘ U → ⦃G, K.ⓘ{I}⦄ ⊢ #↑i ➡[n, h] U.
  52 #n #h #I #G #K #T #U #i *
  53 /3 width=5 by cpg_lref, ex2_intro/
  54 qed.
  55
  56 (* Basic_2A1: includes: cpr_bind *)
  57 lemma cpm_bind: ∀n,h,p,I,G,L,V1,V2,T1,T2.
  58                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 →
  59                 ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] ⓑ{p,I}V2.T2.
  60 #n #h #p #I #G #L #V1 #V2 #T1 #T2 * #cV #HcV #HV12 *
  61 /5 width=5 by cpg_bind, isrt_max_O1, isr_shift, ex2_intro/
  62 qed.
  63
  64 lemma cpm_appl: ∀n,h,G,L,V1,V2,T1,T2.
  65                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
  66                 ⦃G, L⦄ ⊢ ⓐV1.T1 ➡[n, h] ⓐV2.T2.
  67 #n #h #G #L #V1 #V2 #T1 #T2 * #cV #HcV #HV12 *
  68 /5 width=5 by isrt_max_O1, isr_shift, cpg_appl, ex2_intro/
  69 qed.
  70
  71 lemma cpm_cast: ∀n,h,G,L,U1,U2,T1,T2.
  72                 ⦃G, L⦄ ⊢ U1 ➡[n, h] U2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
  73                 ⦃G, L⦄ ⊢ ⓝU1.T1 ➡[n, h] ⓝU2.T2.
  74 #n #h #G #L #U1 #U2 #T1 #T2 * #cU #HcU #HU12 *
  75 /4 width=6 by cpg_cast, isrt_max_idem1, isrt_mono, ex2_intro/
  76 qed.
  77
  78 (* Basic_2A1: includes: cpr_zeta *)
  79 lemma cpm_zeta (n) (h) (G) (L):
  80                ∀T1,T. ⬆*[1] T ≘ T1 → ∀T2. ⦃G, L⦄ ⊢ T ➡[n,h] T2 →
  81                ∀V. ⦃G, L⦄ ⊢ +ⓓV.T1 ➡[n, h] T2.
  82 #n #h #G #L #T1 #T #HT1 #T2 *
  83 /3 width=5 by cpg_zeta, isrt_plus_O2, ex2_intro/
  84 qed.
  85
  86 (* Basic_2A1: includes: cpr_eps *)
  87 lemma cpm_eps: ∀n,h,G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → ⦃G, L⦄ ⊢ ⓝV.T1 ➡[n, h] T2.
  88 #n #h #G #L #V #T1 #T2 *
  89 /3 width=3 by cpg_eps, isrt_plus_O2, ex2_intro/
  90 qed.
  91
  92 lemma cpm_ee: ∀n,h,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 → ⦃G, L⦄ ⊢ ⓝV1.T ➡[↑n, h] V2.
  93 #n #h #G #L #V1 #V2 #T *
  94 /3 width=3 by cpg_ee, isrt_succ, ex2_intro/
  95 qed.
  96
  97 (* Basic_2A1: includes: cpr_beta *)
  98 lemma cpm_beta: ∀n,h,p,G,L,V1,V2,W1,W2,T1,T2.
  99                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 →
 100                 ⦃G, L⦄ ⊢ ⓐV1.ⓛ{p}W1.T1 ➡[n, h] ⓓ{p}ⓝW2.V2.T2.
 101 #n #h #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 * #riV #rhV #HV12 * #riW #rhW #HW12 *
 102 /6 width=7 by cpg_beta, isrt_plus_O2, isrt_max, isr_shift, ex2_intro/
 103 qed.
 104
 105 (* Basic_2A1: includes: cpr_theta *)
 106 lemma cpm_theta: ∀n,h,p,G,L,V1,V,V2,W1,W2,T1,T2.
 107                  ⦃G, L⦄ ⊢ V1 ➡[h] V → ⬆*[1] V ≘ V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
 108                  ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 →
 109                  ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}W1.T1 ➡[n, h] ⓓ{p}W2.ⓐV2.T2.
 110 #n #h #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 * #riV #rhV #HV1 #HV2 * #riW #rhW #HW12 *
 111 /6 width=9 by cpg_theta, isrt_plus_O2, isrt_max, isr_shift, ex2_intro/
 112 qed.
 113
 114 (* Basic properties with r-transition ***************************************)
 115
 116 (* Note: this is needed by cpms_ind_sn and cpms_ind_dx *)
 117 (* Basic_1: includes by definition: pr0_refl *)
 118 (* Basic_2A1: includes: cpr_atom *)
 119 lemma cpr_refl: ∀h,G,L. reflexive … (cpm h G L 0).
 120 /3 width=3 by cpg_refl, ex2_intro/ qed.
 121
 122 (* Advanced properties ******************************************************)
 123
 124 lemma cpm_sort_iter (h) (G) (L):
 125                     ∀n. n ≤ 1 →
 126                     ∀s. ⦃G,L⦄ ⊢ ⋆s ➡ [n,h] ⋆((next h)^n s).
 127 #h #G #L * //
 128 #n #H #s <(le_n_O_to_eq n) /2 width=1 by le_S_S_to_le/
 129 qed.
 130
 131 (* Basic inversion lemmas ***************************************************)
 132
 133 lemma cpm_inv_atom1: ∀n,h,J,G,L,T2. ⦃G, L⦄ ⊢ ⓪{J} ➡[n, h] T2 →
 134                      ∨∨ T2 = ⓪{J} ∧ n = 0
 135                       | ∃∃s. T2 = ⋆(next h s) & J = Sort s & n = 1
 136                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 & ⬆*[1] V2 ≘ T2 &
 137                                    L = K.ⓓV1 & J = LRef 0
 138                       | ∃∃m,K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[m, h] V2 & ⬆*[1] V2 ≘ T2 &
 139                                      L = K.ⓛV1 & J = LRef 0 & n = ↑m
 140                       | ∃∃I,K,T,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T & ⬆*[1] T ≘ T2 &
 141                                    L = K.ⓘ{I} & J = LRef (↑i).
 142 #n #h #J #G #L #T2 * #c #Hc #H elim (cpg_inv_atom1 … H) -H *
 143 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or5_intro0, conj/
 144 | #s #H1 #H2 #H3 destruct /4 width=3 by isrt_inv_01, or5_intro1, ex3_intro/
 145 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 #H3 destruct
 146   /4 width=6 by or5_intro2, ex4_3_intro, ex2_intro/
 147 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 #H3 destruct
 148   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 149   /4 width=9 by or5_intro3, ex5_4_intro, ex2_intro/
 150 | #I #K #V2 #i #HV2 #HVT2 #H1 #H2 destruct
 151   /4 width=8 by or5_intro4, ex4_4_intro, ex2_intro/
 152 ]
 153 qed-.
 154
 155 lemma cpm_inv_sort1: ∀n,h,G,L,T2,s. ⦃G, L⦄ ⊢ ⋆s ➡[n,h] T2 →
 156                      ∧∧ T2 = ⋆(((next h)^n) s) & n ≤ 1.
 157 #n #h #G #L #T2 #s * #c #Hc #H
 158 elim (cpg_inv_sort1 … H) -H * #H1 #H2 destruct
 159 [ lapply (isrt_inv_00 … Hc) | lapply (isrt_inv_01 … Hc) ] -Hc
 160 #H destruct /2 width=1 by conj/
 161 qed-.
 162
 163 lemma cpm_inv_zero1: ∀n,h,G,L,T2. ⦃G, L⦄ ⊢ #0 ➡[n, h] T2 →
 164                      ∨∨ T2 = #0 ∧ n = 0
 165                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 & ⬆*[1] V2 ≘ T2 &
 166                                    L = K.ⓓV1
 167                       | ∃∃m,K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[m, h] V2 & ⬆*[1] V2 ≘ T2 &
 168                                      L = K.ⓛV1 & n = ↑m.
 169 #n #h #G #L #T2 * #c #Hc #H elim (cpg_inv_zero1 … H) -H *
 170 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or3_intro0, conj/
 171 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 destruct
 172   /4 width=8 by or3_intro1, ex3_3_intro, ex2_intro/
 173 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 destruct
 174   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 175   /4 width=8 by or3_intro2, ex4_4_intro, ex2_intro/
 176 ]
 177 qed-.
 178
 179 lemma cpm_inv_lref1: ∀n,h,G,L,T2,i. ⦃G, L⦄ ⊢ #↑i ➡[n, h] T2 →
 180                      ∨∨ T2 = #(↑i) ∧ n = 0
 181                       | ∃∃I,K,T. ⦃G, K⦄ ⊢ #i ➡[n, h] T & ⬆*[1] T ≘ T2 & L = K.ⓘ{I}.
 182 #n #h #G #L #T2 #i * #c #Hc #H elim (cpg_inv_lref1 … H) -H *
 183 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or_introl, conj/
 184 | #I #K #V2 #HV2 #HVT2 #H destruct
 185  /4 width=6 by ex3_3_intro, ex2_intro, or_intror/
 186 ]
 187 qed-.
 188
 189 lemma cpm_inv_gref1: ∀n,h,G,L,T2,l. ⦃G, L⦄ ⊢ §l ➡[n, h] T2 → T2 = §l ∧ n = 0.
 190 #n #h #G #L #T2 #l * #c #Hc #H elim (cpg_inv_gref1 … H) -H
 191 #H1 #H2 destruct /3 width=1 by isrt_inv_00, conj/
 192 qed-.
 193
 194 (* Basic_2A1: includes: cpr_inv_bind1 *)
 195 lemma cpm_inv_bind1: ∀n,h,p,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] U2 →
 196                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 &
 197                                  U2 = ⓑ{p,I}V2.T2
 198                       | ∃∃T. ⬆*[1] T ≘ T1 & ⦃G, L⦄ ⊢ T ➡[n, h] U2 &
 199                              p = true & I = Abbr.
 200 #n #h #p #I #G #L #V1 #T1 #U2 * #c #Hc #H elim (cpg_inv_bind1 … H) -H *
 201 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 202   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 203   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 204   /4 width=5 by ex3_2_intro, ex2_intro, or_introl/
 205 | #cT #T2 #HT21 #HTU2 #H1 #H2 #H3 destruct
 206   /5 width=5 by isrt_inv_plus_O_dx, ex4_intro, ex2_intro, or_intror/
 207 ]
 208 qed-.
 209
 210 (* Basic_1: includes: pr0_gen_abbr pr2_gen_abbr *)
 211 (* Basic_2A1: includes: cpr_inv_abbr1 *)
 212 lemma cpm_inv_abbr1: ∀n,h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{p}V1.T1 ➡[n, h] U2 →
 213                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ➡[n, h] T2 &
 214                                  U2 = ⓓ{p}V2.T2
 215                       | ∃∃T. ⬆*[1] T ≘ T1 & ⦃G, L⦄ ⊢ T ➡[n, h] U2 & p = true.
 216 #n #h #p #G #L #V1 #T1 #U2 #H
 217 elim (cpm_inv_bind1 … H) -H
 218 [ /3 width=1 by or_introl/
 219 | * /3 width=3 by ex3_intro, or_intror/
 220 ]
 221 qed-.
 222
 223 (* Basic_1: includes: pr0_gen_abst pr2_gen_abst *)
 224 (* Basic_2A1: includes: cpr_inv_abst1 *)
 225 lemma cpm_inv_abst1: ∀n,h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{p}V1.T1 ➡[n, h] U2 →
 226                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡[n, h] T2 &
 227                               U2 = ⓛ{p}V2.T2.
 228 #n #h #p #G #L #V1 #T1 #U2 #H
 229 elim (cpm_inv_bind1 … H) -H
 230 [ /3 width=1 by or_introl/
 231 | * #T #_ #_ #_ #H destruct
 232 ]
 233 qed-.
 234
 235 lemma cpm_inv_abst_bi: ∀n,h,p1,p2,G,L,V1,V2,T1,T2. ⦃G,L⦄ ⊢ ⓛ{p1}V1.T1 ➡[n,h] ⓛ{p2}V2.T2 →
 236                        ∧∧ ⦃G,L⦄ ⊢ V1 ➡[h] V2 & ⦃G,L.ⓛV1⦄ ⊢ T1 ➡[n,h] T2 & p1 = p2.
 237 #n #h #p1 #p2 #G #L #V1 #V2 #T1 #T2 #H
 238 elim (cpm_inv_abst1 … H) -H #XV #XT #HV #HT #H destruct
 239 /2 width=1 by and3_intro/
 240 qed-.
 241
 242 (* Basic_1: includes: pr0_gen_appl pr2_gen_appl *)
 243 (* Basic_2A1: includes: cpr_inv_appl1 *)
 244 lemma cpm_inv_appl1: ∀n,h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐ V1.U1 ➡[n, h] U2 →
 245                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ U1 ➡[n, h] T2 &
 246                                  U2 = ⓐV2.T2
 247                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ W1 ➡[h] W2 &
 248                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 &
 249                                             U1 = ⓛ{p}W1.T1 & U2 = ⓓ{p}ⓝW2.V2.T2
 250                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V & ⬆*[1] V ≘ V2 &
 251                                               ⦃G, L⦄ ⊢ W1 ➡[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 &
 252                                               U1 = ⓓ{p}W1.T1 & U2 = ⓓ{p}W2.ⓐV2.T2.
 253 #n #h #G #L #V1 #U1 #U2 * #c #Hc #H elim (cpg_inv_appl1 … H) -H *
 254 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 255   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 256   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 257   /4 width=5 by or3_intro0, ex3_2_intro, ex2_intro/
 258 | #cV #cW #cT #p #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #H1 #H2 #H3 destruct
 259   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 260   elim (isrt_inv_max … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 261   elim (isrt_inv_max … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 262   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 263   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 264   /4 width=11 by or3_intro1, ex5_6_intro, ex2_intro/
 265 | #cV #cW #cT #p #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #H1 #H2 #H3 destruct
 266   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 267   elim (isrt_inv_max … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 268   elim (isrt_inv_max … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 269   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 270   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 271   /4 width=13 by or3_intro2, ex6_7_intro, ex2_intro/
 272 ]
 273 qed-.
 274
 275 lemma cpm_inv_cast1: ∀n,h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝV1.U1 ➡[n, h] U2 →
 276                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 & ⦃G, L⦄ ⊢ U1 ➡[n, h] T2 &
 277                                  U2 = ⓝV2.T2
 278                       | ⦃G, L⦄ ⊢ U1 ➡[n, h] U2
 279                       | ∃∃m. ⦃G, L⦄ ⊢ V1 ➡[m, h] U2 & n = ↑m.
 280 #n #h #G #L #V1 #U1 #U2 * #c #Hc #H elim (cpg_inv_cast1 … H) -H *
 281 [ #cV #cT #V2 #T2 #HV12 #HT12 #HcVT #H1 #H2 destruct
 282   elim (isrt_inv_max … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 283   lapply (isrt_eq_t_trans … HcV HcVT) -HcVT #H
 284   lapply (isrt_inj … H HcT) -H #H destruct <idempotent_max
 285   /4 width=5 by or3_intro0, ex3_2_intro, ex2_intro/
 286 | #cU #U12 #H destruct
 287   /4 width=3 by isrt_inv_plus_O_dx, or3_intro1, ex2_intro/
 288 | #cU #H12 #H destruct
 289   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 290   /4 width=3 by or3_intro2, ex2_intro/
 291 ]
 292 qed-.
 293
 294 (* Basic forward lemmas *****************************************************)
 295
 296 (* Basic_2A1: includes: cpr_fwd_bind1_minus *)
 297 lemma cpm_fwd_bind1_minus: ∀n,h,I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ➡[n, h] T → ∀p.
 298                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] ⓑ{p,I}V2.T2 &
 299                                     T = -ⓑ{I}V2.T2.
 300 #n #h #I #G #L #V1 #T1 #T * #c #Hc #H #p elim (cpg_fwd_bind1_minus … H p) -H
 301 /3 width=4 by ex2_2_intro, ex2_intro/
 302 qed-.
 303
 304 (* Basic eliminators ********************************************************)
 305
 306 lemma cpm_ind (h): ∀Q:relation5 nat genv lenv term term.
 307                    (∀I,G,L. Q 0 G L (⓪{I}) (⓪{I})) →
 308                    (∀G,L,s. Q 1 G L (⋆s) (⋆(next h s))) →
 309                    (∀n,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 → Q n G K V1 V2 →
 310                      ⬆*[1] V2 ≘ W2 → Q n G (K.ⓓV1) (#0) W2
 311                    ) → (∀n,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 → Q n G K V1 V2 →
 312                      ⬆*[1] V2 ≘ W2 → Q (↑n) G (K.ⓛV1) (#0) W2
 313                    ) → (∀n,I,G,K,T,U,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T → Q n G K (#i) T →
 314                      ⬆*[1] T ≘ U → Q n G (K.ⓘ{I}) (#↑i) (U)
 315                    ) → (∀n,p,I,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 →
 316                      Q 0 G L V1 V2 → Q n G (L.ⓑ{I}V1) T1 T2 → Q n G L (ⓑ{p,I}V1.T1) (ⓑ{p,I}V2.T2)
 317                    ) → (∀n,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
 318                      Q 0 G L V1 V2 → Q n G L T1 T2 → Q n G L (ⓐV1.T1) (ⓐV2.T2)
 319                    ) → (∀n,G,L,V1,V2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
 320                      Q n G L V1 V2 → Q n G L T1 T2 → Q n G L (ⓝV1.T1) (ⓝV2.T2)
 321                    ) → (∀n,G,L,V,T1,T,T2. ⬆*[1] T ≘ T1 → ⦃G, L⦄ ⊢ T ➡[n, h] T2 →
 322                      Q n G L T T2 → Q n G L (+ⓓV.T1) T2
 323                    ) → (∀n,G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
 324                      Q n G L T1 T2 → Q n G L (ⓝV.T1) T2
 325                    ) → (∀n,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 →
 326                      Q n G L V1 V2 → Q (↑n) G L (ⓝV1.T) V2
 327                    ) → (∀n,p,G,L,V1,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 →
 328                      Q 0 G L V1 V2 → Q 0 G L W1 W2 → Q n G (L.ⓛW1) T1 T2 →
 329                      Q n G L (ⓐV1.ⓛ{p}W1.T1) (ⓓ{p}ⓝW2.V2.T2)
 330                    ) → (∀n,p,G,L,V1,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 →
 331                      Q 0 G L V1 V → Q 0 G L W1 W2 → Q n G (L.ⓓW1) T1 T2 →
 332                      ⬆*[1] V ≘ V2 → Q n G L (ⓐV1.ⓓ{p}W1.T1) (ⓓ{p}W2.ⓐV2.T2)
 333                    ) →
 334                    ∀n,G,L,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → Q n G L T1 T2.
 335 #h #Q #IH1 #IH2 #IH3 #IH4 #IH5 #IH6 #IH7 #IH8 #IH9 #IH10 #IH11 #IH12 #IH13 #n #G #L #T1 #T2
 336 * #c #HC #H generalize in match HC; -HC generalize in match n; -n
 337 elim H -c -G -L -T1 -T2
 338 [ #I #G #L #n #H <(isrt_inv_00 … H) -H //
 339 | #G #L #s #n #H <(isrt_inv_01 … H) -H //
 340 | /3 width=4 by ex2_intro/
 341 | #c #G #L #V1 #V2 #W2 #HV12 #HVW2 #IH #x #H
 342   elim (isrt_inv_plus_SO_dx … H) -H // #n #Hc #H destruct
 343   /3 width=4 by ex2_intro/
 344 | /3 width=4 by ex2_intro/
 345 | #cV #cT #p #I #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #IHV #IHT #n #H
 346   elim (isrt_inv_max_shift_sn … H) -H #HcV #HcT
 347   /3 width=3 by ex2_intro/
 348 | #cV #cT #G #L #V1 #V2 #T1 #T2 #HV12 #HT12 #IHV #IHT #n #H
 349   elim (isrt_inv_max_shift_sn … H) -H #HcV #HcT
 350   /3 width=3 by ex2_intro/
 351 | #cU #cT #G #L #U1 #U2 #T1 #T2 #HUT #HU12 #HT12 #IHU #IHT #n #H
 352   elim (isrt_inv_max_eq_t … H) -H // #HcV #HcT
 353   /3 width=3 by ex2_intro/
 354 | #c #G #L #V #T1 #T #T2 #HT1 #HT2 #IH #n #H
 355   lapply (isrt_inv_plus_O_dx … H ?) -H // #Hc
 356   /3 width=4 by ex2_intro/
 357 | #c #G #L #U #T1 #T2 #HT12 #IH #n #H
 358   lapply (isrt_inv_plus_O_dx … H ?) -H // #Hc
 359   /3 width=3 by ex2_intro/
 360 | #c #G #L #U1 #U2 #T #HU12 #IH #x #H
 361   elim (isrt_inv_plus_SO_dx … H) -H // #n #Hc #H destruct
 362   /3 width=3 by ex2_intro/
 363 | #cV #cW #cT #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #IHV #IHW #IHT #n #H
 364   lapply (isrt_inv_plus_O_dx … H ?) -H // >max_shift #H
 365   elim (isrt_inv_max_shift_sn … H) -H #H #HcT
 366   elim (isrt_O_inv_max … H) -H #HcV #HcW
 367   /3 width=3 by ex2_intro/
 368 | #cV #cW #cT #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #IHV #IHW #IHT #n #H
 369   lapply (isrt_inv_plus_O_dx … H ?) -H // >max_shift #H
 370   elim (isrt_inv_max_shift_sn … H) -H #H #HcT
 371   elim (isrt_O_inv_max … H) -H #HcV #HcW
 372   /3 width=4 by ex2_intro/
 373 ]
 374 qed-.