matita/matita/contribs/lambdadelta/basic_2/rt_transition/cpm.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basic_2/notation/relations/pred_6.ma".
  16 include "basic_2/notation/relations/pred_5.ma".
  17 include "basic_2/rt_transition/cpg.ma".
  18
  19 (* T-BOUND CONTEXT-SENSITIVE PARALLEL RT-TRANSITION FOR TERMS ***************)
  20
  21 (* Basic_2A1: includes: cpr *)
  22 definition cpm (n) (h): relation4 genv lenv term term ≝
  23                         λG,L,T1,T2. ∃∃c. 𝐑𝐓⦃n, c⦄ & ⦃G, L⦄ ⊢ T1 ⬈[c, h] T2.
  24
  25 interpretation
  26    "semi-counted context-sensitive parallel rt-transition (term)"
  27    'PRed n h G L T1 T2 = (cpm n h G L T1 T2).
  28
  29 interpretation
  30    "context-sensitive parallel r-transition (term)"
  31    'PRed h G L T1 T2 = (cpm O h G L T1 T2).
  32
  33 (* Basic properties *********************************************************)
  34
  35 lemma cpm_ess: ∀h,G,L,s. ⦃G, L⦄ ⊢ ⋆s ➡[1, h] ⋆(next h s).
  36 /2 width=3 by cpg_ess, ex2_intro/ qed.
  37
  38 lemma cpm_delta: ∀n,h,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 →
  39                  ⬆*[1] V2 ≡ W2 → ⦃G, K.ⓓV1⦄ ⊢ #0 ➡[n, h] W2.
  40 #n #h #G #K #V1 #V2 #W2 *
  41 /3 width=5 by cpg_delta, ex2_intro/
  42 qed.
  43
  44 lemma cpm_ell: ∀n,h,G,K,V1,V2,W2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 →
  45                ⬆*[1] V2 ≡ W2 → ⦃G, K.ⓛV1⦄ ⊢ #0 ➡[⫯n, h] W2.
  46 #n #h #G #K #V1 #V2 #W2 *
  47 /3 width=5 by cpg_ell, ex2_intro, isrt_succ/
  48 qed.
  49
  50 lemma cpm_lref: ∀n,h,I,G,K,V,T,U,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T →
  51                 ⬆*[1] T ≡ U → ⦃G, K.ⓑ{I}V⦄ ⊢ #⫯i ➡[n, h] U.
  52 #n #h #I #G #K #V #T #U #i *
  53 /3 width=5 by cpg_lref, ex2_intro/
  54 qed.
  55
  56 lemma cpm_bind: ∀n,h,p,I,G,L,V1,V2,T1,T2.
  57                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 →
  58                 ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] ⓑ{p,I}V2.T2.
  59 #n #h #p #I #G #L #V1 #V2 #T1 #T2 * #riV #rhV #HV12 *
  60 /5 width=5 by cpg_bind, isrt_plus_O1, isr_shift, ex2_intro/
  61 qed.
  62
  63 lemma cpm_flat: ∀n,h,I,G,L,V1,V2,T1,T2.
  64                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 →
  65                 ⦃G, L⦄ ⊢ ⓕ{I}V1.T1 ➡[n, h] ⓕ{I}V2.T2.
  66 #n #h #I #G #L #V1 #V2 #T1 #T2 * #riV #rhV #HV12 *
  67 /5 width=5 by isrt_plus_O1, isr_shift, cpg_flat, ex2_intro/
  68 qed.
  69
  70 lemma cpm_zeta: ∀n,h,G,L,V,T1,T,T2. ⦃G, L.ⓓV⦄ ⊢ T1 ➡[n, h] T →
  71                 ⬆*[1] T2 ≡ T → ⦃G, L⦄ ⊢ +ⓓV.T1 ➡[n, h] T2.
  72 #n #h #G #L #V #T1 #T #T2 *
  73 /3 width=5 by cpg_zeta, isrt_plus_O2, ex2_intro/
  74 qed.
  75
  76 lemma cpm_eps: ∀n,h,G,L,V,T1,T2. ⦃G, L⦄ ⊢ T1 ➡[n, h] T2 → ⦃G, L⦄ ⊢ ⓝV.T1 ➡[n, h] T2.
  77 #n #h #G #L #V #T1 #T2 *
  78 /3 width=3 by cpg_eps, isrt_plus_O2, ex2_intro/
  79 qed.
  80
  81 lemma cpm_ee: ∀n,h,G,L,V1,V2,T. ⦃G, L⦄ ⊢ V1 ➡[n, h] V2 → ⦃G, L⦄ ⊢ ⓝV1.T ➡[⫯n, h] V2.
  82 #n #h #G #L #V1 #V2 #T *
  83 /3 width=3 by cpg_ee, isrt_succ, ex2_intro/
  84 qed.
  85
  86 lemma cpm_beta: ∀n,h,p,G,L,V1,V2,W1,W2,T1,T2.
  87                 ⦃G, L⦄ ⊢ V1 ➡[h] V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 → ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 →
  88                 ⦃G, L⦄ ⊢ ⓐV1.ⓛ{p}W1.T1 ➡[n, h] ⓓ{p}ⓝW2.V2.T2.
  89 #n #h #p #G #L #V1 #V2 #W1 #W2 #T1 #T2 * #riV #rhV #HV12 * #riW #rhW #HW12 *
  90 /6 width=7 by cpg_beta, isrt_plus_O2, isrt_plus, isr_shift, ex2_intro/
  91 qed.
  92
  93 lemma cpm_theta: ∀n,h,p,G,L,V1,V,V2,W1,W2,T1,T2.
  94                  ⦃G, L⦄ ⊢ V1 ➡[h] V → ⬆*[1] V ≡ V2 → ⦃G, L⦄ ⊢ W1 ➡[h] W2 →
  95                  ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 →
  96                  ⦃G, L⦄ ⊢ ⓐV1.ⓓ{p}W1.T1 ➡[n, h] ⓓ{p}W2.ⓐV2.T2.
  97 #n #h #p #G #L #V1 #V #V2 #W1 #W2 #T1 #T2 * #riV #rhV #HV1 #HV2 * #riW #rhW #HW12 *
  98 /6 width=9 by cpg_theta, isrt_plus_O2, isrt_plus, isr_shift, ex2_intro/
  99 qed.
 100
 101 (* Basic properties on r-transition *****************************************)
 102
 103 (* Basic_2A1: includes: cpr_atom *)
 104 lemma cpr_refl: ∀h,G,L. reflexive … (cpm 0 h G L).
 105 /2 width=3 by ex2_intro/ qed.
 106
 107 lemma cpr_pair_sn: ∀h,I,G,L,V1,V2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 →
 108                    ∀T. ⦃G, L⦄ ⊢ ②{I}V1.T ➡[h] ②{I}V2.T.
 109 #h #I #G #L #V1 #V2 *
 110 /3 width=3 by cpg_pair_sn, isr_shift, ex2_intro/
 111 qed.
 112
 113 (* Basic inversion lemmas ***************************************************)
 114
 115 lemma cpm_inv_atom1: ∀n,h,J,G,L,T2. ⦃G, L⦄ ⊢ ⓪{J} ➡[n, h] T2 →
 116                      ∨∨ T2 = ⓪{J} ∧ n = 0
 117                       | ∃∃s. T2 = ⋆(next h s) & J = Sort s & n = 1
 118                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 & ⬆*[1] V2 ≡ T2 &
 119                                    L = K.ⓓV1 & J = LRef 0
 120                       | ∃∃m,K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[m, h] V2 & ⬆*[1] V2 ≡ T2 &
 121                                      L = K.ⓛV1 & J = LRef 0 & n = ⫯m
 122                       | ∃∃I,K,V,T,i. ⦃G, K⦄ ⊢ #i ➡[n, h] T & ⬆*[1] T ≡ T2 &
 123                                      L = K.ⓑ{I}V & J = LRef (⫯i).
 124 #n #h #J #G #L #T2 * #c #Hc #H elim (cpg_inv_atom1 … H) -H *
 125 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or5_intro0, conj/
 126 | #s #H1 #H2 #H3 destruct /4 width=3 by isrt_inv_01, or5_intro1, ex3_intro/
 127 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 #H3 destruct
 128   /4 width=6 by or5_intro2, ex4_3_intro, ex2_intro/
 129 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 #H3 destruct
 130   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 131   /4 width=9 by or5_intro3, ex5_4_intro, ex2_intro/
 132 | #I #K #V1 #V2 #i #HV2 #HVT2 #H1 #H2 destruct
 133   /4 width=9 by or5_intro4, ex4_5_intro, ex2_intro/
 134 ]
 135 qed-.
 136
 137 lemma cpm_inv_sort1: ∀n,h,G,L,T2,s. ⦃G, L⦄ ⊢ ⋆s ➡[n,h] T2 →
 138                      (T2 = ⋆s ∧ n = 0) ∨
 139                      (T2 = ⋆(next h s) ∧ n = 1).
 140 #n #h #G #L #T2 #s * #c #Hc #H elim (cpg_inv_sort1 … H) -H *
 141 #H1 #H2 destruct
 142 /4 width=1 by isrt_inv_01, isrt_inv_00, or_introl, or_intror, conj/
 143 qed-.
 144
 145 lemma cpm_inv_zero1: ∀n,h,G,L,T2. ⦃G, L⦄ ⊢ #0 ➡[n, h] T2 →
 146                      ∨∨ (T2 = #0 ∧ n = 0)
 147                       | ∃∃K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[n, h] V2 & ⬆*[1] V2 ≡ T2 &
 148                                    L = K.ⓓV1
 149                       | ∃∃m,K,V1,V2. ⦃G, K⦄ ⊢ V1 ➡[m, h] V2 & ⬆*[1] V2 ≡ T2 &
 150                                      L = K.ⓛV1 & n = ⫯m.
 151 #n #h #G #L #T2 * #c #Hc #H elim (cpg_inv_zero1 … H) -H *
 152 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or3_intro0, conj/
 153 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 destruct
 154   /4 width=8 by or3_intro1, ex3_3_intro, ex2_intro/
 155 | #cV #K #V1 #V2 #HV12 #HVT2 #H1 #H2 destruct
 156   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 157   /4 width=8 by or3_intro2, ex4_4_intro, ex2_intro/
 158 ]
 159 qed-.
 160
 161 lemma cpm_inv_lref1: ∀n,h,G,L,T2,i. ⦃G, L⦄ ⊢ #⫯i ➡[n, h] T2 →
 162                      (T2 = #(⫯i) ∧ n = 0) ∨
 163                      ∃∃I,K,V,T. ⦃G, K⦄ ⊢ #i ➡[n, h] T & ⬆*[1] T ≡ T2 & L = K.ⓑ{I}V.
 164 #n #h #G #L #T2 #i * #c #Hc #H elim (cpg_inv_lref1 … H) -H *
 165 [ #H1 #H2 destruct /4 width=1 by isrt_inv_00, or_introl, conj/
 166 | #I #K #V1 #V2 #HV2 #HVT2 #H1 destruct
 167  /4 width=7 by ex3_4_intro, ex2_intro, or_intror/
 168 ]
 169 qed-.
 170
 171 lemma cpm_inv_gref1: ∀n,h,G,L,T2,l. ⦃G, L⦄ ⊢ §l ➡[n, h] T2 → T2 = §l ∧ n = 0.
 172 #n #h #G #L #T2 #l * #c #Hc #H elim (cpg_inv_gref1 … H) -H
 173 #H1 #H2 destruct /3 width=1 by isrt_inv_00, conj/
 174 qed-.
 175
 176 lemma cpm_inv_bind1: ∀n,h,p,I,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] U2 → (
 177                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓑ{I}V1⦄ ⊢ T1 ➡[n, h] T2 &
 178                               U2 = ⓑ{p,I}V2.T2
 179                      ) ∨
 180                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡[n, h] T & ⬆*[1] U2 ≡ T &
 181                           p = true & I = Abbr.
 182 #n #h #p #I #G #L #V1 #T1 #U2 * #c #Hc #H elim (cpg_inv_bind1 … H) -H *
 183 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 184   elim (isrt_inv_plus … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 185   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 186   /4 width=5 by ex3_2_intro, ex2_intro, or_introl/
 187 | #cT #T2 #HT12 #HUT2 #H1 #H2 #H3 destruct
 188   /5 width=3 by isrt_inv_plus_O_dx, ex4_intro, ex2_intro, or_intror/
 189 ]
 190 qed-.
 191
 192 lemma cpm_inv_abbr1: ∀n,h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓓ{p}V1.T1 ➡[n, h] U2 → (
 193                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓓV1⦄ ⊢ T1 ➡[n, h] T2 &
 194                               U2 = ⓓ{p}V2.T2
 195                      ) ∨
 196                      ∃∃T. ⦃G, L.ⓓV1⦄ ⊢ T1 ➡[n, h] T & ⬆*[1] U2 ≡ T & p = true.
 197 #n #h #p #G #L #V1 #T1 #U2 * #c #Hc #H elim (cpg_inv_abbr1 … H) -H *
 198 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 199   elim (isrt_inv_plus … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 200   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 201   /4 width=5 by ex3_2_intro, ex2_intro, or_introl/
 202 | #cT #T2 #HT12 #HUT2 #H1 #H2 destruct
 203   /5 width=3 by isrt_inv_plus_O_dx, ex3_intro, ex2_intro, or_intror/
 204 ]
 205 qed-.
 206
 207 lemma cpm_inv_abst1: ∀n,h,p,G,L,V1,T1,U2. ⦃G, L⦄ ⊢ ⓛ{p}V1.T1 ➡[n, h] U2 →
 208                      ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L.ⓛV1⦄ ⊢ T1 ➡[n, h] T2 &
 209                               U2 = ⓛ{p}V2.T2.
 210 #n #h #p #G #L #V1 #T1 #U2 * #c #Hc #H elim (cpg_inv_abst1 … H) -H
 211 #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 212 elim (isrt_inv_plus … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 213 elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 214 /3 width=5 by ex3_2_intro, ex2_intro/
 215 qed-.
 216
 217 lemma cpm_inv_flat1: ∀n,h,I,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓕ{I}V1.U1 ➡[n, h] U2 →
 218                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ U1 ➡[n, h] T2 &
 219                                  U2 = ⓕ{I}V2.T2
 220                       | (⦃G, L⦄ ⊢ U1 ➡[n, h] U2 ∧ I = Cast)
 221                       | ∃∃m. ⦃G, L⦄ ⊢ V1 ➡[m, h] U2 & I = Cast & n = ⫯m
 222                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ W1 ➡[h] W2 &
 223                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 &
 224                                             U1 = ⓛ{p}W1.T1 &
 225                                             U2 = ⓓ{p}ⓝW2.V2.T2 & I = Appl
 226                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V & ⬆*[1] V ≡ V2 &
 227                                               ⦃G, L⦄ ⊢ W1 ➡[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 &
 228                                               U1 = ⓓ{p}W1.T1 &
 229                                               U2 = ⓓ{p}W2.ⓐV2.T2 & I = Appl.
 230 #n #h #I #G #L #V1 #U1 #U2 * #c #Hc #H elim (cpg_inv_flat1 … H) -H *
 231 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 232   elim (isrt_inv_plus … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 233   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 234   /4 width=5 by or5_intro0, ex3_2_intro, ex2_intro/
 235 | #cU #U12 #H1 #H2 destruct
 236   /5 width=3 by isrt_inv_plus_O_dx, or5_intro1, conj, ex2_intro/
 237 | #cU #H12 #H1 #H2 destruct
 238   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 239   /4 width=3 by or5_intro2, ex3_intro, ex2_intro/
 240 | #cV #cW #cT #p #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #H1 #H2 #H3 #H4 destruct
 241   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 242   elim (isrt_inv_plus … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 243   elim (isrt_inv_plus … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 244   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 245   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 246   /4 width=11 by or5_intro3, ex6_6_intro, ex2_intro/
 247 | #cV #cW #cT #p #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #H1 #H2 #H3 #H4 destruct
 248   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 249   elim (isrt_inv_plus … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 250   elim (isrt_inv_plus … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 251   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 252   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 253   /4 width=13 by or5_intro4, ex7_7_intro, ex2_intro/
 254 ]
 255 qed-.
 256
 257 lemma cpm_inv_appl1: ∀n,h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓐ V1.U1 ➡[n, h] U2 →
 258                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ U1 ➡[n, h] T2 &
 259                                  U2 = ⓐV2.T2
 260                       | ∃∃p,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ W1 ➡[h] W2 &
 261                                             ⦃G, L.ⓛW1⦄ ⊢ T1 ➡[n, h] T2 &
 262                                             U1 = ⓛ{p}W1.T1 & U2 = ⓓ{p}ⓝW2.V2.T2
 263                       | ∃∃p,V,V2,W1,W2,T1,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V & ⬆*[1] V ≡ V2 &
 264                                               ⦃G, L⦄ ⊢ W1 ➡[h] W2 & ⦃G, L.ⓓW1⦄ ⊢ T1 ➡[n, h] T2 &
 265                                               U1 = ⓓ{p}W1.T1 & U2 = ⓓ{p}W2.ⓐV2.T2.
 266 #n #h #G #L #V1 #U1 #U2 * #c #Hc #H elim (cpg_inv_appl1 … H) -H *
 267 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 268   elim (isrt_inv_plus … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 269   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 270   /4 width=5 by or3_intro0, ex3_2_intro, ex2_intro/
 271 | #cV #cW #cT #p #V2 #W1 #W2 #T1 #T2 #HV12 #HW12 #HT12 #H1 #H2 #H3 destruct
 272   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 273   elim (isrt_inv_plus … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 274   elim (isrt_inv_plus … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 275   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 276   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 277   /4 width=11 by or3_intro1, ex5_6_intro, ex2_intro/
 278 | #cV #cW #cT #p #V #V2 #W1 #W2 #T1 #T2 #HV1 #HV2 #HW12 #HT12 #H1 #H2 #H3 destruct
 279   lapply (isrt_inv_plus_O_dx … Hc ?) -Hc // #Hc
 280   elim (isrt_inv_plus … Hc) -Hc #n0 #nT #Hc #HcT #H destruct
 281   elim (isrt_inv_plus … Hc) -Hc #nV #nW #HcV #HcW #H destruct
 282   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 283   elim (isrt_inv_shift … HcW) -HcW #HcW #H destruct
 284   /4 width=13 by or3_intro2, ex6_7_intro, ex2_intro/
 285 ]
 286 qed-.
 287
 288 lemma cpm_inv_cast1: ∀n,h,G,L,V1,U1,U2. ⦃G, L⦄ ⊢ ⓝV1.U1 ➡[n, h] U2 →
 289                      ∨∨ ∃∃V2,T2. ⦃G, L⦄ ⊢ V1 ➡[h] V2 & ⦃G, L⦄ ⊢ U1 ➡[n,h] T2 &
 290                                  U2 = ⓝV2.T2
 291                       | ⦃G, L⦄ ⊢ U1 ➡[n, h] U2
 292                       | ∃∃m. ⦃G, L⦄ ⊢ V1 ➡[m, h] U2 & n = ⫯m.
 293 #n #h #G #L #V1 #U1 #U2 * #c #Hc #H elim (cpg_inv_cast1 … H) -H *
 294 [ #cV #cT #V2 #T2 #HV12 #HT12 #H1 #H2 destruct
 295   elim (isrt_inv_plus … Hc) -Hc #nV #nT #HcV #HcT #H destruct
 296   elim (isrt_inv_shift … HcV) -HcV #HcV #H destruct
 297   /4 width=5 by or3_intro0, ex3_2_intro, ex2_intro/
 298 | #cU #U12 #H destruct
 299   /4 width=3 by isrt_inv_plus_O_dx, or3_intro1, ex2_intro/
 300 | #cU #H12 #H destruct
 301   elim (isrt_inv_plus_SO_dx … Hc) -Hc // #m #Hc #H destruct
 302   /4 width=3 by or3_intro2, ex2_intro/
 303 ]
 304 qed-.
 305
 306 (* Basic forward lemmas *****************************************************)
 307
 308 lemma cpm_fwd_bind1_minus: ∀n,h,I,G,L,V1,T1,T. ⦃G, L⦄ ⊢ -ⓑ{I}V1.T1 ➡[n, h] T → ∀p.
 309                            ∃∃V2,T2. ⦃G, L⦄ ⊢ ⓑ{p,I}V1.T1 ➡[n, h] ⓑ{p,I}V2.T2 &
 310                                     T = -ⓑ{I}V2.T2.
 311 #n #h #I #G #L #V1 #T1 #T * #c #Hc #H #p elim (cpg_fwd_bind1_minus … H p) -H
 312 /3 width=4 by ex2_2_intro, ex2_intro/
 313 qed-.